git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UtilController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Config
  11   alias Pleroma.Emoji
  12   alias Pleroma.Healthcheck
  13   alias Pleroma.Notification
  14   alias Pleroma.Plugs.OAuthScopesPlug
  15   alias Pleroma.User
  16   alias Pleroma.Web.CommonAPI
  17   alias Pleroma.Web.WebFinger
  18
  19   plug(Pleroma.Web.FederatingPlug when action == :remote_subscribe)
  20
  21   plug(
  22     OAuthScopesPlug,
  23     %{scopes: ["follow", "write:follows"]}
  24     when action == :follow_import
  25   )
  26
  27   plug(OAuthScopesPlug, %{scopes: ["follow", "write:blocks"]} when action == :blocks_import)
  28
  29   plug(
  30     OAuthScopesPlug,
  31     %{scopes: ["write:accounts"]}
  32     when action in [
  33            :change_email,
  34            :change_password,
  35            :delete_account,
  36            :update_notificaton_settings,
  37            :disable_account
  38          ]
  39   )
  40
  41   plug(OAuthScopesPlug, %{scopes: ["write:notifications"]} when action == :notifications_read)
  42
  43   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  44     with %User{} = user <- User.get_cached_by_nickname(nick),
  45          avatar = User.avatar_url(user) do
  46       conn
  47       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  48     else
  49       _e ->
  50         render(conn, "subscribe.html", %{
  51           nickname: nick,
  52           avatar: nil,
  53           error: "Could not find user"
  54         })
  55     end
  56   end
  57
  58   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  59     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  60          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  61       conn
  62       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  63     else
  64       _e ->
  65         render(conn, "subscribe.html", %{
  66           nickname: nick,
  67           avatar: nil,
  68           error: "Something went wrong."
  69         })
  70     end
  71   end
  72
  73   def notifications_read(%{assigns: %{user: user}} = conn, %{"id" => notification_id}) do
  74     with {:ok, _} <- Notification.read_one(user, notification_id) do
  75       json(conn, %{status: "success"})
  76     else
  77       {:error, message} ->
  78         conn
  79         |> put_resp_content_type("application/json")
  80         |> send_resp(403, Jason.encode!(%{"error" => message}))
  81     end
  82   end
  83
  84   # Deprecated in favor of `/nodeinfo`
  85   # https://git.pleroma.social/pleroma/pleroma/-/merge_requests/2327
  86   # https://git.pleroma.social/pleroma/pleroma-fe/-/merge_requests/1084
  87   def config(conn, _params) do
  88     json(conn, %{
  89       site: %{
  90         textlimit: to_string(Config.get([:instance, :limit])),
  91         vapidPublicKey: Keyword.get(Pleroma.Web.Push.vapid_config(), :public_key)
  92       }
  93     })
  94   end
  95
  96   def frontend_configurations(conn, _params) do
  97     config =
  98       Pleroma.Config.get(:frontend_configurations, %{})
  99       |> Enum.into(%{})
 100
 101     json(conn, config)
 102   end
 103
 104   def emoji(conn, _params) do
 105     emoji =
 106       Enum.reduce(Emoji.get_all(), %{}, fn {code, %Emoji{file: file, tags: tags}}, acc ->
 107         Map.put(acc, code, %{image_url: file, tags: tags})
 108       end)
 109
 110     json(conn, emoji)
 111   end
 112
 113   def update_notificaton_settings(%{assigns: %{user: user}} = conn, params) do
 114     with {:ok, _} <- User.update_notification_settings(user, params) do
 115       json(conn, %{status: "success"})
 116     end
 117   end
 118
 119   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 120     follow_import(conn, %{"list" => File.read!(listfile.path)})
 121   end
 122
 123   def follow_import(%{assigns: %{user: follower}} = conn, %{"list" => list}) do
 124     followed_identifiers =
 125       list
 126       |> String.split("\n")
 127       |> Enum.map(&(&1 |> String.split(",") |> List.first()))
 128       |> List.delete("Account address")
 129       |> Enum.map(&(&1 |> String.trim() |> String.trim_leading("@")))
 130       |> Enum.reject(&(&1 == ""))
 131
 132     User.follow_import(follower, followed_identifiers)
 133     json(conn, "job started")
 134   end
 135
 136   def blocks_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 137     blocks_import(conn, %{"list" => File.read!(listfile.path)})
 138   end
 139
 140   def blocks_import(%{assigns: %{user: blocker}} = conn, %{"list" => list}) do
 141     blocked_identifiers = list |> String.split() |> Enum.map(&String.trim_leading(&1, "@"))
 142     User.blocks_import(blocker, blocked_identifiers)
 143     json(conn, "job started")
 144   end
 145
 146   def change_password(%{assigns: %{user: user}} = conn, params) do
 147     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 148       {:ok, user} ->
 149         with {:ok, _user} <-
 150                User.reset_password(user, %{
 151                  password: params["new_password"],
 152                  password_confirmation: params["new_password_confirmation"]
 153                }) do
 154           json(conn, %{status: "success"})
 155         else
 156           {:error, changeset} ->
 157             {_, {error, _}} = Enum.at(changeset.errors, 0)
 158             json(conn, %{error: "New password #{error}."})
 159
 160           _ ->
 161             json(conn, %{error: "Unable to change password."})
 162         end
 163
 164       {:error, msg} ->
 165         json(conn, %{error: msg})
 166     end
 167   end
 168
 169   def change_email(%{assigns: %{user: user}} = conn, params) do
 170     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 171       {:ok, user} ->
 172         with {:ok, _user} <- User.change_email(user, params["email"]) do
 173           json(conn, %{status: "success"})
 174         else
 175           {:error, changeset} ->
 176             {_, {error, _}} = Enum.at(changeset.errors, 0)
 177             json(conn, %{error: "Email #{error}."})
 178
 179           _ ->
 180             json(conn, %{error: "Unable to change email."})
 181         end
 182
 183       {:error, msg} ->
 184         json(conn, %{error: msg})
 185     end
 186   end
 187
 188   def delete_account(%{assigns: %{user: user}} = conn, params) do
 189     password = params["password"] || ""
 190
 191     case CommonAPI.Utils.confirm_current_password(user, password) do
 192       {:ok, user} ->
 193         User.delete(user)
 194         json(conn, %{status: "success"})
 195
 196       {:error, msg} ->
 197         json(conn, %{error: msg})
 198     end
 199   end
 200
 201   def disable_account(%{assigns: %{user: user}} = conn, params) do
 202     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 203       {:ok, user} ->
 204         User.deactivate_async(user)
 205         json(conn, %{status: "success"})
 206
 207       {:error, msg} ->
 208         json(conn, %{error: msg})
 209     end
 210   end
 211
 212   def captcha(conn, _params) do
 213     json(conn, Pleroma.Captcha.new())
 214   end
 215
 216   def healthcheck(conn, _params) do
 217     with true <- Config.get([:instance, :healthcheck]),
 218          %{healthy: true} = info <- Healthcheck.system_info() do
 219       json(conn, info)
 220     else
 221       %{healthy: false} = info ->
 222         service_unavailable(conn, info)
 223
 224       _ ->
 225         service_unavailable(conn, %{})
 226     end
 227   end
 228
 229   defp service_unavailable(conn, info) do
 230     conn
 231     |> put_status(:service_unavailable)
 232     |> json(info)
 233   end
 234 end