git.squeep.com Git - akkoma/blob - lib/pleroma/web/static_fe/static_fe_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StaticFE.StaticFEController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.Metadata
  14   alias Pleroma.Web.Router.Helpers
  15
  16   plug(:put_layout, :static_fe)
  17   plug(:put_view, Pleroma.Web.StaticFE.StaticFEView)
  18   plug(:assign_id)
  19
  20   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  21
  22   @doc "Renders requested local public activity"
  23   def show(%{assigns: %{notice_id: notice_id}} = conn, _params) do
  24     with %Activity{local: true} = activity <-
  25            Activity.get_by_id_with_object(notice_id),
  26          true <- Visibility.is_public?(activity.object),
  27          {_, true} <- {:visible?, Visibility.visible_for_user?(activity, _reading_user = nil)},
  28          %User{} = user <- User.get_by_ap_id(activity.object.data["actor"]) do
  29       meta = Metadata.build_tags(%{activity_id: notice_id, object: activity.object, user: user})
  30
  31       timeline =
  32         activity.object.data["context"]
  33         |> ActivityPub.fetch_activities_for_context(%{})
  34         |> Enum.reverse()
  35         |> Enum.map(&represent(&1, &1.object.id == activity.object.id))
  36
  37       render(conn, "conversation.html", %{activities: timeline, meta: meta})
  38     else
  39       %Activity{object: %Object{data: data}} ->
  40         conn
  41         |> put_status(:found)
  42         |> redirect(external: data["url"] || data["external_url"] || data["id"])
  43
  44       _ ->
  45         not_found(conn, "Post not found.")
  46     end
  47   end
  48
  49   @doc "Renders public activities of requested user"
  50   def show(%{assigns: %{username_or_id: username_or_id}} = conn, params) do
  51     with {_, %User{local: true} = user} <-
  52            {:fetch_user, User.get_cached_by_nickname_or_id(username_or_id)},
  53          {_, :visible} <- {:visibility, User.visible_for(user, _reading_user = nil)} do
  54       meta = Metadata.build_tags(%{user: user})
  55
  56       params =
  57         params
  58         |> Map.take(@page_keys)
  59         |> Map.new(fn {k, v} -> {String.to_existing_atom(k), v} end)
  60
  61       timeline =
  62         user
  63         |> ActivityPub.fetch_user_activities(_reading_user = nil, params)
  64         |> Enum.map(&represent/1)
  65
  66       prev_page_id =
  67         (params["min_id"] || params["max_id"]) &&
  68           List.first(timeline) && List.first(timeline).id
  69
  70       next_page_id = List.last(timeline) && List.last(timeline).id
  71
  72       render(conn, "profile.html", %{
  73         user: User.sanitize_html(user),
  74         timeline: timeline,
  75         prev_page_id: prev_page_id,
  76         next_page_id: next_page_id,
  77         meta: meta
  78       })
  79     else
  80       _ ->
  81         not_found(conn, "User not found.")
  82     end
  83   end
  84
  85   def show(%{assigns: %{object_id: _}} = conn, _params) do
  86     url = Helpers.url(conn) <> conn.request_path
  87
  88     case Activity.get_create_by_object_ap_id_with_object(url) do
  89       %Activity{} = activity ->
  90         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
  91         redirect(conn, to: to)
  92
  93       _ ->
  94         not_found(conn, "Post not found.")
  95     end
  96   end
  97
  98   def show(%{assigns: %{activity_id: _}} = conn, _params) do
  99     url = Helpers.url(conn) <> conn.request_path
 100
 101     case Activity.get_by_ap_id(url) do
 102       %Activity{} = activity ->
 103         to = Helpers.o_status_path(Pleroma.Web.Endpoint, :notice, activity)
 104         redirect(conn, to: to)
 105
 106       _ ->
 107         not_found(conn, "Post not found.")
 108     end
 109   end
 110
 111   defp get_title(%Object{data: %{"name" => name}}) when is_binary(name),
 112     do: name
 113
 114   defp get_title(%Object{data: %{"summary" => summary}}) when is_binary(summary),
 115     do: summary
 116
 117   defp get_title(_), do: nil
 118
 119   defp not_found(conn, message) do
 120     conn
 121     |> put_status(404)
 122     |> render("error.html", %{message: message, meta: ""})
 123   end
 124
 125   defp get_counts(%Activity{} = activity) do
 126     %Object{data: data} = Object.normalize(activity)
 127
 128     %{
 129       likes: data["like_count"] || 0,
 130       replies: data["repliesCount"] || 0,
 131       announces: data["announcement_count"] || 0
 132     }
 133   end
 134
 135   defp represent(%Activity{} = activity), do: represent(activity, false)
 136
 137   defp represent(%Activity{object: %Object{data: data}} = activity, selected) do
 138     {:ok, user} = User.get_or_fetch(activity.object.data["actor"])
 139
 140     link =
 141       case user.local do
 142         true -> Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 143         _ -> data["url"] || data["external_url"] || data["id"]
 144       end
 145
 146     content =
 147       if data["content"] do
 148         data["content"]
 149         |> Pleroma.HTML.filter_tags()
 150         |> Pleroma.Emoji.Formatter.emojify(Map.get(data, "emoji", %{}))
 151       else
 152         nil
 153       end
 154
 155     %{
 156       user: User.sanitize_html(user),
 157       title: get_title(activity.object),
 158       content: content,
 159       attachment: data["attachment"],
 160       link: link,
 161       published: data["published"],
 162       sensitive: data["sensitive"],
 163       selected: selected,
 164       counts: get_counts(activity),
 165       id: activity.id
 166     }
 167   end
 168
 169   defp assign_id(%{path_info: ["notice", notice_id]} = conn, _opts),
 170     do: assign(conn, :notice_id, notice_id)
 171
 172   defp assign_id(%{path_info: ["users", user_id]} = conn, _opts),
 173     do: assign(conn, :username_or_id, user_id)
 174
 175   defp assign_id(%{path_info: ["objects", object_id]} = conn, _opts),
 176     do: assign(conn, :object_id, object_id)
 177
 178   defp assign_id(%{path_info: ["activities", activity_id]} = conn, _opts),
 179     do: assign(conn, :activity_id, activity_id)
 180
 181   defp assign_id(conn, _opts), do: conn
 182 end