git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.UtilController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4   alias Pleroma.Web
   5   alias Pleroma.Web.OStatus
   6   alias Pleroma.Web.WebFinger
   7   alias Pleroma.Web.CommonAPI
   8   alias Comeonin.Pbkdf2
   9   alias Pleroma.Formatter
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.{Repo, PasswordResetToken, User}
  12
  13   def show_password_reset(conn, %{"token" => token}) do
  14     with %{used: false} = token <- Repo.get_by(PasswordResetToken, %{token: token}),
  15          %User{} = user <- Repo.get(User, token.user_id) do
  16       render(conn, "password_reset.html", %{
  17         token: token,
  18         user: user
  19       })
  20     else
  21       _e -> render(conn, "invalid_token.html")
  22     end
  23   end
  24
  25   def password_reset(conn, %{"data" => data}) do
  26     with {:ok, _} <- PasswordResetToken.reset_password(data["token"], data) do
  27       render(conn, "password_reset_success.html")
  28     else
  29       _e -> render(conn, "password_reset_failed.html")
  30     end
  31   end
  32
  33   def help_test(conn, _params) do
  34     json(conn, "ok")
  35   end
  36
  37   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  38     with %User{} = user <- User.get_cached_by_nickname(nick), avatar = User.avatar_url(user) do
  39       conn
  40       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  41     else
  42       _e ->
  43         render(conn, "subscribe.html", %{
  44           nickname: nick,
  45           avatar: nil,
  46           error: "Could not find user"
  47         })
  48     end
  49   end
  50
  51   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  52     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  53          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  54       conn
  55       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  56     else
  57       _e ->
  58         render(conn, "subscribe.html", %{
  59           nickname: nick,
  60           avatar: nil,
  61           error: "Something went wrong."
  62         })
  63     end
  64   end
  65
  66   def remote_follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  67     {err, followee} = OStatus.find_or_make_user(acct)
  68     avatar = User.avatar_url(followee)
  69     name = followee.nickname
  70     id = followee.id
  71
  72     if !!user do
  73       conn
  74       |> render("follow.html", %{error: err, acct: acct, avatar: avatar, name: name, id: id})
  75     else
  76       conn
  77       |> render("follow_login.html", %{
  78         error: false,
  79         acct: acct,
  80         avatar: avatar,
  81         name: name,
  82         id: id
  83       })
  84     end
  85   end
  86
  87   def do_remote_follow(conn, %{
  88         "authorization" => %{"name" => username, "password" => password, "id" => id}
  89       }) do
  90     followee = Repo.get(User, id)
  91     avatar = User.avatar_url(followee)
  92     name = followee.nickname
  93
  94     with %User{} = user <- User.get_cached_by_nickname(username),
  95          true <- Pbkdf2.checkpw(password, user.password_hash),
  96          %User{} = _followed <- Repo.get(User, id),
  97          {:ok, follower} <- User.follow(user, followee),
  98          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
  99       conn
 100       |> render("followed.html", %{error: false})
 101     else
 102       _e ->
 103         conn
 104         |> render("follow_login.html", %{
 105           error: "Wrong username or password",
 106           id: id,
 107           name: name,
 108           avatar: avatar
 109         })
 110     end
 111   end
 112
 113   def do_remote_follow(%{assigns: %{user: user}} = conn, %{"user" => %{"id" => id}}) do
 114     with %User{} = followee <- Repo.get(User, id),
 115          {:ok, follower} <- User.follow(user, followee),
 116          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
 117       conn
 118       |> render("followed.html", %{error: false})
 119     else
 120       e ->
 121         Logger.debug("Remote follow failed with error #{inspect(e)}")
 122
 123         conn
 124         |> render("followed.html", %{error: inspect(e)})
 125     end
 126   end
 127
 128   @instance Application.get_env(:pleroma, :instance)
 129   @instance_fe Application.get_env(:pleroma, :fe)
 130   @instance_chat Application.get_env(:pleroma, :chat)
 131   def config(conn, _params) do
 132     case get_format(conn) do
 133       "xml" ->
 134         response = """
 135         <config>
 136           <site>
 137             <name>#{Keyword.get(@instance, :name)}</name>
 138             <site>#{Web.base_url()}</site>
 139             <textlimit>#{Keyword.get(@instance, :limit)}</textlimit>
 140             <closed>#{!Keyword.get(@instance, :registrations_open)}</closed>
 141           </site>
 142         </config>
 143         """
 144
 145         conn
 146         |> put_resp_content_type("application/xml")
 147         |> send_resp(200, response)
 148
 149       _ ->
 150         json(conn, %{
 151           site: %{
 152             name: Keyword.get(@instance, :name),
 153             description: Keyword.get(@instance, :description),
 154             server: Web.base_url(),
 155             textlimit: to_string(Keyword.get(@instance, :limit)),
 156             closed: if(Keyword.get(@instance, :registrations_open), do: "0", else: "1"),
 157             private: if(Keyword.get(@instance, :public, true), do: "0", else: "1"),
 158             pleromafe: %{
 159               theme: Keyword.get(@instance_fe, :theme),
 160               background: Keyword.get(@instance_fe, :background),
 161               logo: Keyword.get(@instance_fe, :logo),
 162               redirectRootNoLogin: Keyword.get(@instance_fe, :redirect_root_no_login),
 163               redirectRootLogin: Keyword.get(@instance_fe, :redirect_root_login),
 164               chatDisabled: !Keyword.get(@instance_chat, :enabled),
 165               showInstanceSpecificPanel: Keyword.get(@instance_fe, :show_instance_panel),
 166               showWhoToFollowPanel: Keyword.get(@instance_fe, :show_who_to_follow_panel),
 167               scopeOptionsEnabled: Keyword.get(@instance_fe, :scope_options_enabled),
 168               whoToFollowProvider: Keyword.get(@instance_fe, :who_to_follow_provider),
 169               whoToFollowLink: Keyword.get(@instance_fe, :who_to_follow_link)
 170             }
 171           }
 172         })
 173     end
 174   end
 175
 176   def version(conn, _params) do
 177     version = Keyword.get(@instance, :version)
 178
 179     case get_format(conn) do
 180       "xml" ->
 181         response = "<version>#{version}</version>"
 182
 183         conn
 184         |> put_resp_content_type("application/xml")
 185         |> send_resp(200, response)
 186
 187       _ ->
 188         json(conn, version)
 189     end
 190   end
 191
 192   def emoji(conn, _params) do
 193     json(conn, Enum.into(Formatter.get_custom_emoji(), %{}))
 194   end
 195
 196   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 197     follow_import(conn, %{"list" => File.read!(listfile.path)})
 198   end
 199
 200   def follow_import(%{assigns: %{user: user}} = conn, %{"list" => list}) do
 201     Task.start(fn ->
 202       String.split(list)
 203       |> Enum.map(fn account ->
 204         with %User{} = follower <- User.get_cached_by_ap_id(user.ap_id),
 205              %User{} = followed <- User.get_or_fetch(account),
 206              {:ok, follower} <- User.follow(follower, followed) do
 207           ActivityPub.follow(follower, followed)
 208         else
 209           err -> Logger.debug("follow_import: following #{account} failed with #{inspect(err)}")
 210         end
 211       end)
 212     end)
 213
 214     json(conn, "job started")
 215   end
 216
 217   def change_password(%{assigns: %{user: user}} = conn, params) do
 218     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 219       {:ok, user} ->
 220         with {:ok, _user} <-
 221                User.reset_password(user, %{
 222                  password: params["new_password"],
 223                  password_confirmation: params["new_password_confirmation"]
 224                }) do
 225           json(conn, %{status: "success"})
 226         else
 227           {:error, changeset} ->
 228             {_, {error, _}} = Enum.at(changeset.errors, 0)
 229             json(conn, %{error: "New password #{error}."})
 230
 231           _ ->
 232             json(conn, %{error: "Unable to change password."})
 233         end
 234
 235       {:error, msg} ->
 236         json(conn, %{error: msg})
 237     end
 238   end
 239
 240   def delete_account(%{assigns: %{user: user}} = conn, params) do
 241     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 242       {:ok, user} ->
 243         Task.start(fn -> User.delete(user) end)
 244         json(conn, %{status: "success"})
 245
 246       {:error, msg} ->
 247         json(conn, %{error: msg})
 248     end
 249   end
 250 end