git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/remote_follow_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.RemoteFollowController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Activity
  11   alias Pleroma.Object.Fetcher
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.User
  14   alias Pleroma.Web.Auth.Authenticator
  15   alias Pleroma.Web.CommonAPI
  16
  17   @status_types ["Article", "Event", "Note", "Video", "Page", "Question"]
  18
  19   plug(Pleroma.Web.FederatingPlug)
  20
  21   # Note: follower can submit the form (with password auth) not being signed in (having no token)
  22   plug(
  23     OAuthScopesPlug,
  24     %{fallback: :proceed_unauthenticated, scopes: ["follow", "write:follows"]}
  25     when action in [:do_follow]
  26   )
  27
  28   # GET /ostatus_subscribe
  29   #
  30   def follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  31     case is_status?(acct) do
  32       true -> follow_status(conn, user, acct)
  33       _ -> follow_account(conn, user, acct)
  34     end
  35   end
  36
  37   defp follow_status(conn, _user, acct) do
  38     with {:ok, object} <- Fetcher.fetch_object_from_id(acct),
  39          %Activity{id: activity_id} <- Activity.get_create_by_object_ap_id(object.data["id"]) do
  40       redirect(conn, to: o_status_path(conn, :notice, activity_id))
  41     else
  42       error ->
  43         handle_follow_error(conn, error)
  44     end
  45   end
  46
  47   defp follow_account(conn, user, acct) do
  48     with {:ok, followee} <- User.get_or_fetch(acct) do
  49       render(conn, follow_template(user), %{error: false, followee: followee, acct: acct})
  50     else
  51       {:error, _reason} ->
  52         render(conn, follow_template(user), %{error: :error})
  53     end
  54   end
  55
  56   defp follow_template(%User{} = _user), do: "follow.html"
  57   defp follow_template(_), do: "follow_login.html"
  58
  59   defp is_status?(acct) do
  60     case Fetcher.fetch_and_contain_remote_object_from_id(acct) do
  61       {:ok, %{"type" => type}} when type in @status_types ->
  62         true
  63
  64       _ ->
  65         false
  66     end
  67   end
  68
  69   # POST  /ostatus_subscribe
  70   #
  71   def do_follow(%{assigns: %{user: %User{} = user}} = conn, %{"user" => %{"id" => id}}) do
  72     with {:fetch_user, %User{} = followee} <- {:fetch_user, User.get_cached_by_id(id)},
  73          {:ok, _, _, _} <- CommonAPI.follow(user, followee) do
  74       redirect(conn, to: "/users/#{followee.id}")
  75     else
  76       error ->
  77         handle_follow_error(conn, error)
  78     end
  79   end
  80
  81   def do_follow(conn, %{"authorization" => %{"name" => _, "password" => _, "id" => id}}) do
  82     with {:fetch_user, %User{} = followee} <- {:fetch_user, User.get_cached_by_id(id)},
  83          {_, {:ok, user}, _} <- {:auth, Authenticator.get_user(conn), followee},
  84          {:ok, _, _, _} <- CommonAPI.follow(user, followee) do
  85       redirect(conn, to: "/users/#{followee.id}")
  86     else
  87       error ->
  88         handle_follow_error(conn, error)
  89     end
  90   end
  91
  92   def do_follow(%{assigns: %{user: nil}} = conn, _) do
  93     Logger.debug("Insufficient permissions: follow | write:follows.")
  94     render(conn, "followed.html", %{error: "Insufficient permissions: follow | write:follows."})
  95   end
  96
  97   defp handle_follow_error(conn, {:auth, _, followee} = _) do
  98     render(conn, "follow_login.html", %{error: "Wrong username or password", followee: followee})
  99   end
 100
 101   defp handle_follow_error(conn, {:fetch_user, error} = _) do
 102     Logger.debug("Remote follow failed with error #{inspect(error)}")
 103     render(conn, "followed.html", %{error: "Could not find user"})
 104   end
 105
 106   defp handle_follow_error(conn, {:error, "Could not follow user:" <> _} = _) do
 107     render(conn, "followed.html", %{error: "Error following account"})
 108   end
 109
 110   defp handle_follow_error(conn, error) do
 111     Logger.debug("Remote follow failed with error #{inspect(error)}")
 112     render(conn, "followed.html", %{error: "Something went wrong."})
 113   end
 114 end