git.squeep.com Git - akkoma/blob - lib/pleroma/web/static_fe/static_fe_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StaticFE.StaticFEController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.Router.Helpers
  13
  14   plug(:put_layout, :static_fe)
  15   plug(:put_view, Pleroma.Web.StaticFE.StaticFEView)
  16   plug(:assign_id)
  17   action_fallback(:not_found)
  18
  19   defp get_title(%Object{data: %{"name" => name}}) when is_binary(name),
  20     do: name
  21
  22   defp get_title(%Object{data: %{"summary" => summary}}) when is_binary(summary),
  23     do: summary
  24
  25   defp get_title(_), do: nil
  26
  27   def represent(%Activity{} = activity, %User{} = user, selected) do
  28     %{
  29       user: user,
  30       title: get_title(activity.object),
  31       content: activity.object.data["content"] || nil,
  32       attachment: activity.object.data["attachment"],
  33       link: Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity.id),
  34       published: activity.object.data["published"],
  35       sensitive: activity.object.data["sensitive"],
  36       selected: selected
  37     }
  38   end
  39
  40   def represent(%Activity{} = activity, selected) do
  41     {:ok, user} = User.get_or_fetch(activity.data["actor"])
  42     represent(activity, user, selected)
  43   end
  44
  45   def show_notice(%{assigns: %{notice_id: notice_id}} = conn, _params) do
  46     instance_name = Pleroma.Config.get([:instance, :name], "Pleroma")
  47     activity = Activity.get_by_id_with_object(notice_id)
  48     context = activity.object.data["context"]
  49     activities = ActivityPub.fetch_activities_for_context(context, %{})
  50
  51     represented =
  52       for a <- Enum.reverse(activities) do
  53         represent(activity, a.object.id == activity.object.id)
  54       end
  55
  56     render(conn, "conversation.html", %{activities: represented, instance_name: instance_name})
  57   end
  58
  59   def show_user(%{assigns: %{username_or_id: username_or_id}} = conn, _params) do
  60     instance_name = Pleroma.Config.get([:instance, :name], "Pleroma")
  61     %User{} = user = User.get_cached_by_nickname_or_id(username_or_id)
  62
  63     timeline =
  64       for activity <- ActivityPub.fetch_user_activities(user, nil, %{}) do
  65         represent(activity, user, false)
  66       end
  67
  68     render(conn, "profile.html", %{user: user, timeline: timeline, instance_name: instance_name})
  69   end
  70
  71   def assign_id(%{path_info: ["notice", notice_id]} = conn, _opts),
  72     do: assign(conn, :notice_id, notice_id)
  73
  74   def assign_id(%{path_info: ["users", user_id]} = conn, _opts),
  75     do: assign(conn, :username_or_id, user_id)
  76
  77   def assign_id(%{path_info: [user_id]} = conn, _opts),
  78     do: assign(conn, :username_or_id, user_id)
  79
  80   def assign_id(conn, _opts), do: conn
  81
  82   # Fallback for unhandled types
  83   def not_found(conn, _opts) do
  84     conn
  85     |> put_status(404)
  86     |> text("Not found")
  87   end
  88 end