git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UtilController do
   6   use Pleroma.Web, :controller
   7   require Logger
   8   alias Pleroma.Web
   9   alias Pleroma.Web.OStatus
  10   alias Pleroma.Web.WebFinger
  11   alias Pleroma.Web.CommonAPI
  12   alias Comeonin.Pbkdf2
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.{Repo, PasswordResetToken, User, Emoji}
  15
  16   def show_password_reset(conn, %{"token" => token}) do
  17     with %{used: false} = token <- Repo.get_by(PasswordResetToken, %{token: token}),
  18          %User{} = user <- Repo.get(User, token.user_id) do
  19       render(conn, "password_reset.html", %{
  20         token: token,
  21         user: user
  22       })
  23     else
  24       _e -> render(conn, "invalid_token.html")
  25     end
  26   end
  27
  28   def password_reset(conn, %{"data" => data}) do
  29     with {:ok, _} <- PasswordResetToken.reset_password(data["token"], data) do
  30       render(conn, "password_reset_success.html")
  31     else
  32       _e -> render(conn, "password_reset_failed.html")
  33     end
  34   end
  35
  36   def help_test(conn, _params) do
  37     json(conn, "ok")
  38   end
  39
  40   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  41     with %User{} = user <- User.get_cached_by_nickname(nick), avatar = User.avatar_url(user) do
  42       conn
  43       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  44     else
  45       _e ->
  46         render(conn, "subscribe.html", %{
  47           nickname: nick,
  48           avatar: nil,
  49           error: "Could not find user"
  50         })
  51     end
  52   end
  53
  54   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  55     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  56          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  57       conn
  58       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  59     else
  60       _e ->
  61         render(conn, "subscribe.html", %{
  62           nickname: nick,
  63           avatar: nil,
  64           error: "Something went wrong."
  65         })
  66     end
  67   end
  68
  69   def remote_follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  70     {err, followee} = OStatus.find_or_make_user(acct)
  71     avatar = User.avatar_url(followee)
  72     name = followee.nickname
  73     id = followee.id
  74
  75     if !!user do
  76       conn
  77       |> render("follow.html", %{error: err, acct: acct, avatar: avatar, name: name, id: id})
  78     else
  79       conn
  80       |> render("follow_login.html", %{
  81         error: false,
  82         acct: acct,
  83         avatar: avatar,
  84         name: name,
  85         id: id
  86       })
  87     end
  88   end
  89
  90   def do_remote_follow(conn, %{
  91         "authorization" => %{"name" => username, "password" => password, "id" => id}
  92       }) do
  93     followee = Repo.get(User, id)
  94     avatar = User.avatar_url(followee)
  95     name = followee.nickname
  96
  97     with %User{} = user <- User.get_cached_by_nickname(username),
  98          true <- Pbkdf2.checkpw(password, user.password_hash),
  99          %User{} = _followed <- Repo.get(User, id),
 100          {:ok, follower} <- User.follow(user, followee),
 101          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
 102       conn
 103       |> render("followed.html", %{error: false})
 104     else
 105       # Was already following user
 106       {:error, "Could not follow user:" <> _rest} ->
 107         render(conn, "followed.html", %{error: false})
 108
 109       _e ->
 110         conn
 111         |> render("follow_login.html", %{
 112           error: "Wrong username or password",
 113           id: id,
 114           name: name,
 115           avatar: avatar
 116         })
 117     end
 118   end
 119
 120   def do_remote_follow(%{assigns: %{user: user}} = conn, %{"user" => %{"id" => id}}) do
 121     with %User{} = followee <- Repo.get(User, id),
 122          {:ok, follower} <- User.follow(user, followee),
 123          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
 124       conn
 125       |> render("followed.html", %{error: false})
 126     else
 127       # Was already following user
 128       {:error, "Could not follow user:" <> _rest} ->
 129         conn
 130         |> render("followed.html", %{error: false})
 131
 132       e ->
 133         Logger.debug("Remote follow failed with error #{inspect(e)}")
 134
 135         conn
 136         |> render("followed.html", %{error: inspect(e)})
 137     end
 138   end
 139
 140   def config(conn, _params) do
 141     instance = Pleroma.Config.get(:instance)
 142     instance_fe = Pleroma.Config.get(:fe)
 143     instance_chat = Pleroma.Config.get(:chat)
 144
 145     case get_format(conn) do
 146       "xml" ->
 147         response = """
 148         <config>
 149           <site>
 150             <name>#{Keyword.get(instance, :name)}</name>
 151             <site>#{Web.base_url()}</site>
 152             <textlimit>#{Keyword.get(instance, :limit)}</textlimit>
 153             <closed>#{!Keyword.get(instance, :registrations_open)}</closed>
 154           </site>
 155         </config>
 156         """
 157
 158         conn
 159         |> put_resp_content_type("application/xml")
 160         |> send_resp(200, response)
 161
 162       _ ->
 163         vapid_public_key = Keyword.get(Pleroma.Web.Push.vapid_config(), :public_key)
 164
 165         uploadlimit = %{
 166           uploadlimit: to_string(Keyword.get(instance, :upload_limit)),
 167           avatarlimit: to_string(Keyword.get(instance, :avatar_upload_limit)),
 168           backgroundlimit: to_string(Keyword.get(instance, :background_upload_limit)),
 169           bannerlimit: to_string(Keyword.get(instance, :banner_upload_limit))
 170         }
 171
 172         data = %{
 173           name: Keyword.get(instance, :name),
 174           description: Keyword.get(instance, :description),
 175           server: Web.base_url(),
 176           textlimit: to_string(Keyword.get(instance, :limit)),
 177           uploadlimit: uploadlimit,
 178           closed: if(Keyword.get(instance, :registrations_open), do: "0", else: "1"),
 179           private: if(Keyword.get(instance, :public, true), do: "0", else: "1"),
 180           vapidPublicKey: vapid_public_key,
 181           accountActivationRequired:
 182             if(Keyword.get(instance, :account_activation_required, false), do: "1", else: "0"),
 183           invitesEnabled: if(Keyword.get(instance, :invites_enabled, false), do: "1", else: "0")
 184         }
 185
 186         pleroma_fe = %{
 187           theme: Keyword.get(instance_fe, :theme),
 188           background: Keyword.get(instance_fe, :background),
 189           logo: Keyword.get(instance_fe, :logo),
 190           logoMask: Keyword.get(instance_fe, :logo_mask),
 191           logoMargin: Keyword.get(instance_fe, :logo_margin),
 192           redirectRootNoLogin: Keyword.get(instance_fe, :redirect_root_no_login),
 193           redirectRootLogin: Keyword.get(instance_fe, :redirect_root_login),
 194           chatDisabled: !Keyword.get(instance_chat, :enabled),
 195           showInstanceSpecificPanel: Keyword.get(instance_fe, :show_instance_panel),
 196           scopeOptionsEnabled: Keyword.get(instance_fe, :scope_options_enabled),
 197           formattingOptionsEnabled: Keyword.get(instance_fe, :formatting_options_enabled),
 198           collapseMessageWithSubject: Keyword.get(instance_fe, :collapse_message_with_subject),
 199           hidePostStats: Keyword.get(instance_fe, :hide_post_stats),
 200           hideUserStats: Keyword.get(instance_fe, :hide_user_stats),
 201           scopeCopy: Keyword.get(instance_fe, :scope_copy),
 202           subjectLineBehavior: Keyword.get(instance_fe, :subject_line_behavior),
 203           alwaysShowSubjectInput: Keyword.get(instance_fe, :always_show_subject_input)
 204         }
 205
 206         managed_config = Keyword.get(instance, :managed_config)
 207
 208         data =
 209           if managed_config do
 210             data |> Map.put("pleromafe", pleroma_fe)
 211           else
 212             data
 213           end
 214
 215         json(conn, %{site: data})
 216     end
 217   end
 218
 219   def version(conn, _params) do
 220     version = Pleroma.Application.named_version()
 221
 222     case get_format(conn) do
 223       "xml" ->
 224         response = "<version>#{version}</version>"
 225
 226         conn
 227         |> put_resp_content_type("application/xml")
 228         |> send_resp(200, response)
 229
 230       _ ->
 231         json(conn, version)
 232     end
 233   end
 234
 235   def emoji(conn, _params) do
 236     json(conn, Enum.into(Emoji.get_all(), %{}))
 237   end
 238
 239   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 240     follow_import(conn, %{"list" => File.read!(listfile.path)})
 241   end
 242
 243   def follow_import(%{assigns: %{user: follower}} = conn, %{"list" => list}) do
 244     with followed_identifiers <- String.split(list),
 245          {:ok, _} = Task.start(fn -> User.follow_import(follower, followed_identifiers) end) do
 246       json(conn, "job started")
 247     end
 248   end
 249
 250   def blocks_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 251     blocks_import(conn, %{"list" => File.read!(listfile.path)})
 252   end
 253
 254   def blocks_import(%{assigns: %{user: blocker}} = conn, %{"list" => list}) do
 255     with blocked_identifiers <- String.split(list),
 256          {:ok, _} = Task.start(fn -> User.blocks_import(blocker, blocked_identifiers) end) do
 257       json(conn, "job started")
 258     end
 259   end
 260
 261   def change_password(%{assigns: %{user: user}} = conn, params) do
 262     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 263       {:ok, user} ->
 264         with {:ok, _user} <-
 265                User.reset_password(user, %{
 266                  password: params["new_password"],
 267                  password_confirmation: params["new_password_confirmation"]
 268                }) do
 269           json(conn, %{status: "success"})
 270         else
 271           {:error, changeset} ->
 272             {_, {error, _}} = Enum.at(changeset.errors, 0)
 273             json(conn, %{error: "New password #{error}."})
 274
 275           _ ->
 276             json(conn, %{error: "Unable to change password."})
 277         end
 278
 279       {:error, msg} ->
 280         json(conn, %{error: msg})
 281     end
 282   end
 283
 284   def delete_account(%{assigns: %{user: user}} = conn, params) do
 285     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 286       {:ok, user} ->
 287         Task.start(fn -> User.delete(user) end)
 288         json(conn, %{status: "success"})
 289
 290       {:error, msg} ->
 291         json(conn, %{error: msg})
 292     end
 293   end
 294
 295   def captcha(conn, _params) do
 296     json(conn, Pleroma.Captcha.new())
 297   end
 298 end