git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   6   alias Pleroma.Web.OStatus
   7   alias Pleroma.Formatter
   8
   9   import Ecto.Query
  10   import Pleroma.Web.TwitterAPI.Utils
  11
  12   @httpoison Application.get_env(:pleroma, :httpoison)
  13
  14   def to_for_user_and_mentions(user, mentions, inReplyTo) do
  15     default_to = [
  16       User.ap_followers(user),
  17       "https://www.w3.org/ns/activitystreams#Public"
  18     ]
  19
  20     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  21     if inReplyTo do
  22       Enum.uniq([inReplyTo.data["actor"] | to])
  23     else
  24       to
  25     end
  26   end
  27
  28   def get_replied_to_activity(id) when not is_nil(id) do
  29     Repo.get(Activity, id)
  30   end
  31
  32   def get_replied_to_activity(_), do: nil
  33
  34   def create_status(%User{} = user, %{"status" => status} = data) do
  35     with attachments <- attachments_from_ids(data["media_ids"]),
  36          mentions <- Formatter.parse_mentions(status),
  37          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  38          to <- to_for_user_and_mentions(user, mentions, inReplyTo),
  39          content_html <- make_content_html(status, mentions, attachments),
  40          context <- make_context(inReplyTo),
  41          tags <- Formatter.parse_tags(status),
  42          object <- make_note_data(user.ap_id, to, context, content_html, attachments, inReplyTo, tags) do
  43       ActivityPub.create(to, user, context, object)
  44     end
  45   end
  46
  47   def fetch_friend_statuses(user, opts \\ %{}) do
  48     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  49     |> activities_to_statuses(%{for: user})
  50   end
  51
  52   def fetch_public_statuses(user, opts \\ %{}) do
  53     opts = Map.put(opts, "local_only", true)
  54     ActivityPub.fetch_public_activities(opts)
  55     |> activities_to_statuses(%{for: user})
  56   end
  57
  58   def fetch_public_and_external_statuses(user, opts \\ %{}) do
  59     ActivityPub.fetch_public_activities(opts)
  60     |> activities_to_statuses(%{for: user})
  61   end
  62
  63   def fetch_user_statuses(user, opts \\ %{}) do
  64     ActivityPub.fetch_activities([], opts)
  65     |> activities_to_statuses(%{for: user})
  66   end
  67
  68   def fetch_mentions(user, opts \\ %{}) do
  69     ActivityPub.fetch_activities([user.ap_id], opts)
  70     |> activities_to_statuses(%{for: user})
  71   end
  72
  73   def fetch_conversation(user, id) do
  74     with context when is_binary(context) <- conversation_id_to_context(id),
  75          activities <- ActivityPub.fetch_activities_for_context(context),
  76          statuses <- activities |> activities_to_statuses(%{for: user})
  77     do
  78       statuses
  79     else _e ->
  80       []
  81     end
  82   end
  83
  84   def fetch_status(user, id) do
  85     with %Activity{} = activity <- Repo.get(Activity, id) do
  86       activity_to_status(activity, %{for: user})
  87     end
  88   end
  89
  90   def follow(%User{} = follower, params) do
  91     with {:ok, %User{} = followed} <- get_user(params),
  92          {:ok, follower} <- User.follow(follower, followed),
  93          {:ok, activity} <- ActivityPub.follow(follower, followed)
  94     do
  95       {:ok, follower, followed, activity}
  96     else
  97       err -> err
  98     end
  99   end
 100
 101   def unfollow(%User{} = follower, params) do
 102     with { :ok, %User{} = unfollowed } <- get_user(params),
 103          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
 104          { :ok, _activity } <- ActivityPub.insert(%{
 105            "type" => "Undo",
 106            "actor" => follower.ap_id,
 107            "object" => follow_activity.data["id"], # get latest Follow for these users
 108            "published" => make_date()
 109          })
 110     do
 111       { :ok, follower, unfollowed }
 112     else
 113       err -> err
 114     end
 115   end
 116
 117   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 118     object = Object.get_by_ap_id(object["id"])
 119
 120     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 121     new_data = activity.data
 122     |> Map.put("object", object.data)
 123
 124     status = %{activity | data: new_data}
 125     |> activity_to_status(%{for: user})
 126
 127     {:ok, status}
 128   end
 129
 130   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 131     object = Object.get_by_ap_id(object["id"])
 132
 133     {:ok, object} = ActivityPub.unlike(user, object)
 134     new_data = activity.data
 135     |> Map.put("object", object.data)
 136
 137     status = %{activity | data: new_data}
 138     |> activity_to_status(%{for: user})
 139
 140     {:ok, status}
 141   end
 142
 143   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 144     object = Object.get_by_ap_id(object["id"])
 145
 146     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 147     new_data = activity.data
 148     |> Map.put("object", object.data)
 149
 150     status = %{activity | data: new_data}
 151     |> activity_to_status(%{for: user})
 152
 153     {:ok, status}
 154   end
 155
 156   def upload(%Plug.Upload{} = file, format \\ "xml") do
 157     {:ok, object} = ActivityPub.upload(file)
 158
 159     url = List.first(object.data["url"])
 160     href = url["href"]
 161     type = url["mediaType"]
 162
 163     case format do
 164       "xml" ->
 165         # Fake this as good as possible...
 166         """
 167         <?xml version="1.0" encoding="UTF-8"?>
 168         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 169         <mediaid>#{object.id}</mediaid>
 170         <media_id>#{object.id}</media_id>
 171         <media_id_string>#{object.id}</media_id_string>
 172         <media_url>#{href}</media_url>
 173         <mediaurl>#{href}</mediaurl>
 174         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 175         </rsp>
 176         """
 177       "json" ->
 178         %{
 179           media_id: object.id,
 180           media_id_string: "#{object.id}}",
 181           media_url: href,
 182           size: 0
 183         } |> Poison.encode!
 184     end
 185   end
 186
 187   def register_user(params) do
 188     params = %{
 189       nickname: params["nickname"],
 190       name: params["fullname"],
 191       bio: params["bio"],
 192       email: params["email"],
 193       password: params["password"],
 194       password_confirmation: params["confirm"]
 195     }
 196
 197     changeset = User.register_changeset(%User{}, params)
 198
 199     with {:ok, user} <- Repo.insert(changeset) do
 200       {:ok, UserRepresenter.to_map(user)}
 201     else
 202       {:error, changeset} ->
 203         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 204       |> Poison.encode!
 205       {:error, %{error: errors}}
 206     end
 207   end
 208
 209   def get_by_id_or_nickname(id_or_nickname) do
 210     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 211       Repo.get_by(User, nickname: id_or_nickname)
 212     else
 213       Repo.get(User, id_or_nickname)
 214     end
 215   end
 216
 217   def get_user(user \\ nil, params) do
 218     case params do
 219       %{"user_id" => user_id} ->
 220         case target = get_by_id_or_nickname(user_id) do
 221           nil ->
 222             {:error, "No user with such user_id"}
 223           _ ->
 224             {:ok, target}
 225         end
 226       %{"screen_name" => nickname} ->
 227         case target = Repo.get_by(User, nickname: nickname) do
 228           nil ->
 229             {:error, "No user with such screen_name"}
 230           _ ->
 231             {:ok, target}
 232         end
 233       _ ->
 234         if user do
 235           {:ok, user}
 236         else
 237           {:error, "You need to specify screen_name or user_id"}
 238         end
 239     end
 240   end
 241
 242   defp activities_to_statuses(activities, opts) do
 243     Enum.map(activities, fn(activity) ->
 244       activity_to_status(activity, opts)
 245     end)
 246   end
 247
 248   # For likes, fetch the liked activity, too.
 249   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 250     actor = get_in(activity.data, ["actor"])
 251     user = User.get_cached_by_ap_id(actor)
 252     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 253
 254     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 255   end
 256
 257   # For announces, fetch the announced activity and the user.
 258   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 259     actor = get_in(activity.data, ["actor"])
 260     user = User.get_cached_by_ap_id(actor)
 261     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 262     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 263
 264     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 265   end
 266
 267   defp activity_to_status(activity, opts) do
 268     actor = get_in(activity.data, ["actor"])
 269     user = User.get_cached_by_ap_id(actor)
 270     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 271     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 272       User.get_cached_by_ap_id(ap_id)
 273     end)
 274     |> Enum.filter(&(&1))
 275
 276     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 277   end
 278
 279   defp make_date do
 280     DateTime.utc_now() |> DateTime.to_iso8601
 281   end
 282
 283   def context_to_conversation_id(context) do
 284     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 285       id
 286       else _e ->
 287         changeset = Object.context_mapping(context)
 288         case Repo.insert(changeset) do
 289           {:ok, %{id: id}} -> id
 290           # This should be solved by an upsert, but it seems ecto
 291           # has problems accessing the constraint inside the jsonb.
 292           {:error, _} -> Object.get_cached_by_ap_id(context).id
 293         end
 294     end
 295   end
 296
 297   def conversation_id_to_context(id) do
 298     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 299       context
 300     else _e ->
 301       {:error, "No such conversation"}
 302     end
 303   end
 304
 305   def get_external_profile(for_user, uri) do
 306     with {:ok, %User{} = user} <- OStatus.find_or_make_user(uri) do
 307       with url <- user.info["topic"],
 308            {:ok, %{body: body}} <- @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 309         OStatus.handle_incoming(body)
 310       end
 311       {:ok, UserRepresenter.to_map(user, %{for: for_user})}
 312     else _e ->
 313         {:error, "Couldn't find user"}
 314     end
 315   end
 316 end