git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.UtilController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4   alias Pleroma.Web
   5   alias Pleroma.Web.OStatus
   6   alias Pleroma.Web.WebFinger
   7   alias Pleroma.Web.CommonAPI
   8   alias Comeonin.Pbkdf2
   9   alias Pleroma.{Formatter, Emoji}
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.{Repo, PasswordResetToken, User}
  12
  13   def show_password_reset(conn, %{"token" => token}) do
  14     with %{used: false} = token <- Repo.get_by(PasswordResetToken, %{token: token}),
  15          %User{} = user <- Repo.get(User, token.user_id) do
  16       render(conn, "password_reset.html", %{
  17         token: token,
  18         user: user
  19       })
  20     else
  21       _e -> render(conn, "invalid_token.html")
  22     end
  23   end
  24
  25   def password_reset(conn, %{"data" => data}) do
  26     with {:ok, _} <- PasswordResetToken.reset_password(data["token"], data) do
  27       render(conn, "password_reset_success.html")
  28     else
  29       _e -> render(conn, "password_reset_failed.html")
  30     end
  31   end
  32
  33   def help_test(conn, _params) do
  34     json(conn, "ok")
  35   end
  36
  37   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  38     with %User{} = user <- User.get_cached_by_nickname(nick), avatar = User.avatar_url(user) do
  39       conn
  40       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  41     else
  42       _e ->
  43         render(conn, "subscribe.html", %{
  44           nickname: nick,
  45           avatar: nil,
  46           error: "Could not find user"
  47         })
  48     end
  49   end
  50
  51   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  52     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  53          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  54       conn
  55       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  56     else
  57       _e ->
  58         render(conn, "subscribe.html", %{
  59           nickname: nick,
  60           avatar: nil,
  61           error: "Something went wrong."
  62         })
  63     end
  64   end
  65
  66   def remote_follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  67     {err, followee} = OStatus.find_or_make_user(acct)
  68     avatar = User.avatar_url(followee)
  69     name = followee.nickname
  70     id = followee.id
  71
  72     if !!user do
  73       conn
  74       |> render("follow.html", %{error: err, acct: acct, avatar: avatar, name: name, id: id})
  75     else
  76       conn
  77       |> render("follow_login.html", %{
  78         error: false,
  79         acct: acct,
  80         avatar: avatar,
  81         name: name,
  82         id: id
  83       })
  84     end
  85   end
  86
  87   def do_remote_follow(conn, %{
  88         "authorization" => %{"name" => username, "password" => password, "id" => id}
  89       }) do
  90     followee = Repo.get(User, id)
  91     avatar = User.avatar_url(followee)
  92     name = followee.nickname
  93
  94     with %User{} = user <- User.get_cached_by_nickname(username),
  95          true <- Pbkdf2.checkpw(password, user.password_hash),
  96          %User{} = _followed <- Repo.get(User, id),
  97          {:ok, follower} <- User.follow(user, followee),
  98          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
  99       conn
 100       |> render("followed.html", %{error: false})
 101     else
 102       # Was already following user
 103       {:error, "Could not follow user:" <> _rest} ->
 104         render(conn, "followed.html", %{error: false})
 105
 106       _e ->
 107         conn
 108         |> render("follow_login.html", %{
 109           error: "Wrong username or password",
 110           id: id,
 111           name: name,
 112           avatar: avatar
 113         })
 114     end
 115   end
 116
 117   def do_remote_follow(%{assigns: %{user: user}} = conn, %{"user" => %{"id" => id}}) do
 118     with %User{} = followee <- Repo.get(User, id),
 119          {:ok, follower} <- User.follow(user, followee),
 120          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
 121       conn
 122       |> render("followed.html", %{error: false})
 123     else
 124       # Was already following user
 125       {:error, "Could not follow user:" <> _rest} ->
 126         conn
 127         |> render("followed.html", %{error: false})
 128
 129       e ->
 130         Logger.debug("Remote follow failed with error #{inspect(e)}")
 131
 132         conn
 133         |> render("followed.html", %{error: inspect(e)})
 134     end
 135   end
 136
 137   def config(conn, _params) do
 138     instance = Pleroma.Config.get(:instance)
 139     instance_fe = Pleroma.Config.get(:fe)
 140     instance_chat = Pleroma.Config.get(:chat)
 141
 142     case get_format(conn) do
 143       "xml" ->
 144         response = """
 145         <config>
 146           <site>
 147             <name>#{Keyword.get(instance, :name)}</name>
 148             <site>#{Web.base_url()}</site>
 149             <textlimit>#{Keyword.get(instance, :limit)}</textlimit>
 150             <closed>#{!Keyword.get(instance, :registrations_open)}</closed>
 151           </site>
 152         </config>
 153         """
 154
 155         conn
 156         |> put_resp_content_type("application/xml")
 157         |> send_resp(200, response)
 158
 159       _ ->
 160         vapid_public_key =
 161           Keyword.get(Application.get_env(:web_push_encryption, :vapid_details), :public_key)
 162
 163         data = %{
 164           name: Keyword.get(instance, :name),
 165           description: Keyword.get(instance, :description),
 166           server: Web.base_url(),
 167           textlimit: to_string(Keyword.get(instance, :limit)),
 168           closed: if(Keyword.get(instance, :registrations_open), do: "0", else: "1"),
 169           private: if(Keyword.get(instance, :public, true), do: "0", else: "1"),
 170           vapidPublicKey: vapid_public_key
 171         }
 172
 173         pleroma_fe = %{
 174           theme: Keyword.get(instance_fe, :theme),
 175           background: Keyword.get(instance_fe, :background),
 176           logo: Keyword.get(instance_fe, :logo),
 177           logoMask: Keyword.get(instance_fe, :logo_mask),
 178           logoMargin: Keyword.get(instance_fe, :logo_margin),
 179           redirectRootNoLogin: Keyword.get(instance_fe, :redirect_root_no_login),
 180           redirectRootLogin: Keyword.get(instance_fe, :redirect_root_login),
 181           chatDisabled: !Keyword.get(instance_chat, :enabled),
 182           showInstanceSpecificPanel: Keyword.get(instance_fe, :show_instance_panel),
 183           scopeOptionsEnabled: Keyword.get(instance_fe, :scope_options_enabled),
 184           formattingOptionsEnabled: Keyword.get(instance_fe, :formatting_options_enabled),
 185           collapseMessageWithSubject: Keyword.get(instance_fe, :collapse_message_with_subject),
 186           hidePostStats: Keyword.get(instance_fe, :hide_post_stats),
 187           hideUserStats: Keyword.get(instance_fe, :hide_user_stats)
 188         }
 189
 190         managed_config = Keyword.get(instance, :managed_config)
 191
 192         data =
 193           if managed_config do
 194             data |> Map.put("pleromafe", pleroma_fe)
 195           else
 196             data
 197           end
 198
 199         json(conn, %{site: data})
 200     end
 201   end
 202
 203   def version(conn, _params) do
 204     version = Pleroma.Application.named_version()
 205
 206     case get_format(conn) do
 207       "xml" ->
 208         response = "<version>#{version}</version>"
 209
 210         conn
 211         |> put_resp_content_type("application/xml")
 212         |> send_resp(200, response)
 213
 214       _ ->
 215         json(conn, version)
 216     end
 217   end
 218
 219   def emoji(conn, _params) do
 220     json(conn, Enum.into(Emoji.get_all(), %{}))
 221   end
 222
 223   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 224     follow_import(conn, %{"list" => File.read!(listfile.path)})
 225   end
 226
 227   def follow_import(%{assigns: %{user: user}} = conn, %{"list" => list}) do
 228     Task.start(fn ->
 229       String.split(list)
 230       |> Enum.map(fn account ->
 231         with %User{} = follower <- User.get_cached_by_ap_id(user.ap_id),
 232              %User{} = followed <- User.get_or_fetch(account),
 233              {:ok, follower} <- User.maybe_direct_follow(follower, followed) do
 234           ActivityPub.follow(follower, followed)
 235         else
 236           err -> Logger.debug("follow_import: following #{account} failed with #{inspect(err)}")
 237         end
 238       end)
 239     end)
 240
 241     json(conn, "job started")
 242   end
 243
 244   def change_password(%{assigns: %{user: user}} = conn, params) do
 245     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 246       {:ok, user} ->
 247         with {:ok, _user} <-
 248                User.reset_password(user, %{
 249                  password: params["new_password"],
 250                  password_confirmation: params["new_password_confirmation"]
 251                }) do
 252           json(conn, %{status: "success"})
 253         else
 254           {:error, changeset} ->
 255             {_, {error, _}} = Enum.at(changeset.errors, 0)
 256             json(conn, %{error: "New password #{error}."})
 257
 258           _ ->
 259             json(conn, %{error: "Unable to change password."})
 260         end
 261
 262       {:error, msg} ->
 263         json(conn, %{error: msg})
 264     end
 265   end
 266
 267   def delete_account(%{assigns: %{user: user}} = conn, params) do
 268     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 269       {:ok, user} ->
 270         Task.start(fn -> User.delete(user) end)
 271         json(conn, %{status: "success"})
 272
 273       {:error, msg} ->
 274         json(conn, %{error: msg})
 275     end
 276   end
 277 end