git.squeep.com Git - akkoma/blob - lib/pleroma/web/salmon/salmon.ex

   1 defmodule Pleroma.Web.Salmon do
   2   use Bitwise
   3   alias Pleroma.Web.XML
   4   alias Pleroma.Web.OStatus.ActivityRepresenter
   5   alias Pleroma.User
   6   require Logger
   7
   8   def decode(salmon) do
   9     doc = XML.parse_document(salmon)
  10
  11     {:xmlObj, :string, data} = :xmerl_xpath.string('string(//me:data[1])', doc)
  12     {:xmlObj, :string, sig} = :xmerl_xpath.string('string(//me:sig[1])', doc)
  13     {:xmlObj, :string, alg} = :xmerl_xpath.string('string(//me:alg[1])', doc)
  14     {:xmlObj, :string, encoding} = :xmerl_xpath.string('string(//me:encoding[1])', doc)
  15     {:xmlObj, :string, type} = :xmerl_xpath.string('string(//me:data[1]/@type)', doc)
  16
  17     {:ok, data} = Base.url_decode64(to_string(data), ignore: :whitespace)
  18     {:ok, sig} = Base.url_decode64(to_string(sig), ignore: :whitespace)
  19     alg = to_string(alg)
  20     encoding = to_string(encoding)
  21     type = to_string(type)
  22
  23     [data, type, encoding, alg, sig]
  24   end
  25
  26   def fetch_magic_key(salmon) do
  27     with [data, _, _, _, _] <- decode(salmon),
  28          doc <- XML.parse_document(data),
  29          uri when not is_nil(uri) <- XML.string_from_xpath("/entry/author[1]/uri", doc),
  30          {:ok, %{info: %{"magic_key" => magic_key}}} <- Pleroma.Web.OStatus.find_or_make_user(uri) do
  31       {:ok, magic_key}
  32     end
  33   end
  34
  35   def decode_and_validate(magickey, salmon) do
  36     [data, type, encoding, alg, sig] = decode(salmon)
  37
  38     signed_text = [data, type, encoding, alg]
  39     |> Enum.map(&Base.url_encode64/1)
  40     |> Enum.join(".")
  41
  42     key = decode_key(magickey)
  43
  44     verify = :public_key.verify(signed_text, :sha256, sig, key)
  45
  46     if verify do
  47       {:ok, data}
  48     else
  49       :error
  50     end
  51   end
  52
  53   def decode_key("RSA." <> magickey) do
  54     make_integer = fn(bin) ->
  55       list = :erlang.binary_to_list(bin)
  56       Enum.reduce(list, 0, fn (el, acc) -> (acc <<< 8) ||| el end)
  57     end
  58
  59     [modulus, exponent] = magickey
  60     |> String.split(".")
  61     |> Enum.map(&Base.url_decode64!/1)
  62     |> Enum.map(make_integer)
  63
  64     {:RSAPublicKey, modulus, exponent}
  65   end
  66
  67   def encode_key({:RSAPublicKey, modulus, exponent}) do
  68     modulus_enc = :binary.encode_unsigned(modulus) |> Base.url_encode64
  69     exponent_enc = :binary.encode_unsigned(exponent) |> Base.url_encode64
  70
  71     "RSA.#{modulus_enc}.#{exponent_enc}"
  72   end
  73
  74   def generate_rsa_pem do
  75     port = Port.open({:spawn, "openssl genrsa"}, [:binary])
  76     {:ok, pem} = receive do
  77       {^port, {:data, pem}} -> {:ok, pem}
  78     end
  79     Port.close(port)
  80     if Regex.match?(~r/RSA PRIVATE KEY/, pem) do
  81       {:ok, pem}
  82     else
  83       :error
  84     end
  85   end
  86
  87   def keys_from_pem(pem) do
  88     [private_key_code] = :public_key.pem_decode(pem)
  89     private_key = :public_key.pem_entry_decode(private_key_code)
  90     {:RSAPrivateKey, _, modulus, exponent, _, _, _, _, _, _, _} = private_key
  91     public_key = {:RSAPublicKey, modulus, exponent}
  92     {:ok, private_key, public_key}
  93   end
  94
  95   def encode(private_key, doc) do
  96     type = "application/atom+xml"
  97     encoding = "base64url"
  98     alg = "RSA-SHA256"
  99
 100     signed_text = [doc, type, encoding, alg]
 101     |> Enum.map(&Base.url_encode64/1)
 102     |> Enum.join(".")
 103
 104     signature = :public_key.sign(signed_text, :sha256, private_key) |> to_string |> Base.url_encode64
 105     doc_base64= doc |> Base.url_encode64
 106
 107     # Don't need proper xml building, these strings are safe to leave unescaped
 108     salmon = """
 109     <?xml version="1.0" encoding="UTF-8"?>
 110     <me:env xmlns:me="http://salmon-protocol.org/ns/magic-env">
 111       <me:data type="application/atom+xml">#{doc_base64}</me:data>
 112       <me:encoding>#{encoding}</me:encoding>
 113       <me:alg>#{alg}</me:alg>
 114       <me:sig>#{signature}</me:sig>
 115     </me:env>
 116     """
 117
 118     {:ok, salmon}
 119   end
 120
 121   def remote_users(%{data: %{"to" => to}}) do
 122     to
 123     |> Enum.map(fn(id) -> User.get_cached_by_ap_id(id) end)
 124     |> Enum.filter(fn(user) -> user && !user.local end)
 125   end
 126
 127   defp send_to_user(%{info: %{"salmon" => salmon}}, feed, poster) do
 128     poster.(salmon, feed, [{"Content-Type", "application/magic-envelope+xml"}])
 129   end
 130
 131   defp send_to_user(_,_,_), do: nil
 132
 133   def publish(user, activity, poster \\ &HTTPoison.post/3)
 134   def publish(%{info: %{"keys" => keys}} = user, activity, poster) do
 135     feed = ActivityRepresenter.to_simple_form(activity, user, true)
 136     |> ActivityRepresenter.wrap_with_entry
 137     |> :xmerl.export_simple(:xmerl_xml)
 138     |> to_string
 139
 140     if feed do
 141       {:ok, private, _} = keys_from_pem(keys)
 142       {:ok, feed} = encode(private, feed)
 143
 144       remote_users(activity)
 145       |> Enum.each(fn(remote_user) ->
 146         Logger.debug("sending salmon to #{remote_user.ap_id}")
 147         send_to_user(remote_user, feed, poster)
 148       end)
 149     end
 150   end
 151
 152   def publish(%{id: id}, _, _), do: Logger.debug("Keys missing for user #{id}")
 153 end