git.squeep.com Git - akkoma/blob - lib/pleroma/web/plugs/o_auth_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Plugs.OAuthPlug do
   6   @moduledoc "Performs OAuth authentication by token from params / headers / cookies."
   7
   8   import Plug.Conn
   9   import Ecto.Query
  10
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.OAuth.App
  14   alias Pleroma.Web.OAuth.Token
  15
  16   @realm_reg Regex.compile!("Bearer\:?\s+(.*)$", "i")
  17
  18   def init(options), do: options
  19
  20   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  21
  22   def call(conn, _) do
  23     with {:ok, token_str} <- fetch_token_str(conn) do
  24       with {:ok, user, user_token} <- fetch_user_and_token(token_str),
  25            false <- Token.is_expired?(user_token) do
  26         conn
  27         |> assign(:token, user_token)
  28         |> assign(:user, user)
  29       else
  30         _ ->
  31           with {:ok, app, app_token} <- fetch_app_and_token(token_str),
  32                false <- Token.is_expired?(app_token) do
  33             conn
  34             |> assign(:token, app_token)
  35             |> assign(:app, app)
  36           else
  37             _ -> conn
  38           end
  39       end
  40     else
  41       _ -> conn
  42     end
  43   end
  44
  45   # Gets user by token
  46   #
  47   @spec fetch_user_and_token(String.t()) :: {:ok, User.t(), Token.t()} | nil
  48   defp fetch_user_and_token(token) do
  49     query =
  50       from(t in Token,
  51         where: t.token == ^token,
  52         join: user in assoc(t, :user),
  53         preload: [user: user]
  54       )
  55
  56     with %Token{user: user} = token_record <- Repo.one(query) do
  57       {:ok, user, token_record}
  58     end
  59   end
  60
  61   @spec fetch_app_and_token(String.t()) :: {:ok, App.t(), Token.t()} | nil
  62   defp fetch_app_and_token(token) do
  63     query =
  64       from(t in Token, where: t.token == ^token, join: app in assoc(t, :app), preload: [app: app])
  65
  66     with %Token{app: app} = token_record <- Repo.one(query) do
  67       {:ok, app, token_record}
  68     end
  69   end
  70
  71   # Gets token string from conn (in params / headers / session)
  72   #
  73   @spec fetch_token_str(Plug.Conn.t() | list(String.t())) :: :no_token_found | {:ok, String.t()}
  74   defp fetch_token_str(%Plug.Conn{params: %{"access_token" => access_token}} = _conn) do
  75     {:ok, access_token}
  76   end
  77
  78   defp fetch_token_str(%Plug.Conn{} = conn) do
  79     headers = get_req_header(conn, "authorization")
  80
  81     with {:ok, token} <- fetch_token_str(headers) do
  82       {:ok, token}
  83     else
  84       _ -> fetch_token_from_session(conn)
  85     end
  86   end
  87
  88   defp fetch_token_str([token | tail]) do
  89     trimmed_token = String.trim(token)
  90
  91     case Regex.run(@realm_reg, trimmed_token) do
  92       [_, match] -> {:ok, String.trim(match)}
  93       _ -> fetch_token_str(tail)
  94     end
  95   end
  96
  97   defp fetch_token_str([]), do: :no_token_found
  98
  99   @spec fetch_token_from_session(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
 100   defp fetch_token_from_session(conn) do
 101     case get_session(conn, :oauth_token) do
 102       nil -> :no_token_found
 103       token -> {:ok, token}
 104     end
 105   end
 106 end