git.squeep.com Git - akkoma/blob - lib/pleroma/web/rich_media/helpers.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright _ 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.RichMedia.Helpers do
   6   alias Pleroma.Activity
   7   alias Pleroma.HTML
   8   alias Pleroma.Object
   9   alias Pleroma.Web.RichMedia.Parser
  10
  11   defp validate_page_url(page_url) when is_binary(page_url) do
  12     validate_tld = Application.get_env(:auto_linker, :opts)[:validate_tld]
  13
  14     if AutoLinker.Parser.url?(page_url, scheme: true, validate_tld: validate_tld) do
  15       URI.parse(page_url) |> validate_page_url
  16     else
  17       :error
  18     end
  19   end
  20
  21   defp validate_page_url(%URI{authority: nil}), do: :error
  22   defp validate_page_url(%URI{scheme: nil}), do: :error
  23   defp validate_page_url(%URI{}), do: :ok
  24   defp validate_page_url(_), do: :error
  25
  26   def fetch_data_for_activity(%Activity{data: %{"type" => "Create"}} = activity) do
  27     with true <- Pleroma.Config.get([:rich_media, :enabled]),
  28          %Object{} = object <- Object.normalize(activity),
  29          false <- object.data["sensitive"] || false,
  30          {:ok, page_url} <- HTML.extract_first_external_url(object, object.data["content"]),
  31          :ok <- validate_page_url(page_url),
  32          {:ok, rich_media} <- Parser.parse(page_url) do
  33       %{page_url: page_url, rich_media: rich_media}
  34     else
  35       _ -> %{}
  36     end
  37   end
  38
  39   def fetch_data_for_activity(_), do: %{}
  40
  41   def perform(:fetch, %Activity{} = activity), do: fetch_data_for_activity(activity)
  42 end