git.squeep.com Git - akkoma/blob - lib/pleroma/web/salmon/salmon.ex

   1 defmodule Pleroma.Web.Salmon do
   2   use Bitwise
   3   alias Pleroma.Web.XML
   4   alias Pleroma.Web.OStatus.ActivityRepresenter
   5   alias Pleroma.User
   6   require Logger
   7
   8   def decode(salmon) do
   9     doc = XML.parse_document(salmon)
  10
  11     {:xmlObj, :string, data} = :xmerl_xpath.string('string(//me:data[1])', doc)
  12     {:xmlObj, :string, sig} = :xmerl_xpath.string('string(//me:sig[1])', doc)
  13     {:xmlObj, :string, alg} = :xmerl_xpath.string('string(//me:alg[1])', doc)
  14     {:xmlObj, :string, encoding} = :xmerl_xpath.string('string(//me:encoding[1])', doc)
  15     {:xmlObj, :string, type} = :xmerl_xpath.string('string(//me:data[1]/@type)', doc)
  16
  17
  18     {:ok, data} = Base.url_decode64(to_string(data), ignore: :whitespace)
  19     {:ok, sig} = Base.url_decode64(to_string(sig), ignore: :whitespace)
  20     alg = to_string(alg)
  21     encoding = to_string(encoding)
  22     type = to_string(type)
  23
  24     [data, type, encoding, alg, sig]
  25   end
  26
  27   def fetch_magic_key(salmon) do
  28     with [data, _, _, _, _] <- decode(salmon),
  29          doc <- XML.parse_document(data),
  30          uri when not is_nil(uri) <- XML.string_from_xpath("/entry/author[1]/uri", doc),
  31          {:ok, %{info: %{"magic_key" => magic_key}}} <- Pleroma.Web.OStatus.find_or_make_user(uri) do
  32       {:ok, magic_key}
  33     end
  34   end
  35
  36   def decode_and_validate(magickey, salmon) do
  37     [data, type, encoding, alg, sig] = decode(salmon)
  38
  39     signed_text = [data, type, encoding, alg]
  40     |> Enum.map(&Base.url_encode64/1)
  41     |> Enum.join(".")
  42
  43     key = decode_key(magickey)
  44
  45     verify = :public_key.verify(signed_text, :sha256, sig, key)
  46
  47     if verify do
  48       {:ok, data}
  49     else
  50       :error
  51     end
  52   end
  53
  54   def decode_key("RSA." <> magickey) do
  55     make_integer = fn(bin) ->
  56       list = :erlang.binary_to_list(bin)
  57       Enum.reduce(list, 0, fn (el, acc) -> (acc <<< 8) ||| el end)
  58     end
  59
  60     [modulus, exponent] = magickey
  61     |> String.split(".")
  62     |> Enum.map(&Base.url_decode64!/1)
  63     |> Enum.map(make_integer)
  64
  65     {:RSAPublicKey, modulus, exponent}
  66   end
  67
  68   def encode_key({:RSAPublicKey, modulus, exponent}) do
  69     modulus_enc = :binary.encode_unsigned(modulus) |> Base.url_encode64
  70     exponent_enc = :binary.encode_unsigned(exponent) |> Base.url_encode64
  71
  72     "RSA.#{modulus_enc}.#{exponent_enc}"
  73   end
  74
  75   def generate_rsa_pem do
  76     port = Port.open({:spawn, "openssl genrsa"}, [:binary])
  77     {:ok, pem} = receive do
  78       {^port, {:data, pem}} -> {:ok, pem}
  79     end
  80     Port.close(port)
  81     if Regex.match?(~r/RSA PRIVATE KEY/, pem) do
  82       {:ok, pem}
  83     else
  84       :error
  85     end
  86   end
  87
  88   def keys_from_pem(pem) do
  89     [private_key_code] = :public_key.pem_decode(pem)
  90     private_key = :public_key.pem_entry_decode(private_key_code)
  91     {:RSAPrivateKey, _, modulus, exponent, _, _, _, _, _, _, _} = private_key
  92     public_key = {:RSAPublicKey, modulus, exponent}
  93     {:ok, private_key, public_key}
  94   end
  95
  96   def encode(private_key, doc) do
  97     type = "application/atom+xml"
  98     encoding = "base64url"
  99     alg = "RSA-SHA256"
 100
 101     signed_text = [doc, type, encoding, alg]
 102     |> Enum.map(&Base.url_encode64/1)
 103     |> Enum.join(".")
 104
 105     signature = :public_key.sign(signed_text, :sha256, private_key) |> to_string |> Base.url_encode64
 106     doc_base64= doc |> Base.url_encode64
 107
 108     # Don't need proper xml building, these strings are safe to leave unescaped
 109     salmon = """
 110     <?xml version="1.0" encoding="UTF-8"?>
 111     <me:env xmlns:me="http://salmon-protocol.org/ns/magic-env">
 112       <me:data type="application/atom+xml">#{doc_base64}</me:data>
 113       <me:encoding>#{encoding}</me:encoding>
 114       <me:alg>#{alg}</me:alg>
 115       <me:sig>#{signature}</me:sig>
 116     </me:env>
 117     """
 118
 119     {:ok, salmon}
 120   end
 121
 122   def remote_users(%{data: %{"to" => to}}) do
 123     to
 124     |> Enum.map(fn(id) -> User.get_cached_by_ap_id(id) end)
 125     |> Enum.filter(fn(user) -> user && !user.local end)
 126   end
 127
 128   defp send_to_user(%{info: %{"salmon" => salmon}}, feed, poster) do
 129     poster.(salmon, feed, [{"Content-Type", "application/magic-envelope+xml"}])
 130   end
 131
 132   defp send_to_user(_,_,_), do: nil
 133
 134   def publish(user, activity, poster \\ &HTTPoison.post/3)
 135   def publish(%{info: %{"keys" => keys}} = user, activity, poster) do
 136     feed = ActivityRepresenter.to_simple_form(activity, user, true)
 137     |> ActivityRepresenter.wrap_with_entry
 138     |> :xmerl.export_simple(:xmerl_xml)
 139     |> to_string
 140
 141     if feed do
 142       {:ok, private, _} = keys_from_pem(keys)
 143       {:ok, feed} = encode(private, feed)
 144
 145       remote_users(activity)
 146       |> Enum.each(fn(remote_user) ->
 147         Logger.debug("sending salmon to #{remote_user.ap_id}")
 148         send_to_user(remote_user, feed, poster)
 149       end)
 150     end
 151   end
 152
 153   def publish(%{id: id}, _, _), do: Logger.debug("Keys missing for user #{id}")
 154 end