git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.UtilController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4   alias Pleroma.Web
   5   alias Pleroma.Web.OStatus
   6   alias Pleroma.Web.WebFinger
   7   alias Pleroma.Web.CommonAPI
   8   alias Comeonin.Pbkdf2
   9   alias Pleroma.Formatter
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.{Repo, PasswordResetToken, User}
  12
  13   def show_password_reset(conn, %{"token" => token}) do
  14     with %{used: false} = token <- Repo.get_by(PasswordResetToken, %{token: token}),
  15          %User{} = user <- Repo.get(User, token.user_id) do
  16       render(conn, "password_reset.html", %{
  17         token: token,
  18         user: user
  19       })
  20     else
  21       _e -> render(conn, "invalid_token.html")
  22     end
  23   end
  24
  25   def password_reset(conn, %{"data" => data}) do
  26     with {:ok, _} <- PasswordResetToken.reset_password(data["token"], data) do
  27       render(conn, "password_reset_success.html")
  28     else
  29       _e -> render(conn, "password_reset_failed.html")
  30     end
  31   end
  32
  33   def help_test(conn, _params) do
  34     json(conn, "ok")
  35   end
  36
  37   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  38     with %User{} = user <- User.get_cached_by_nickname(nick), avatar = User.avatar_url(user) do
  39       conn
  40       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  41     else
  42       _e ->
  43         render(conn, "subscribe.html", %{
  44           nickname: nick,
  45           avatar: nil,
  46           error: "Could not find user"
  47         })
  48     end
  49   end
  50
  51   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  52     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  53          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  54       conn
  55       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  56     else
  57       _e ->
  58         render(conn, "subscribe.html", %{
  59           nickname: nick,
  60           avatar: nil,
  61           error: "Something went wrong."
  62         })
  63     end
  64   end
  65
  66   def remote_follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  67     {err, followee} = OStatus.find_or_make_user(acct)
  68     avatar = User.avatar_url(followee)
  69     name = followee.nickname
  70     id = followee.id
  71
  72     if !!user do
  73       conn
  74       |> render("follow.html", %{error: err, acct: acct, avatar: avatar, name: name, id: id})
  75     else
  76       conn
  77       |> render("follow_login.html", %{
  78         error: false,
  79         acct: acct,
  80         avatar: avatar,
  81         name: name,
  82         id: id
  83       })
  84     end
  85   end
  86
  87   def do_remote_follow(conn, %{
  88         "authorization" => %{"name" => username, "password" => password, "id" => id}
  89       }) do
  90     followee = Repo.get(User, id)
  91     avatar = User.avatar_url(followee)
  92     name = followee.nickname
  93
  94     with %User{} = user <- User.get_cached_by_nickname(username),
  95          true <- Pbkdf2.checkpw(password, user.password_hash),
  96          %User{} = _followed <- Repo.get(User, id),
  97          {:ok, follower} <- User.follow(user, followee),
  98          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
  99       conn
 100       |> render("followed.html", %{error: false})
 101     else
 102       # Was already following user
 103       {:error, "Could not follow user:" <> _rest} ->
 104         render(conn, "followed.html", %{error: false})
 105
 106       _e ->
 107         conn
 108         |> render("follow_login.html", %{
 109           error: "Wrong username or password",
 110           id: id,
 111           name: name,
 112           avatar: avatar
 113         })
 114     end
 115   end
 116
 117   def do_remote_follow(%{assigns: %{user: user}} = conn, %{"user" => %{"id" => id}}) do
 118     with %User{} = followee <- Repo.get(User, id),
 119          {:ok, follower} <- User.follow(user, followee),
 120          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
 121       conn
 122       |> render("followed.html", %{error: false})
 123     else
 124       # Was already following user
 125       {:error, "Could not follow user:" <> _rest} ->
 126         conn
 127         |> render("followed.html", %{error: false})
 128
 129       e ->
 130         Logger.debug("Remote follow failed with error #{inspect(e)}")
 131
 132         conn
 133         |> render("followed.html", %{error: inspect(e)})
 134     end
 135   end
 136
 137   @instance Application.get_env(:pleroma, :instance)
 138   @instance_fe Application.get_env(:pleroma, :fe)
 139   @instance_chat Application.get_env(:pleroma, :chat)
 140   def config(conn, _params) do
 141     case get_format(conn) do
 142       "xml" ->
 143         response = """
 144         <config>
 145           <site>
 146             <name>#{Keyword.get(@instance, :name)}</name>
 147             <site>#{Web.base_url()}</site>
 148             <textlimit>#{Keyword.get(@instance, :limit)}</textlimit>
 149             <closed>#{!Keyword.get(@instance, :registrations_open)}</closed>
 150           </site>
 151         </config>
 152         """
 153
 154         conn
 155         |> put_resp_content_type("application/xml")
 156         |> send_resp(200, response)
 157
 158       _ ->
 159         json(conn, %{
 160           site: %{
 161             name: Keyword.get(@instance, :name),
 162             description: Keyword.get(@instance, :description),
 163             server: Web.base_url(),
 164             textlimit: to_string(Keyword.get(@instance, :limit)),
 165             closed: if(Keyword.get(@instance, :registrations_open), do: "0", else: "1"),
 166             private: if(Keyword.get(@instance, :public, true), do: "0", else: "1"),
 167             pleromafe: %{
 168               theme: Keyword.get(@instance_fe, :theme),
 169               background: Keyword.get(@instance_fe, :background),
 170               logo: Keyword.get(@instance_fe, :logo),
 171               redirectRootNoLogin: Keyword.get(@instance_fe, :redirect_root_no_login),
 172               redirectRootLogin: Keyword.get(@instance_fe, :redirect_root_login),
 173               chatDisabled: !Keyword.get(@instance_chat, :enabled),
 174               showInstanceSpecificPanel: Keyword.get(@instance_fe, :show_instance_panel),
 175               showWhoToFollowPanel: Keyword.get(@instance_fe, :show_who_to_follow_panel),
 176               scopeOptionsEnabled: Keyword.get(@instance_fe, :scope_options_enabled),
 177               whoToFollowProvider: Keyword.get(@instance_fe, :who_to_follow_provider),
 178               whoToFollowLink: Keyword.get(@instance_fe, :who_to_follow_link)
 179             }
 180           }
 181         })
 182     end
 183   end
 184
 185   def version(conn, _params) do
 186     version = Keyword.get(@instance, :version)
 187
 188     case get_format(conn) do
 189       "xml" ->
 190         response = "<version>#{version}</version>"
 191
 192         conn
 193         |> put_resp_content_type("application/xml")
 194         |> send_resp(200, response)
 195
 196       _ ->
 197         json(conn, version)
 198     end
 199   end
 200
 201   def emoji(conn, _params) do
 202     json(conn, Enum.into(Formatter.get_custom_emoji(), %{}))
 203   end
 204
 205   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 206     follow_import(conn, %{"list" => File.read!(listfile.path)})
 207   end
 208
 209   def follow_import(%{assigns: %{user: user}} = conn, %{"list" => list}) do
 210     Task.start(fn ->
 211       String.split(list)
 212       |> Enum.map(fn account ->
 213         with %User{} = follower <- User.get_cached_by_ap_id(user.ap_id),
 214              %User{} = followed <- User.get_or_fetch(account),
 215              {:ok, follower} <- User.follow(follower, followed) do
 216           ActivityPub.follow(follower, followed)
 217         else
 218           err -> Logger.debug("follow_import: following #{account} failed with #{inspect(err)}")
 219         end
 220       end)
 221     end)
 222
 223     json(conn, "job started")
 224   end
 225
 226   def change_password(%{assigns: %{user: user}} = conn, params) do
 227     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 228       {:ok, user} ->
 229         with {:ok, _user} <-
 230                User.reset_password(user, %{
 231                  password: params["new_password"],
 232                  password_confirmation: params["new_password_confirmation"]
 233                }) do
 234           json(conn, %{status: "success"})
 235         else
 236           {:error, changeset} ->
 237             {_, {error, _}} = Enum.at(changeset.errors, 0)
 238             json(conn, %{error: "New password #{error}."})
 239
 240           _ ->
 241             json(conn, %{error: "Unable to change password."})
 242         end
 243
 244       {:error, msg} ->
 245         json(conn, %{error: msg})
 246     end
 247   end
 248
 249   def delete_account(%{assigns: %{user: user}} = conn, params) do
 250     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 251       {:ok, user} ->
 252         Task.start(fn -> User.delete(user) end)
 253         json(conn, %{status: "success"})
 254
 255       {:error, msg} ->
 256         json(conn, %{error: msg})
 257     end
 258   end
 259 end