git.squeep.com Git - akkoma/blob - lib/pleroma/web/plugs/o_auth_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Plugs.OAuthPlug do
   6   @moduledoc "Performs OAuth authentication by token from params / headers / cookies."
   7
   8   import Plug.Conn
   9   import Ecto.Query
  10
  11   alias Pleroma.Helpers.AuthHelper
  12   alias Pleroma.Repo
  13   alias Pleroma.User
  14   alias Pleroma.Web.OAuth.App
  15   alias Pleroma.Web.OAuth.Token
  16
  17   @realm_reg Regex.compile!("Bearer\:?\s+(.*)$", "i")
  18
  19   def init(options), do: options
  20
  21   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  22
  23   def call(conn, _) do
  24     with {:ok, token_str} <- fetch_token_str(conn) do
  25       with {:ok, user, user_token} <- fetch_user_and_token(token_str),
  26            false <- Token.is_expired?(user_token) do
  27         conn
  28         |> assign(:token, user_token)
  29         |> assign(:user, user)
  30       else
  31         _ ->
  32           with {:ok, app, app_token} <- fetch_app_and_token(token_str),
  33                false <- Token.is_expired?(app_token) do
  34             conn
  35             |> assign(:token, app_token)
  36             |> assign(:app, app)
  37           else
  38             _ -> conn
  39           end
  40       end
  41     else
  42       _ -> conn
  43     end
  44   end
  45
  46   # Gets user by token
  47   #
  48   @spec fetch_user_and_token(String.t()) :: {:ok, User.t(), Token.t()} | nil
  49   defp fetch_user_and_token(token) do
  50     query =
  51       from(t in Token,
  52         where: t.token == ^token,
  53         join: user in assoc(t, :user),
  54         preload: [user: user]
  55       )
  56
  57     with %Token{user: user} = token_record <- Repo.one(query) do
  58       {:ok, user, token_record}
  59     end
  60   end
  61
  62   @spec fetch_app_and_token(String.t()) :: {:ok, App.t(), Token.t()} | nil
  63   defp fetch_app_and_token(token) do
  64     query =
  65       from(t in Token, where: t.token == ^token, join: app in assoc(t, :app), preload: [app: app])
  66
  67     with %Token{app: app} = token_record <- Repo.one(query) do
  68       {:ok, app, token_record}
  69     end
  70   end
  71
  72   # Gets token string from conn (in params / headers / session)
  73   #
  74   @spec fetch_token_str(Plug.Conn.t() | list(String.t())) :: :no_token_found | {:ok, String.t()}
  75   defp fetch_token_str(%Plug.Conn{params: %{"access_token" => access_token}} = _conn) do
  76     {:ok, access_token}
  77   end
  78
  79   defp fetch_token_str(%Plug.Conn{} = conn) do
  80     headers = get_req_header(conn, "authorization")
  81
  82     with {:ok, token} <- fetch_token_str(headers) do
  83       {:ok, token}
  84     else
  85       _ -> fetch_token_from_session(conn)
  86     end
  87   end
  88
  89   defp fetch_token_str([token | tail]) do
  90     trimmed_token = String.trim(token)
  91
  92     case Regex.run(@realm_reg, trimmed_token) do
  93       [_, match] -> {:ok, String.trim(match)}
  94       _ -> fetch_token_str(tail)
  95     end
  96   end
  97
  98   defp fetch_token_str([]), do: :no_token_found
  99
 100   @spec fetch_token_from_session(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
 101   defp fetch_token_from_session(conn) do
 102     case AuthHelper.get_session_token(conn) do
 103       nil -> :no_token_found
 104       token -> {:ok, token}
 105     end
 106   end
 107 end