git.squeep.com Git - akkoma/blob - lib/pleroma/web/rich_media/helpers.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright _ 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.RichMedia.Helpers do
   6   alias Pleroma.Activity
   7   alias Pleroma.Config
   8   alias Pleroma.HTML
   9   alias Pleroma.Object
  10   alias Pleroma.Web.RichMedia.Parser
  11
  12   @options [
  13     pool: :media,
  14     max_body: 2_000_000,
  15     recv_timeout: 2_000
  16   ]
  17
  18   @spec validate_page_url(URI.t() | binary()) :: :ok | :error
  19   defp validate_page_url(page_url) when is_binary(page_url) do
  20     validate_tld = Config.get([Pleroma.Formatter, :validate_tld])
  21
  22     page_url
  23     |> Linkify.Parser.url?(validate_tld: validate_tld)
  24     |> parse_uri(page_url)
  25   end
  26
  27   defp validate_page_url(%URI{host: host, scheme: "https", authority: authority})
  28        when is_binary(authority) do
  29     cond do
  30       host in Config.get([:rich_media, :ignore_hosts], []) ->
  31         :error
  32
  33       get_tld(host) in Config.get([:rich_media, :ignore_tld], []) ->
  34         :error
  35
  36       true ->
  37         :ok
  38     end
  39   end
  40
  41   defp validate_page_url(_), do: :error
  42
  43   defp parse_uri(true, url) do
  44     url
  45     |> URI.parse()
  46     |> validate_page_url
  47   end
  48
  49   defp parse_uri(_, _), do: :error
  50
  51   defp get_tld(host) do
  52     host
  53     |> String.split(".")
  54     |> Enum.reverse()
  55     |> hd
  56   end
  57
  58   def fetch_data_for_object(object) do
  59     with true <- Config.get([:rich_media, :enabled]),
  60          false <- object.data["sensitive"] || false,
  61          {:ok, page_url} <-
  62            HTML.extract_first_external_url_from_object(object),
  63          :ok <- validate_page_url(page_url),
  64          {:ok, rich_media} <- Parser.parse(page_url) do
  65       %{page_url: page_url, rich_media: rich_media}
  66     else
  67       _ -> %{}
  68     end
  69   end
  70
  71   def fetch_data_for_activity(%Activity{data: %{"type" => "Create"}} = activity) do
  72     with true <- Config.get([:rich_media, :enabled]),
  73          %Object{} = object <- Object.normalize(activity) do
  74       fetch_data_for_object(object)
  75     else
  76       _ -> %{}
  77     end
  78   end
  79
  80   def fetch_data_for_activity(_), do: %{}
  81
  82   def perform(:fetch, %Activity{} = activity) do
  83     fetch_data_for_activity(activity)
  84     :ok
  85   end
  86
  87   def rich_media_get(url) do
  88     headers = [{"user-agent", Pleroma.Application.user_agent() <> "; Bot"}]
  89
  90     Pleroma.HTTP.get(url, headers, adapter: @options)
  91   end
  92 end