git.squeep.com Git - akkoma/blob - lib/pleroma/web/push/subscription.ex

   1 defmodule Pleroma.Web.Push.Subscription do
   2   use Ecto.Schema
   3   import Ecto.Changeset
   4   alias Pleroma.{Repo, User}
   5   alias Pleroma.Web.OAuth.Token
   6   alias Pleroma.Web.Push.Subscription
   7
   8   schema "push_subscriptions" do
   9     belongs_to(:user, User)
  10     belongs_to(:token, Token)
  11     field(:endpoint, :string)
  12     field(:key_p256dh, :string)
  13     field(:key_auth, :string)
  14     field(:data, :map, default: %{})
  15
  16     timestamps()
  17   end
  18
  19   @supported_alert_types ~w[follow favourite mention reblog]
  20
  21   defp alerts(%{"data" => %{"alerts" => alerts}}) do
  22     alerts = Map.take(alerts, @supported_alert_types)
  23     %{"alerts" => alerts}
  24   end
  25
  26   def create(
  27         %User{} = user,
  28         %Token{} = token,
  29         %{
  30           "subscription" => %{
  31             "endpoint" => endpoint,
  32             "keys" => %{"auth" => key_auth, "p256dh" => key_p256dh}
  33           }
  34         } = params
  35       ) do
  36     Repo.insert(%Subscription{
  37       user_id: user.id,
  38       token_id: token.id,
  39       endpoint: endpoint,
  40       key_auth: ensure_base64_urlsafe(key_auth),
  41       key_p256dh: ensure_base64_urlsafe(key_p256dh),
  42       data: alerts(params)
  43     })
  44   end
  45
  46   def get(%User{id: user_id}, %Token{id: token_id}) do
  47     Repo.get_by(Subscription, user_id: user_id, token_id: token_id)
  48   end
  49
  50   def update(user, token, params) do
  51     get(user, token)
  52     |> change(data: alerts(params))
  53     |> Repo.update()
  54   end
  55
  56   def delete(user, token) do
  57     Repo.delete(get(user, token))
  58   end
  59
  60   def delete_if_exists(user, token) do
  61     case get(user, token) do
  62       nil -> {:ok, nil}
  63       sub -> Repo.delete(sub)
  64     end
  65   end
  66
  67   # Some webpush clients (e.g. iOS Toot!) use an non urlsafe base64 as an encoding for the key.
  68   # However, the web push rfs specify to use base64 urlsafe, and the `web_push_encryption` library we use
  69   # requires the key to be properly encoded. So we just convert base64 to urlsafe base64.
  70   defp ensure_base64_urlsafe(string) do
  71     string
  72     |> String.replace("+", "-")
  73     |> String.replace("/", "_")
  74     |> String.replace("=", "")
  75   end
  76 end