git.squeep.com Git - akkoma/blob - lib/pleroma/web/static_fe/static_fe_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StaticFE.StaticFEController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.Metadata
  14   alias Pleroma.Web.Router.Helpers
  15
  16   plug(:put_layout, :static_fe)
  17   plug(:put_view, Pleroma.Web.StaticFE.StaticFEView)
  18   plug(:assign_id)
  19
  20   plug(Pleroma.Web.Plugs.EnsureAuthenticatedPlug,
  21     unless_func: &Pleroma.Web.Plugs.FederatingPlug.federating?/1
  22   )
  23
  24   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  25
  26   defp get_title(%Object{data: %{"name" => name}}) when is_binary(name),
  27     do: name
  28
  29   defp get_title(%Object{data: %{"summary" => summary}}) when is_binary(summary),
  30     do: summary
  31
  32   defp get_title(_), do: nil
  33
  34   defp not_found(conn, message) do
  35     conn
  36     |> put_status(404)
  37     |> render("error.html", %{message: message, meta: ""})
  38   end
  39
  40   defp get_counts(%Activity{} = activity) do
  41     %Object{data: data} = Object.normalize(activity)
  42
  43     %{
  44       likes: data["like_count"] || 0,
  45       replies: data["repliesCount"] || 0,
  46       announces: data["announcement_count"] || 0
  47     }
  48   end
  49
  50   defp represent(%Activity{} = activity), do: represent(activity, false)
  51
  52   defp represent(%Activity{object: %Object{data: data}} = activity, selected) do
  53     {:ok, user} = User.get_or_fetch(activity.object.data["actor"])
  54
  55     link =
  56       case user.local do
  57         true -> Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
  58         _ -> data["url"] || data["external_url"] || data["id"]
  59       end
  60
  61     content =
  62       if data["content"] do
  63         data["content"]
  64         |> Pleroma.HTML.filter_tags()
  65         |> Pleroma.Emoji.Formatter.emojify(Map.get(data, "emoji", %{}))
  66       else
  67         nil
  68       end
  69
  70     %{
  71       user: User.sanitize_html(user),
  72       title: get_title(activity.object),
  73       content: content,
  74       attachment: data["attachment"],
  75       link: link,
  76       published: data["published"],
  77       sensitive: data["sensitive"],
  78       selected: selected,
  79       counts: get_counts(activity),
  80       id: activity.id
  81     }
  82   end
  83
  84   def show(%{assigns: %{notice_id: notice_id}} = conn, _params) do
  85     with %Activity{local: true} = activity <-
  86            Activity.get_by_id_with_object(notice_id),
  87          true <- Visibility.is_public?(activity.object),
  88          %User{} = user <- User.get_by_ap_id(activity.object.data["actor"]) do
  89       meta = Metadata.build_tags(%{activity_id: notice_id, object: activity.object, user: user})
  90
  91       timeline =
  92         activity.object.data["context"]
  93         |> ActivityPub.fetch_activities_for_context(%{})
  94         |> Enum.reverse()
  95         |> Enum.map(&represent(&1, &1.object.id == activity.object.id))
  96
  97       render(conn, "conversation.html", %{activities: timeline, meta: meta})
  98     else
  99       %Activity{object: %Object{data: data}} ->
 100         conn
 101         |> put_status(:found)
 102         |> redirect(external: data["url"] || data["external_url"] || data["id"])
 103
 104       _ ->
 105         not_found(conn, "Post not found.")
 106     end
 107   end
 108
 109   def show(%{assigns: %{username_or_id: username_or_id}} = conn, params) do
 110     case User.get_cached_by_nickname_or_id(username_or_id) do
 111       %User{} = user ->
 112         meta = Metadata.build_tags(%{user: user})
 113
 114         params =
 115           params
 116           |> Map.take(@page_keys)
 117           |> Map.new(fn {k, v} -> {String.to_existing_atom(k), v} end)
 118
 119         timeline =
 120           user
 121           |> ActivityPub.fetch_user_activities(nil, params)
 122           |> Enum.map(&represent/1)
 123
 124         prev_page_id =
 125           (params["min_id"] || params["max_id"]) &&
 126             List.first(timeline) && List.first(timeline).id
 127
 128         next_page_id = List.last(timeline) && List.last(timeline).id
 129
 130         render(conn, "profile.html", %{
 131           user: User.sanitize_html(user),
 132           timeline: timeline,
 133           prev_page_id: prev_page_id,
 134           next_page_id: next_page_id,
 135           meta: meta
 136         })
 137
 138       _ ->
 139         not_found(conn, "User not found.")
 140     end
 141   end
 142
 143   def show(%{assigns: %{object_id: _}} = conn, _params) do
 144     url = Helpers.url(conn) <> conn.request_path
 145
 146     case Activity.get_create_by_object_ap_id_with_object(url) do
 147       %Activity{} = activity ->
 148         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
 149         redirect(conn, to: to)
 150
 151       _ ->
 152         not_found(conn, "Post not found.")
 153     end
 154   end
 155
 156   def show(%{assigns: %{activity_id: _}} = conn, _params) do
 157     url = Helpers.url(conn) <> conn.request_path
 158
 159     case Activity.get_by_ap_id(url) do
 160       %Activity{} = activity ->
 161         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
 162         redirect(conn, to: to)
 163
 164       _ ->
 165         not_found(conn, "Post not found.")
 166     end
 167   end
 168
 169   defp assign_id(%{path_info: ["notice", notice_id]} = conn, _opts),
 170     do: assign(conn, :notice_id, notice_id)
 171
 172   defp assign_id(%{path_info: ["users", user_id]} = conn, _opts),
 173     do: assign(conn, :username_or_id, user_id)
 174
 175   defp assign_id(%{path_info: ["objects", object_id]} = conn, _opts),
 176     do: assign(conn, :object_id, object_id)
 177
 178   defp assign_id(%{path_info: ["activities", activity_id]} = conn, _opts),
 179     do: assign(conn, :activity_id, activity_id)
 180
 181   defp assign_id(conn, _opts), do: conn
 182 end