git.squeep.com Git - akkoma/blob - lib/pleroma/web/push/subscription.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Push.Subscription do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.OAuth.Token
  13   alias Pleroma.Web.Push.Subscription
  14
  15   schema "push_subscriptions" do
  16     belongs_to(:user, User, type: Pleroma.FlakeId)
  17     belongs_to(:token, Token)
  18     field(:endpoint, :string)
  19     field(:key_p256dh, :string)
  20     field(:key_auth, :string)
  21     field(:data, :map, default: %{})
  22
  23     timestamps()
  24   end
  25
  26   @supported_alert_types ~w[follow favourite mention reblog]
  27
  28   defp alerts(%{"data" => %{"alerts" => alerts}}) do
  29     alerts = Map.take(alerts, @supported_alert_types)
  30     %{"alerts" => alerts}
  31   end
  32
  33   def create(
  34         %User{} = user,
  35         %Token{} = token,
  36         %{
  37           "subscription" => %{
  38             "endpoint" => endpoint,
  39             "keys" => %{"auth" => key_auth, "p256dh" => key_p256dh}
  40           }
  41         } = params
  42       ) do
  43     Repo.insert(%Subscription{
  44       user_id: user.id,
  45       token_id: token.id,
  46       endpoint: endpoint,
  47       key_auth: ensure_base64_urlsafe(key_auth),
  48       key_p256dh: ensure_base64_urlsafe(key_p256dh),
  49       data: alerts(params)
  50     })
  51   end
  52
  53   def get(%User{id: user_id}, %Token{id: token_id}) do
  54     Repo.get_by(Subscription, user_id: user_id, token_id: token_id)
  55   end
  56
  57   def update(user, token, params) do
  58     get(user, token)
  59     |> change(data: alerts(params))
  60     |> Repo.update()
  61   end
  62
  63   def delete(user, token) do
  64     Repo.delete(get(user, token))
  65   end
  66
  67   def delete_if_exists(user, token) do
  68     case get(user, token) do
  69       nil -> {:ok, nil}
  70       sub -> Repo.delete(sub)
  71     end
  72   end
  73
  74   # Some webpush clients (e.g. iOS Toot!) use an non urlsafe base64 as an encoding for the key.
  75   # However, the web push rfs specify to use base64 urlsafe, and the `web_push_encryption` library we use
  76   # requires the key to be properly encoded. So we just convert base64 to urlsafe base64.
  77   defp ensure_base64_urlsafe(string) do
  78     string
  79     |> String.replace("+", "-")
  80     |> String.replace("/", "_")
  81     |> String.replace("=", "")
  82   end
  83 end