git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UtilController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Config
  11   alias Pleroma.Emoji
  12   alias Pleroma.Healthcheck
  13   alias Pleroma.Notification
  14   alias Pleroma.Plugs.OAuthScopesPlug
  15   alias Pleroma.User
  16   alias Pleroma.Web.CommonAPI
  17   alias Pleroma.Web.WebFinger
  18
  19   plug(Pleroma.Web.FederatingPlug when action == :remote_subscribe)
  20
  21   plug(
  22     OAuthScopesPlug,
  23     %{scopes: ["follow", "write:follows"]}
  24     when action == :follow_import
  25   )
  26
  27   # Note: follower can submit the form (with password auth) not being signed in (having no token)
  28   plug(
  29     OAuthScopesPlug,
  30     %{fallback: :proceed_unauthenticated, scopes: ["follow", "write:follows"]}
  31     when action == :do_remote_follow
  32   )
  33
  34   plug(OAuthScopesPlug, %{scopes: ["follow", "write:blocks"]} when action == :blocks_import)
  35
  36   plug(
  37     OAuthScopesPlug,
  38     %{scopes: ["write:accounts"]}
  39     when action in [
  40            :change_email,
  41            :change_password,
  42            :delete_account,
  43            :update_notificaton_settings,
  44            :disable_account
  45          ]
  46   )
  47
  48   plug(OAuthScopesPlug, %{scopes: ["write:notifications"]} when action == :notifications_read)
  49
  50   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  51     with %User{} = user <- User.get_cached_by_nickname(nick),
  52          avatar = User.avatar_url(user) do
  53       conn
  54       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  55     else
  56       _e ->
  57         render(conn, "subscribe.html", %{
  58           nickname: nick,
  59           avatar: nil,
  60           error: "Could not find user"
  61         })
  62     end
  63   end
  64
  65   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  66     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  67          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  68       conn
  69       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  70     else
  71       _e ->
  72         render(conn, "subscribe.html", %{
  73           nickname: nick,
  74           avatar: nil,
  75           error: "Something went wrong."
  76         })
  77     end
  78   end
  79
  80   def notifications_read(%{assigns: %{user: user}} = conn, %{"id" => notification_id}) do
  81     with {:ok, _} <- Notification.read_one(user, notification_id) do
  82       json(conn, %{status: "success"})
  83     else
  84       {:error, message} ->
  85         conn
  86         |> put_resp_content_type("application/json")
  87         |> send_resp(403, Jason.encode!(%{"error" => message}))
  88     end
  89   end
  90
  91   def frontend_configurations(conn, _params) do
  92     config =
  93       Pleroma.Config.get(:frontend_configurations, %{})
  94       |> Enum.into(%{})
  95
  96     json(conn, config)
  97   end
  98
  99   def emoji(conn, _params) do
 100     emoji =
 101       Enum.reduce(Emoji.get_all(), %{}, fn {code, %Emoji{file: file, tags: tags}}, acc ->
 102         Map.put(acc, code, %{image_url: file, tags: tags})
 103       end)
 104
 105     json(conn, emoji)
 106   end
 107
 108   def update_notificaton_settings(%{assigns: %{user: user}} = conn, params) do
 109     with {:ok, _} <- User.update_notification_settings(user, params) do
 110       json(conn, %{status: "success"})
 111     end
 112   end
 113
 114   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 115     follow_import(conn, %{"list" => File.read!(listfile.path)})
 116   end
 117
 118   def follow_import(%{assigns: %{user: follower}} = conn, %{"list" => list}) do
 119     with lines <- String.split(list, "\n"),
 120          followed_identifiers <-
 121            Enum.map(lines, fn line ->
 122              String.split(line, ",") |> List.first()
 123            end)
 124            |> List.delete("Account address") do
 125       User.follow_import(follower, followed_identifiers)
 126       json(conn, "job started")
 127     end
 128   end
 129
 130   def blocks_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 131     blocks_import(conn, %{"list" => File.read!(listfile.path)})
 132   end
 133
 134   def blocks_import(%{assigns: %{user: blocker}} = conn, %{"list" => list}) do
 135     with blocked_identifiers <- String.split(list) do
 136       User.blocks_import(blocker, blocked_identifiers)
 137       json(conn, "job started")
 138     end
 139   end
 140
 141   def change_password(%{assigns: %{user: user}} = conn, params) do
 142     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 143       {:ok, user} ->
 144         with {:ok, _user} <-
 145                User.reset_password(user, %{
 146                  password: params["new_password"],
 147                  password_confirmation: params["new_password_confirmation"]
 148                }) do
 149           json(conn, %{status: "success"})
 150         else
 151           {:error, changeset} ->
 152             {_, {error, _}} = Enum.at(changeset.errors, 0)
 153             json(conn, %{error: "New password #{error}."})
 154
 155           _ ->
 156             json(conn, %{error: "Unable to change password."})
 157         end
 158
 159       {:error, msg} ->
 160         json(conn, %{error: msg})
 161     end
 162   end
 163
 164   def change_email(%{assigns: %{user: user}} = conn, params) do
 165     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 166       {:ok, user} ->
 167         with {:ok, _user} <- User.change_email(user, params["email"]) do
 168           json(conn, %{status: "success"})
 169         else
 170           {:error, changeset} ->
 171             {_, {error, _}} = Enum.at(changeset.errors, 0)
 172             json(conn, %{error: "Email #{error}."})
 173
 174           _ ->
 175             json(conn, %{error: "Unable to change email."})
 176         end
 177
 178       {:error, msg} ->
 179         json(conn, %{error: msg})
 180     end
 181   end
 182
 183   def delete_account(%{assigns: %{user: user}} = conn, params) do
 184     password = params["password"] || ""
 185
 186     case CommonAPI.Utils.confirm_current_password(user, password) do
 187       {:ok, user} ->
 188         User.delete(user)
 189         json(conn, %{status: "success"})
 190
 191       {:error, msg} ->
 192         json(conn, %{error: msg})
 193     end
 194   end
 195
 196   def disable_account(%{assigns: %{user: user}} = conn, params) do
 197     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 198       {:ok, user} ->
 199         User.deactivate_async(user)
 200         json(conn, %{status: "success"})
 201
 202       {:error, msg} ->
 203         json(conn, %{error: msg})
 204     end
 205   end
 206
 207   def captcha(conn, _params) do
 208     json(conn, Pleroma.Captcha.new())
 209   end
 210
 211   def healthcheck(conn, _params) do
 212     with true <- Config.get([:instance, :healthcheck]),
 213          %{healthy: true} = info <- Healthcheck.system_info() do
 214       json(conn, info)
 215     else
 216       %{healthy: false} = info ->
 217         service_unavailable(conn, info)
 218
 219       _ ->
 220         service_unavailable(conn, %{})
 221     end
 222   end
 223
 224   defp service_unavailable(conn, info) do
 225     conn
 226     |> put_status(:service_unavailable)
 227     |> json(info)
 228   end
 229 end