git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.UtilController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4   alias Pleroma.Web
   5   alias Pleroma.Web.OStatus
   6   alias Pleroma.Web.WebFinger
   7   alias Pleroma.Web.CommonAPI
   8   alias Comeonin.Pbkdf2
   9   alias Pleroma.{Formatter, Emoji}
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.{Repo, PasswordResetToken, User}
  12
  13   def show_password_reset(conn, %{"token" => token}) do
  14     with %{used: false} = token <- Repo.get_by(PasswordResetToken, %{token: token}),
  15          %User{} = user <- Repo.get(User, token.user_id) do
  16       render(conn, "password_reset.html", %{
  17         token: token,
  18         user: user
  19       })
  20     else
  21       _e -> render(conn, "invalid_token.html")
  22     end
  23   end
  24
  25   def password_reset(conn, %{"data" => data}) do
  26     with {:ok, _} <- PasswordResetToken.reset_password(data["token"], data) do
  27       render(conn, "password_reset_success.html")
  28     else
  29       _e -> render(conn, "password_reset_failed.html")
  30     end
  31   end
  32
  33   def help_test(conn, _params) do
  34     json(conn, "ok")
  35   end
  36
  37   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  38     with %User{} = user <- User.get_cached_by_nickname(nick), avatar = User.avatar_url(user) do
  39       conn
  40       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  41     else
  42       _e ->
  43         render(conn, "subscribe.html", %{
  44           nickname: nick,
  45           avatar: nil,
  46           error: "Could not find user"
  47         })
  48     end
  49   end
  50
  51   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  52     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  53          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  54       conn
  55       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  56     else
  57       _e ->
  58         render(conn, "subscribe.html", %{
  59           nickname: nick,
  60           avatar: nil,
  61           error: "Something went wrong."
  62         })
  63     end
  64   end
  65
  66   def remote_follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  67     {err, followee} = OStatus.find_or_make_user(acct)
  68     avatar = User.avatar_url(followee)
  69     name = followee.nickname
  70     id = followee.id
  71
  72     if !!user do
  73       conn
  74       |> render("follow.html", %{error: err, acct: acct, avatar: avatar, name: name, id: id})
  75     else
  76       conn
  77       |> render("follow_login.html", %{
  78         error: false,
  79         acct: acct,
  80         avatar: avatar,
  81         name: name,
  82         id: id
  83       })
  84     end
  85   end
  86
  87   def do_remote_follow(conn, %{
  88         "authorization" => %{"name" => username, "password" => password, "id" => id}
  89       }) do
  90     followee = Repo.get(User, id)
  91     avatar = User.avatar_url(followee)
  92     name = followee.nickname
  93
  94     with %User{} = user <- User.get_cached_by_nickname(username),
  95          true <- Pbkdf2.checkpw(password, user.password_hash),
  96          %User{} = _followed <- Repo.get(User, id),
  97          {:ok, follower} <- User.follow(user, followee),
  98          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
  99       conn
 100       |> render("followed.html", %{error: false})
 101     else
 102       # Was already following user
 103       {:error, "Could not follow user:" <> _rest} ->
 104         render(conn, "followed.html", %{error: false})
 105
 106       _e ->
 107         conn
 108         |> render("follow_login.html", %{
 109           error: "Wrong username or password",
 110           id: id,
 111           name: name,
 112           avatar: avatar
 113         })
 114     end
 115   end
 116
 117   def do_remote_follow(%{assigns: %{user: user}} = conn, %{"user" => %{"id" => id}}) do
 118     with %User{} = followee <- Repo.get(User, id),
 119          {:ok, follower} <- User.follow(user, followee),
 120          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
 121       conn
 122       |> render("followed.html", %{error: false})
 123     else
 124       # Was already following user
 125       {:error, "Could not follow user:" <> _rest} ->
 126         conn
 127         |> render("followed.html", %{error: false})
 128
 129       e ->
 130         Logger.debug("Remote follow failed with error #{inspect(e)}")
 131
 132         conn
 133         |> render("followed.html", %{error: inspect(e)})
 134     end
 135   end
 136
 137   def config(conn, _params) do
 138     instance = Pleroma.Config.get(:instance)
 139     instance_fe = Pleroma.Config.get(:fe)
 140     instance_chat = Pleroma.Config.get(:chat)
 141
 142     case get_format(conn) do
 143       "xml" ->
 144         response = """
 145         <config>
 146           <site>
 147             <name>#{Keyword.get(instance, :name)}</name>
 148             <site>#{Web.base_url()}</site>
 149             <textlimit>#{Keyword.get(instance, :limit)}</textlimit>
 150             <closed>#{!Keyword.get(instance, :registrations_open)}</closed>
 151           </site>
 152         </config>
 153         """
 154
 155         conn
 156         |> put_resp_content_type("application/xml")
 157         |> send_resp(200, response)
 158
 159       _ ->
 160         data = %{
 161           name: Keyword.get(instance, :name),
 162           description: Keyword.get(instance, :description),
 163           server: Web.base_url(),
 164           textlimit: to_string(Keyword.get(instance, :limit)),
 165           closed: if(Keyword.get(instance, :registrations_open), do: "0", else: "1"),
 166           private: if(Keyword.get(instance, :public, true), do: "0", else: "1")
 167         }
 168
 169         pleroma_fe = %{
 170           theme: Keyword.get(instance_fe, :theme),
 171           background: Keyword.get(instance_fe, :background),
 172           logo: Keyword.get(instance_fe, :logo),
 173           logoMask: Keyword.get(instance_fe, :logo_mask),
 174           logoMargin: Keyword.get(instance_fe, :logo_margin),
 175           redirectRootNoLogin: Keyword.get(instance_fe, :redirect_root_no_login),
 176           redirectRootLogin: Keyword.get(instance_fe, :redirect_root_login),
 177           chatDisabled: !Keyword.get(instance_chat, :enabled),
 178           showInstanceSpecificPanel: Keyword.get(instance_fe, :show_instance_panel),
 179           scopeOptionsEnabled: Keyword.get(instance_fe, :scope_options_enabled),
 180           formattingOptionsEnabled: Keyword.get(instance_fe, :formatting_options_enabled),
 181           collapseMessageWithSubject: Keyword.get(instance_fe, :collapse_message_with_subject),
 182           hidePostStats: Keyword.get(instance_fe, :hide_post_stats),
 183           hideUserStats: Keyword.get(instance_fe, :hide_user_stats)
 184         }
 185
 186         managed_config = Keyword.get(instance, :managed_config)
 187
 188         data =
 189           if managed_config do
 190             data |> Map.put("pleromafe", pleroma_fe)
 191           else
 192             data
 193           end
 194
 195         json(conn, %{site: data})
 196     end
 197   end
 198
 199   def version(conn, _params) do
 200     version = Pleroma.Application.named_version()
 201
 202     case get_format(conn) do
 203       "xml" ->
 204         response = "<version>#{version}</version>"
 205
 206         conn
 207         |> put_resp_content_type("application/xml")
 208         |> send_resp(200, response)
 209
 210       _ ->
 211         json(conn, version)
 212     end
 213   end
 214
 215   def emoji(conn, _params) do
 216     json(conn, Enum.into(Emoji.get_all(), %{}))
 217   end
 218
 219   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 220     follow_import(conn, %{"list" => File.read!(listfile.path)})
 221   end
 222
 223   def follow_import(%{assigns: %{user: user}} = conn, %{"list" => list}) do
 224     Task.start(fn ->
 225       String.split(list)
 226       |> Enum.map(fn account ->
 227         with %User{} = follower <- User.get_cached_by_ap_id(user.ap_id),
 228              %User{} = followed <- User.get_or_fetch(account),
 229              {:ok, follower} <- User.maybe_direct_follow(follower, followed) do
 230           ActivityPub.follow(follower, followed)
 231         else
 232           err -> Logger.debug("follow_import: following #{account} failed with #{inspect(err)}")
 233         end
 234       end)
 235     end)
 236
 237     json(conn, "job started")
 238   end
 239
 240   def change_password(%{assigns: %{user: user}} = conn, params) do
 241     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 242       {:ok, user} ->
 243         with {:ok, _user} <-
 244                User.reset_password(user, %{
 245                  password: params["new_password"],
 246                  password_confirmation: params["new_password_confirmation"]
 247                }) do
 248           json(conn, %{status: "success"})
 249         else
 250           {:error, changeset} ->
 251             {_, {error, _}} = Enum.at(changeset.errors, 0)
 252             json(conn, %{error: "New password #{error}."})
 253
 254           _ ->
 255             json(conn, %{error: "Unable to change password."})
 256         end
 257
 258       {:error, msg} ->
 259         json(conn, %{error: msg})
 260     end
 261   end
 262
 263   def delete_account(%{assigns: %{user: user}} = conn, params) do
 264     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 265       {:ok, user} ->
 266         Task.start(fn -> User.delete(user) end)
 267         json(conn, %{status: "success"})
 268
 269       {:error, msg} ->
 270         json(conn, %{error: msg})
 271     end
 272   end
 273 end