git.squeep.com Git - akkoma/blob - lib/pleroma/web/rich_media/helpers.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright _ 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.RichMedia.Helpers do
   6   alias Pleroma.Activity
   7   alias Pleroma.HTML
   8   alias Pleroma.Object
   9   alias Pleroma.Web.RichMedia.Parser
  10
  11   @private_ip_regexp ~r/(127\.)|(10\.\d+\.\d+.\d+)|(192\.168\.)
  12   |(^172\.1[6-9]\.)|(^172\.2[0-9]\.)|(^172\.3[0-1]\.)|(localhost)/
  13
  14   defp validate_page_url(page_url) when is_binary(page_url) do
  15     validate_tld = Application.get_env(:auto_linker, :opts)[:validate_tld]
  16
  17     cond do
  18       Regex.match?(@private_ip_regexp, page_url) ->
  19         :error
  20
  21       AutoLinker.Parser.url?(page_url, scheme: true, validate_tld: validate_tld) ->
  22         URI.parse(page_url) |> validate_page_url
  23
  24       true ->
  25         :error
  26     end
  27   end
  28
  29   defp validate_page_url(%URI{authority: nil}), do: :error
  30   defp validate_page_url(%URI{scheme: nil}), do: :error
  31   defp validate_page_url(%URI{}), do: :ok
  32   defp validate_page_url(_), do: :error
  33
  34   def fetch_data_for_activity(%Activity{data: %{"type" => "Create"}} = activity) do
  35     with true <- Pleroma.Config.get([:rich_media, :enabled]),
  36          %Object{} = object <- Object.normalize(activity),
  37          false <- object.data["sensitive"] || false,
  38          {:ok, page_url} <- HTML.extract_first_external_url(object, object.data["content"]),
  39          :ok <- validate_page_url(page_url),
  40          {:ok, rich_media} <- Parser.parse(page_url) do
  41       %{page_url: page_url, rich_media: rich_media}
  42     else
  43       _ -> %{}
  44     end
  45   end
  46
  47   def fetch_data_for_activity(_), do: %{}
  48
  49   def perform(:fetch, %Activity{} = activity), do: fetch_data_for_activity(activity)
  50 end