git.squeep.com Git - akkoma/blob - lib/pleroma/web/rich_media/parser.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.RichMedia.Parser do
   6   @parsers [
   7     Pleroma.Web.RichMedia.Parsers.OGP,
   8     Pleroma.Web.RichMedia.Parsers.TwitterCard,
   9     Pleroma.Web.RichMedia.Parsers.OEmbed
  10   ]
  11
  12   @hackney_options [
  13     pool: :media,
  14     recv_timeout: 2_000,
  15     max_body: 2_000_000,
  16     with_body: true
  17   ]
  18
  19   def parse(nil), do: {:error, "No URL provided"}
  20
  21   if Mix.env() == :test do
  22     def parse(url), do: parse_url(url)
  23   else
  24     def parse(url) do
  25       try do
  26         Cachex.fetch!(:rich_media_cache, url, fn _ ->
  27           {:commit, parse_url(url)}
  28         end)
  29       rescue
  30         e ->
  31           {:error, "Cachex error: #{inspect(e)}"}
  32       end
  33     end
  34   end
  35
  36   defp parse_url(url) do
  37     try do
  38       {:ok, %Tesla.Env{body: html}} = Pleroma.HTTP.get(url, [], adapter: @hackney_options)
  39
  40       html |> maybe_parse() |> clean_parsed_data() |> check_parsed_data()
  41     rescue
  42       e ->
  43         {:error, "Parsing error: #{inspect(e)}"}
  44     end
  45   end
  46
  47   defp maybe_parse(html) do
  48     Enum.reduce_while(@parsers, %{}, fn parser, acc ->
  49       case parser.parse(html, acc) do
  50         {:ok, data} -> {:halt, data}
  51         {:error, _msg} -> {:cont, acc}
  52       end
  53     end)
  54   end
  55
  56   defp check_parsed_data(%{title: title} = data) when is_binary(title) and byte_size(title) > 0 do
  57     {:ok, data}
  58   end
  59
  60   defp check_parsed_data(data) do
  61     {:error, "Found metadata was invalid or incomplete: #{inspect(data)}"}
  62   end
  63
  64   defp clean_parsed_data(data) do
  65     data
  66     |> Enum.reject(fn {key, val} ->
  67       with {:ok, _} <- Jason.encode(%{key => val}) do
  68         false
  69       else
  70         _ -> true
  71       end
  72     end)
  73     |> Map.new()
  74   end
  75 end