git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UtilController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Config
  11   alias Pleroma.Emoji
  12   alias Pleroma.Healthcheck
  13   alias Pleroma.Notification
  14   alias Pleroma.Plugs.OAuthScopesPlug
  15   alias Pleroma.User
  16   alias Pleroma.Web.CommonAPI
  17   alias Pleroma.Web.WebFinger
  18
  19   plug(Pleroma.Web.FederatingPlug when action == :remote_subscribe)
  20
  21   plug(
  22     OAuthScopesPlug,
  23     %{scopes: ["follow", "write:follows"]}
  24     when action == :follow_import
  25   )
  26
  27   # Note: follower can submit the form (with password auth) not being signed in (having no token)
  28   plug(
  29     OAuthScopesPlug,
  30     %{fallback: :proceed_unauthenticated, scopes: ["follow", "write:follows"]}
  31     when action == :do_remote_follow
  32   )
  33
  34   plug(OAuthScopesPlug, %{scopes: ["follow", "write:blocks"]} when action == :blocks_import)
  35
  36   plug(
  37     OAuthScopesPlug,
  38     %{scopes: ["write:accounts"]}
  39     when action in [
  40            :change_email,
  41            :change_password,
  42            :delete_account,
  43            :update_notificaton_settings,
  44            :disable_account
  45          ]
  46   )
  47
  48   plug(OAuthScopesPlug, %{scopes: ["write:notifications"]} when action == :notifications_read)
  49
  50   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  51     with %User{} = user <- User.get_cached_by_nickname(nick),
  52          avatar = User.avatar_url(user) do
  53       conn
  54       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  55     else
  56       _e ->
  57         render(conn, "subscribe.html", %{
  58           nickname: nick,
  59           avatar: nil,
  60           error: "Could not find user"
  61         })
  62     end
  63   end
  64
  65   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  66     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  67          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  68       conn
  69       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  70     else
  71       _e ->
  72         render(conn, "subscribe.html", %{
  73           nickname: nick,
  74           avatar: nil,
  75           error: "Something went wrong."
  76         })
  77     end
  78   end
  79
  80   def notifications_read(%{assigns: %{user: user}} = conn, %{"id" => notification_id}) do
  81     with {:ok, _} <- Notification.read_one(user, notification_id) do
  82       json(conn, %{status: "success"})
  83     else
  84       {:error, message} ->
  85         conn
  86         |> put_resp_content_type("application/json")
  87         |> send_resp(403, Jason.encode!(%{"error" => message}))
  88     end
  89   end
  90
  91   # Deprecated in favor of `/nodeinfo`
  92   # https://git.pleroma.social/pleroma/pleroma/-/merge_requests/2327
  93   # https://git.pleroma.social/pleroma/pleroma-fe/-/merge_requests/1084
  94   def config(conn, _params) do
  95     json(conn, %{
  96       site: %{
  97         textlimit: to_string(Config.get([:instance, :limit])),
  98         vapidPublicKey: Keyword.get(Pleroma.Web.Push.vapid_config(), :public_key)
  99       }
 100     })
 101   end
 102
 103   def frontend_configurations(conn, _params) do
 104     config =
 105       Pleroma.Config.get(:frontend_configurations, %{})
 106       |> Enum.into(%{})
 107
 108     json(conn, config)
 109   end
 110
 111   def emoji(conn, _params) do
 112     emoji =
 113       Enum.reduce(Emoji.get_all(), %{}, fn {code, %Emoji{file: file, tags: tags}}, acc ->
 114         Map.put(acc, code, %{image_url: file, tags: tags})
 115       end)
 116
 117     json(conn, emoji)
 118   end
 119
 120   def update_notificaton_settings(%{assigns: %{user: user}} = conn, params) do
 121     with {:ok, _} <- User.update_notification_settings(user, params) do
 122       json(conn, %{status: "success"})
 123     end
 124   end
 125
 126   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 127     follow_import(conn, %{"list" => File.read!(listfile.path)})
 128   end
 129
 130   def follow_import(%{assigns: %{user: follower}} = conn, %{"list" => list}) do
 131     with lines <- String.split(list, "\n"),
 132          followed_identifiers <-
 133            Enum.map(lines, fn line ->
 134              String.split(line, ",") |> List.first()
 135            end)
 136            |> List.delete("Account address") do
 137       User.follow_import(follower, followed_identifiers)
 138       json(conn, "job started")
 139     end
 140   end
 141
 142   def blocks_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 143     blocks_import(conn, %{"list" => File.read!(listfile.path)})
 144   end
 145
 146   def blocks_import(%{assigns: %{user: blocker}} = conn, %{"list" => list}) do
 147     with blocked_identifiers <- String.split(list) do
 148       User.blocks_import(blocker, blocked_identifiers)
 149       json(conn, "job started")
 150     end
 151   end
 152
 153   def change_password(%{assigns: %{user: user}} = conn, params) do
 154     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 155       {:ok, user} ->
 156         with {:ok, _user} <-
 157                User.reset_password(user, %{
 158                  password: params["new_password"],
 159                  password_confirmation: params["new_password_confirmation"]
 160                }) do
 161           json(conn, %{status: "success"})
 162         else
 163           {:error, changeset} ->
 164             {_, {error, _}} = Enum.at(changeset.errors, 0)
 165             json(conn, %{error: "New password #{error}."})
 166
 167           _ ->
 168             json(conn, %{error: "Unable to change password."})
 169         end
 170
 171       {:error, msg} ->
 172         json(conn, %{error: msg})
 173     end
 174   end
 175
 176   def change_email(%{assigns: %{user: user}} = conn, params) do
 177     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 178       {:ok, user} ->
 179         with {:ok, _user} <- User.change_email(user, params["email"]) do
 180           json(conn, %{status: "success"})
 181         else
 182           {:error, changeset} ->
 183             {_, {error, _}} = Enum.at(changeset.errors, 0)
 184             json(conn, %{error: "Email #{error}."})
 185
 186           _ ->
 187             json(conn, %{error: "Unable to change email."})
 188         end
 189
 190       {:error, msg} ->
 191         json(conn, %{error: msg})
 192     end
 193   end
 194
 195   def delete_account(%{assigns: %{user: user}} = conn, params) do
 196     password = params["password"] || ""
 197
 198     case CommonAPI.Utils.confirm_current_password(user, password) do
 199       {:ok, user} ->
 200         User.delete(user)
 201         json(conn, %{status: "success"})
 202
 203       {:error, msg} ->
 204         json(conn, %{error: msg})
 205     end
 206   end
 207
 208   def disable_account(%{assigns: %{user: user}} = conn, params) do
 209     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 210       {:ok, user} ->
 211         User.deactivate_async(user)
 212         json(conn, %{status: "success"})
 213
 214       {:error, msg} ->
 215         json(conn, %{error: msg})
 216     end
 217   end
 218
 219   def captcha(conn, _params) do
 220     json(conn, Pleroma.Captcha.new())
 221   end
 222
 223   def healthcheck(conn, _params) do
 224     with true <- Config.get([:instance, :healthcheck]),
 225          %{healthy: true} = info <- Healthcheck.system_info() do
 226       json(conn, info)
 227     else
 228       %{healthy: false} = info ->
 229         service_unavailable(conn, info)
 230
 231       _ ->
 232         service_unavailable(conn, %{})
 233     end
 234   end
 235
 236   defp service_unavailable(conn, info) do
 237     conn
 238     |> put_status(:service_unavailable)
 239     |> json(info)
 240   end
 241 end