git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.Web.TwitterAPI.UserView
   6   alias Pleroma.Web.{OStatus, CommonAPI}
   7   alias Pleroma.Formatter
   8
   9   @httpoison Application.get_env(:pleroma, :httpoison)
  10
  11   def create_status(%User{} = user, %{"status" => status} = data) do
  12     CommonAPI.post(user, data)
  13   end
  14
  15   def fetch_friend_statuses(user, opts \\ %{}) do
  16     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  17     |> activities_to_statuses(%{for: user})
  18   end
  19
  20   def fetch_public_statuses(user, opts \\ %{}) do
  21     opts = Map.put(opts, "local_only", true)
  22     ActivityPub.fetch_public_activities(opts)
  23     |> activities_to_statuses(%{for: user})
  24   end
  25
  26   def fetch_public_and_external_statuses(user, opts \\ %{}) do
  27     ActivityPub.fetch_public_activities(opts)
  28     |> activities_to_statuses(%{for: user})
  29   end
  30
  31   def fetch_user_statuses(user, opts \\ %{}) do
  32     ActivityPub.fetch_activities([], opts)
  33     |> activities_to_statuses(%{for: user})
  34   end
  35
  36   def fetch_mentions(user, opts \\ %{}) do
  37     ActivityPub.fetch_activities([user.ap_id], opts)
  38     |> activities_to_statuses(%{for: user})
  39   end
  40
  41   def fetch_conversation(user, id) do
  42     with context when is_binary(context) <- conversation_id_to_context(id),
  43          activities <- ActivityPub.fetch_activities_for_context(context),
  44          statuses <- activities |> activities_to_statuses(%{for: user})
  45     do
  46       statuses
  47     else _e ->
  48       []
  49     end
  50   end
  51
  52   def fetch_status(user, id) do
  53     with %Activity{} = activity <- Repo.get(Activity, id) do
  54       activity_to_status(activity, %{for: user})
  55     end
  56   end
  57
  58   def follow(%User{} = follower, params) do
  59     with {:ok, %User{} = followed} <- get_user(params),
  60          {:ok, follower} <- User.follow(follower, followed),
  61          {:ok, activity} <- ActivityPub.follow(follower, followed)
  62     do
  63       {:ok, follower, followed, activity}
  64     else
  65       err -> err
  66     end
  67   end
  68
  69   def unfollow(%User{} = follower, params) do
  70     with { :ok, %User{} = unfollowed } <- get_user(params),
  71          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
  72          { :ok, _activity } <- ActivityPub.insert(%{
  73            "type" => "Undo",
  74            "actor" => follower.ap_id,
  75            "object" => follow_activity.data["id"], # get latest Follow for these users
  76            "published" => make_date()
  77          })
  78     do
  79       { :ok, follower, unfollowed }
  80     else
  81       err -> err
  82     end
  83   end
  84
  85   def repeat(%User{} = user, ap_id_or_id) do
  86     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
  87          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  88          status <- activity_to_status(activity, %{for: user}) do
  89       {:ok, status}
  90     end
  91   end
  92
  93   def fav(%User{} = user, ap_id_or_id) do
  94     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
  95          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  96          status <- activity_to_status(activity, %{for: user}) do
  97       {:ok, status}
  98     end
  99   end
 100
 101   def unfav(%User{} = user, ap_id_or_id) do
 102     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 103          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
 104          status <- activity_to_status(activity, %{for: user}) do
 105       {:ok, status}
 106     end
 107   end
 108
 109   def upload(%Plug.Upload{} = file, format \\ "xml") do
 110     {:ok, object} = ActivityPub.upload(file)
 111
 112     url = List.first(object.data["url"])
 113     href = url["href"]
 114     type = url["mediaType"]
 115
 116     case format do
 117       "xml" ->
 118         # Fake this as good as possible...
 119         """
 120         <?xml version="1.0" encoding="UTF-8"?>
 121         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 122         <mediaid>#{object.id}</mediaid>
 123         <media_id>#{object.id}</media_id>
 124         <media_id_string>#{object.id}</media_id_string>
 125         <media_url>#{href}</media_url>
 126         <mediaurl>#{href}</mediaurl>
 127         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 128         </rsp>
 129         """
 130       "json" ->
 131         %{
 132           media_id: object.id,
 133           media_id_string: "#{object.id}}",
 134           media_url: href,
 135           size: 0
 136         } |> Poison.encode!
 137     end
 138   end
 139
 140   def register_user(params) do
 141     params = %{
 142       nickname: params["nickname"],
 143       name: params["fullname"],
 144       bio: params["bio"],
 145       email: params["email"],
 146       password: params["password"],
 147       password_confirmation: params["confirm"]
 148     }
 149
 150     changeset = User.register_changeset(%User{}, params)
 151
 152     with {:ok, user} <- Repo.insert(changeset) do
 153       {:ok, user}
 154     else
 155       {:error, changeset} ->
 156         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 157       |> Poison.encode!
 158       {:error, %{error: errors}}
 159     end
 160   end
 161
 162   def get_by_id_or_nickname(id_or_nickname) do
 163     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 164       Repo.get_by(User, nickname: id_or_nickname)
 165     else
 166       Repo.get(User, id_or_nickname)
 167     end
 168   end
 169
 170   def get_user(user \\ nil, params) do
 171     case params do
 172       %{"user_id" => user_id} ->
 173         case target = get_by_id_or_nickname(user_id) do
 174           nil ->
 175             {:error, "No user with such user_id"}
 176           _ ->
 177             {:ok, target}
 178         end
 179       %{"screen_name" => nickname} ->
 180         case target = Repo.get_by(User, nickname: nickname) do
 181           nil ->
 182             {:error, "No user with such screen_name"}
 183           _ ->
 184             {:ok, target}
 185         end
 186       _ ->
 187         if user do
 188           {:ok, user}
 189         else
 190           {:error, "You need to specify screen_name or user_id"}
 191         end
 192     end
 193   end
 194
 195   defp activities_to_statuses(activities, opts) do
 196     Enum.map(activities, fn(activity) ->
 197       activity_to_status(activity, opts)
 198     end)
 199   end
 200
 201   # For likes, fetch the liked activity, too.
 202   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 203     actor = get_in(activity.data, ["actor"])
 204     user = User.get_cached_by_ap_id(actor)
 205     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 206
 207     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 208   end
 209
 210   # For announces, fetch the announced activity and the user.
 211   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 212     actor = get_in(activity.data, ["actor"])
 213     user = User.get_cached_by_ap_id(actor)
 214     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 215     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 216
 217     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 218   end
 219
 220   defp activity_to_status(%Activity{data: %{"type" => "Delete"}} = activity, opts) do
 221     actor = get_in(activity.data, ["actor"])
 222     user = User.get_cached_by_ap_id(actor)
 223     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user}))
 224   end
 225
 226   defp activity_to_status(activity, opts) do
 227     actor = get_in(activity.data, ["actor"])
 228     user = User.get_cached_by_ap_id(actor)
 229     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 230     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 231       if ap_id do
 232         User.get_cached_by_ap_id(ap_id)
 233       else
 234         nil
 235       end
 236     end)
 237     |> Enum.filter(&(&1))
 238
 239     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 240   end
 241
 242   defp make_date do
 243     DateTime.utc_now() |> DateTime.to_iso8601
 244   end
 245
 246   def context_to_conversation_id(context) do
 247     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 248       id
 249       else _e ->
 250         changeset = Object.context_mapping(context)
 251         case Repo.insert(changeset) do
 252           {:ok, %{id: id}} -> id
 253           # This should be solved by an upsert, but it seems ecto
 254           # has problems accessing the constraint inside the jsonb.
 255           {:error, _} -> Object.get_cached_by_ap_id(context).id
 256         end
 257     end
 258   end
 259
 260   def conversation_id_to_context(id) do
 261     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 262       context
 263     else _e ->
 264       {:error, "No such conversation"}
 265     end
 266   end
 267
 268   def get_external_profile(for_user, uri) do
 269     with {:ok, %User{} = user} <- OStatus.find_or_make_user(uri) do
 270       with url <- user.info["topic"],
 271            {:ok, %{body: body}} <- @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 272         OStatus.handle_incoming(body)
 273       end
 274       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 275     else _e ->
 276         {:error, "Couldn't find user"}
 277     end
 278   end
 279 end