git.squeep.com Git - akkoma/blob - lib/pleroma/web/plugs/set_locale_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 # NOTE: this module is based on https://github.com/smeevil/set_locale
   6 defmodule Pleroma.Web.Plugs.SetLocalePlug do
   7   import Plug.Conn, only: [get_req_header: 2, assign: 3]
   8
   9   def frontend_language_cookie_name, do: "userLanguage"
  10
  11   def init(_), do: nil
  12
  13   def call(conn, _) do
  14     locales = get_locales_from_header(conn)
  15     first_locale = Enum.at(locales, 0, Gettext.get_locale())
  16
  17     Pleroma.Web.Gettext.put_locales(locales)
  18
  19     conn
  20     |> assign(:locale, first_locale)
  21     |> assign(:locales, locales)
  22   end
  23
  24   defp get_locales_from_header(conn) do
  25     conn
  26     |> extract_preferred_language()
  27     |> normalize_language_codes()
  28     |> all_supported()
  29   end
  30
  31   defp all_supported(locales) do
  32     locales
  33     |> Enum.flat_map(&Pleroma.Web.Gettext.supported_variants_of_locale/1)
  34     |> Enum.filter(&supported_locale?/1)
  35   end
  36
  37   defp normalize_language_codes(codes) do
  38     codes
  39     |> Enum.map(fn code -> Pleroma.Web.Gettext.normalize_locale(code) end)
  40   end
  41
  42   defp extract_preferred_language(conn) do
  43     extract_frontend_language(conn) ++ extract_accept_language(conn)
  44   end
  45
  46   defp extract_frontend_language(conn) do
  47     %{req_cookies: cookies} =
  48       conn
  49       |> Plug.Conn.fetch_cookies()
  50
  51     case cookies[frontend_language_cookie_name()] do
  52       nil ->
  53         []
  54
  55       fe_lang ->
  56         [fe_lang]
  57         |> ensure_language_fallbacks()
  58     end
  59   end
  60
  61   defp extract_accept_language(conn) do
  62     case get_req_header(conn, "accept-language") do
  63       [value | _] ->
  64         value
  65         |> String.split(",")
  66         |> Enum.map(&parse_language_option/1)
  67         |> Enum.sort(&(&1.quality > &2.quality))
  68         |> Enum.map(& &1.tag)
  69         |> Enum.reject(&is_nil/1)
  70         |> ensure_language_fallbacks()
  71
  72       _ ->
  73         []
  74     end
  75   end
  76
  77   defp supported_locale?(locale) do
  78     Pleroma.Web.Gettext.supports_locale?(locale)
  79   end
  80
  81   defp parse_language_option(string) do
  82     captures = Regex.named_captures(~r/^\s?(?<tag>[\w\-]+)(?:;q=(?<quality>[\d\.]+))?$/i, string)
  83
  84     quality =
  85       case Float.parse(captures["quality"] || "1.0") do
  86         {val, _} -> val
  87         :error -> 1.0
  88       end
  89
  90     %{tag: captures["tag"], quality: quality}
  91   end
  92
  93   defp ensure_language_fallbacks(tags) do
  94     Enum.flat_map(tags, fn tag ->
  95       [language | _] = String.split(tag, "-")
  96       if Enum.member?(tags, language), do: [tag], else: [tag, language]
  97     end)
  98   end
  99 end