git.squeep.com Git - akkoma/blob - lib/pleroma/web/push/subscription.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Push.Subscription do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   alias Pleroma.{Repo, User}
   9   alias Pleroma.Web.OAuth.Token
  10   alias Pleroma.Web.Push.Subscription
  11
  12   schema "push_subscriptions" do
  13     belongs_to(:user, User)
  14     belongs_to(:token, Token)
  15     field(:endpoint, :string)
  16     field(:key_p256dh, :string)
  17     field(:key_auth, :string)
  18     field(:data, :map, default: %{})
  19
  20     timestamps()
  21   end
  22
  23   @supported_alert_types ~w[follow favourite mention reblog]
  24
  25   defp alerts(%{"data" => %{"alerts" => alerts}}) do
  26     alerts = Map.take(alerts, @supported_alert_types)
  27     %{"alerts" => alerts}
  28   end
  29
  30   def create(
  31         %User{} = user,
  32         %Token{} = token,
  33         %{
  34           "subscription" => %{
  35             "endpoint" => endpoint,
  36             "keys" => %{"auth" => key_auth, "p256dh" => key_p256dh}
  37           }
  38         } = params
  39       ) do
  40     Repo.insert(%Subscription{
  41       user_id: user.id,
  42       token_id: token.id,
  43       endpoint: endpoint,
  44       key_auth: ensure_base64_urlsafe(key_auth),
  45       key_p256dh: ensure_base64_urlsafe(key_p256dh),
  46       data: alerts(params)
  47     })
  48   end
  49
  50   def get(%User{id: user_id}, %Token{id: token_id}) do
  51     Repo.get_by(Subscription, user_id: user_id, token_id: token_id)
  52   end
  53
  54   def update(user, token, params) do
  55     get(user, token)
  56     |> change(data: alerts(params))
  57     |> Repo.update()
  58   end
  59
  60   def delete(user, token) do
  61     Repo.delete(get(user, token))
  62   end
  63
  64   def delete_if_exists(user, token) do
  65     case get(user, token) do
  66       nil -> {:ok, nil}
  67       sub -> Repo.delete(sub)
  68     end
  69   end
  70
  71   # Some webpush clients (e.g. iOS Toot!) use an non urlsafe base64 as an encoding for the key.
  72   # However, the web push rfs specify to use base64 urlsafe, and the `web_push_encryption` library we use
  73   # requires the key to be properly encoded. So we just convert base64 to urlsafe base64.
  74   defp ensure_base64_urlsafe(string) do
  75     string
  76     |> String.replace("+", "-")
  77     |> String.replace("/", "_")
  78     |> String.replace("=", "")
  79   end
  80 end