git.squeep.com Git - akkoma/blob - lib/pleroma/web/static_fe/static_fe_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StaticFE.StaticFEController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.Metadata
  14   alias Pleroma.Web.Router.Helpers
  15
  16   plug(:put_layout, :static_fe)
  17   plug(:put_view, Pleroma.Web.StaticFE.StaticFEView)
  18   plug(:assign_id)
  19
  20   plug(Pleroma.Plugs.EnsureAuthenticatedPlug,
  21     unless_func: &Pleroma.Web.FederatingPlug.federating?/0
  22   )
  23
  24   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  25
  26   defp get_title(%Object{data: %{"name" => name}}) when is_binary(name),
  27     do: name
  28
  29   defp get_title(%Object{data: %{"summary" => summary}}) when is_binary(summary),
  30     do: summary
  31
  32   defp get_title(_), do: nil
  33
  34   defp not_found(conn, message) do
  35     conn
  36     |> put_status(404)
  37     |> render("error.html", %{message: message, meta: ""})
  38   end
  39
  40   defp get_counts(%Activity{} = activity) do
  41     %Object{data: data} = Object.normalize(activity)
  42
  43     %{
  44       likes: data["like_count"] || 0,
  45       replies: data["repliesCount"] || 0,
  46       announces: data["announcement_count"] || 0
  47     }
  48   end
  49
  50   defp represent(%Activity{} = activity), do: represent(activity, false)
  51
  52   defp represent(%Activity{object: %Object{data: data}} = activity, selected) do
  53     {:ok, user} = User.get_or_fetch(activity.object.data["actor"])
  54
  55     link =
  56       case user.local do
  57         true -> Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
  58         _ -> data["url"] || data["external_url"] || data["id"]
  59       end
  60
  61     %{
  62       user: user,
  63       title: get_title(activity.object),
  64       content: data["content"] || nil,
  65       attachment: data["attachment"],
  66       link: link,
  67       published: data["published"],
  68       sensitive: data["sensitive"],
  69       selected: selected,
  70       counts: get_counts(activity),
  71       id: activity.id
  72     }
  73   end
  74
  75   def show(%{assigns: %{notice_id: notice_id}} = conn, _params) do
  76     with %Activity{local: true} = activity <-
  77            Activity.get_by_id_with_object(notice_id),
  78          true <- Visibility.is_public?(activity.object),
  79          %User{} = user <- User.get_by_ap_id(activity.object.data["actor"]) do
  80       meta = Metadata.build_tags(%{activity_id: notice_id, object: activity.object, user: user})
  81
  82       timeline =
  83         activity.object.data["context"]
  84         |> ActivityPub.fetch_activities_for_context(%{})
  85         |> Enum.reverse()
  86         |> Enum.map(&represent(&1, &1.object.id == activity.object.id))
  87
  88       render(conn, "conversation.html", %{activities: timeline, meta: meta})
  89     else
  90       %Activity{object: %Object{data: data}} ->
  91         conn
  92         |> put_status(:found)
  93         |> redirect(external: data["url"] || data["external_url"] || data["id"])
  94
  95       _ ->
  96         not_found(conn, "Post not found.")
  97     end
  98   end
  99
 100   def show(%{assigns: %{username_or_id: username_or_id}} = conn, params) do
 101     case User.get_cached_by_nickname_or_id(username_or_id) do
 102       %User{} = user ->
 103         meta = Metadata.build_tags(%{user: user})
 104
 105         timeline =
 106           ActivityPub.fetch_user_activities(user, nil, Map.take(params, @page_keys))
 107           |> Enum.map(&represent/1)
 108
 109         prev_page_id =
 110           (params["min_id"] || params["max_id"]) &&
 111             List.first(timeline) && List.first(timeline).id
 112
 113         next_page_id = List.last(timeline) && List.last(timeline).id
 114
 115         render(conn, "profile.html", %{
 116           user: user,
 117           timeline: timeline,
 118           prev_page_id: prev_page_id,
 119           next_page_id: next_page_id,
 120           meta: meta
 121         })
 122
 123       _ ->
 124         not_found(conn, "User not found.")
 125     end
 126   end
 127
 128   def show(%{assigns: %{object_id: _}} = conn, _params) do
 129     url = Helpers.url(conn) <> conn.request_path
 130
 131     case Activity.get_create_by_object_ap_id_with_object(url) do
 132       %Activity{} = activity ->
 133         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
 134         redirect(conn, to: to)
 135
 136       _ ->
 137         not_found(conn, "Post not found.")
 138     end
 139   end
 140
 141   def show(%{assigns: %{activity_id: _}} = conn, _params) do
 142     url = Helpers.url(conn) <> conn.request_path
 143
 144     case Activity.get_by_ap_id(url) do
 145       %Activity{} = activity ->
 146         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
 147         redirect(conn, to: to)
 148
 149       _ ->
 150         not_found(conn, "Post not found.")
 151     end
 152   end
 153
 154   defp assign_id(%{path_info: ["notice", notice_id]} = conn, _opts),
 155     do: assign(conn, :notice_id, notice_id)
 156
 157   defp assign_id(%{path_info: ["users", user_id]} = conn, _opts),
 158     do: assign(conn, :username_or_id, user_id)
 159
 160   defp assign_id(%{path_info: ["objects", object_id]} = conn, _opts),
 161     do: assign(conn, :object_id, object_id)
 162
 163   defp assign_id(%{path_info: ["activities", activity_id]} = conn, _opts),
 164     do: assign(conn, :activity_id, activity_id)
 165
 166   defp assign_id(conn, _opts), do: conn
 167 end