git.squeep.com Git - akkoma/blob - lib/pleroma/web/static_fe/static_fe_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StaticFE.StaticFEController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.Metadata
  14   alias Pleroma.Web.Router.Helpers
  15
  16   plug(:put_layout, :static_fe)
  17   plug(:put_view, Pleroma.Web.StaticFE.StaticFEView)
  18   plug(:assign_id)
  19
  20   plug(Pleroma.Plugs.EnsureAuthenticatedPlug,
  21     unless_func: &Pleroma.Web.FederatingPlug.federating?/0
  22   )
  23
  24   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  25
  26   defp get_title(%Object{data: %{"name" => name}}) when is_binary(name),
  27     do: name
  28
  29   defp get_title(%Object{data: %{"summary" => summary}}) when is_binary(summary),
  30     do: summary
  31
  32   defp get_title(_), do: nil
  33
  34   defp not_found(conn, message) do
  35     conn
  36     |> put_status(404)
  37     |> render("error.html", %{message: message, meta: ""})
  38   end
  39
  40   defp get_counts(%Activity{} = activity) do
  41     %Object{data: data} = Object.normalize(activity)
  42
  43     %{
  44       likes: data["like_count"] || 0,
  45       replies: data["repliesCount"] || 0,
  46       announces: data["announcement_count"] || 0
  47     }
  48   end
  49
  50   defp represent(%Activity{} = activity), do: represent(activity, false)
  51
  52   defp represent(%Activity{object: %Object{data: data}} = activity, selected) do
  53     {:ok, user} = User.get_or_fetch(activity.object.data["actor"])
  54
  55     link =
  56       case user.local do
  57         true -> Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
  58         _ -> data["url"] || data["external_url"] || data["id"]
  59       end
  60
  61     content =
  62       if data["content"] do
  63         Pleroma.HTML.filter_tags(data["content"])
  64       else
  65         nil
  66       end
  67
  68     %{
  69       user: User.sanitize_html(user),
  70       title: get_title(activity.object),
  71       content: content,
  72       attachment: data["attachment"],
  73       link: link,
  74       published: data["published"],
  75       sensitive: data["sensitive"],
  76       selected: selected,
  77       counts: get_counts(activity),
  78       id: activity.id
  79     }
  80   end
  81
  82   def show(%{assigns: %{notice_id: notice_id}} = conn, _params) do
  83     with %Activity{local: true} = activity <-
  84            Activity.get_by_id_with_object(notice_id),
  85          true <- Visibility.is_public?(activity.object),
  86          %User{} = user <- User.get_by_ap_id(activity.object.data["actor"]) do
  87       meta = Metadata.build_tags(%{activity_id: notice_id, object: activity.object, user: user})
  88
  89       timeline =
  90         activity.object.data["context"]
  91         |> ActivityPub.fetch_activities_for_context(%{})
  92         |> Enum.reverse()
  93         |> Enum.map(&represent(&1, &1.object.id == activity.object.id))
  94
  95       render(conn, "conversation.html", %{activities: timeline, meta: meta})
  96     else
  97       %Activity{object: %Object{data: data}} ->
  98         conn
  99         |> put_status(:found)
 100         |> redirect(external: data["url"] || data["external_url"] || data["id"])
 101
 102       _ ->
 103         not_found(conn, "Post not found.")
 104     end
 105   end
 106
 107   def show(%{assigns: %{username_or_id: username_or_id}} = conn, params) do
 108     case User.get_cached_by_nickname_or_id(username_or_id) do
 109       %User{} = user ->
 110         meta = Metadata.build_tags(%{user: user})
 111
 112         timeline =
 113           ActivityPub.fetch_user_activities(user, nil, Map.take(params, @page_keys))
 114           |> Enum.map(&represent/1)
 115
 116         prev_page_id =
 117           (params["min_id"] || params["max_id"]) &&
 118             List.first(timeline) && List.first(timeline).id
 119
 120         next_page_id = List.last(timeline) && List.last(timeline).id
 121
 122         render(conn, "profile.html", %{
 123           user: User.sanitize_html(user),
 124           timeline: timeline,
 125           prev_page_id: prev_page_id,
 126           next_page_id: next_page_id,
 127           meta: meta
 128         })
 129
 130       _ ->
 131         not_found(conn, "User not found.")
 132     end
 133   end
 134
 135   def show(%{assigns: %{object_id: _}} = conn, _params) do
 136     url = Helpers.url(conn) <> conn.request_path
 137
 138     case Activity.get_create_by_object_ap_id_with_object(url) do
 139       %Activity{} = activity ->
 140         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
 141         redirect(conn, to: to)
 142
 143       _ ->
 144         not_found(conn, "Post not found.")
 145     end
 146   end
 147
 148   def show(%{assigns: %{activity_id: _}} = conn, _params) do
 149     url = Helpers.url(conn) <> conn.request_path
 150
 151     case Activity.get_by_ap_id(url) do
 152       %Activity{} = activity ->
 153         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
 154         redirect(conn, to: to)
 155
 156       _ ->
 157         not_found(conn, "Post not found.")
 158     end
 159   end
 160
 161   defp assign_id(%{path_info: ["notice", notice_id]} = conn, _opts),
 162     do: assign(conn, :notice_id, notice_id)
 163
 164   defp assign_id(%{path_info: ["users", user_id]} = conn, _opts),
 165     do: assign(conn, :username_or_id, user_id)
 166
 167   defp assign_id(%{path_info: ["objects", object_id]} = conn, _opts),
 168     do: assign(conn, :object_id, object_id)
 169
 170   defp assign_id(%{path_info: ["activities", activity_id]} = conn, _opts),
 171     do: assign(conn, :activity_id, activity_id)
 172
 173   defp assign_id(conn, _opts), do: conn
 174 end