git.squeep.com Git - akkoma/blob - lib/pleroma/web/plugs/o_auth_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Plugs.OAuthPlug do
   6   @moduledoc "Performs OAuth authentication by token from params / headers / cookies."
   7
   8   import Plug.Conn
   9   import Ecto.Query
  10
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.OAuth.App
  14   alias Pleroma.Web.OAuth.Token
  15
  16   @realm_reg Regex.compile!("Bearer\:?\s+(.*)$", "i")
  17
  18   def init(options), do: options
  19
  20   def call(conn, _) do
  21     with {:ok, token_str} <- fetch_token_str(conn) do
  22       with {:ok, user, user_token} <- fetch_user_and_token(token_str),
  23            false <- Token.is_expired?(user_token) do
  24         conn
  25         |> assign(:token, user_token)
  26         |> assign(:user, user)
  27       else
  28         _ ->
  29           with {:ok, app, app_token} <- fetch_app_and_token(token_str),
  30                false <- Token.is_expired?(app_token) do
  31             conn
  32             |> assign(:token, app_token)
  33             |> assign(:app, app)
  34           else
  35             _ -> conn
  36           end
  37       end
  38     else
  39       _ -> conn
  40     end
  41   end
  42
  43   # Gets user by token
  44   #
  45   @spec fetch_user_and_token(String.t()) :: {:ok, User.t(), Token.t()} | nil
  46   defp fetch_user_and_token(token) do
  47     query =
  48       from(t in Token,
  49         where: t.token == ^token,
  50         join: user in assoc(t, :user),
  51         preload: [user: user]
  52       )
  53
  54     with %Token{user: user} = token_record <- Repo.one(query) do
  55       {:ok, user, token_record}
  56     end
  57   end
  58
  59   @spec fetch_app_and_token(String.t()) :: {:ok, App.t(), Token.t()} | nil
  60   defp fetch_app_and_token(token) do
  61     query =
  62       from(t in Token, where: t.token == ^token, join: app in assoc(t, :app), preload: [app: app])
  63
  64     with %Token{app: app} = token_record <- Repo.one(query) do
  65       {:ok, app, token_record}
  66     end
  67   end
  68
  69   # Gets token string from conn (in params / headers / session)
  70   #
  71   @spec fetch_token_str(Plug.Conn.t() | list(String.t())) :: :no_token_found | {:ok, String.t()}
  72   defp fetch_token_str(%Plug.Conn{params: %{"access_token" => access_token}} = _conn) do
  73     {:ok, access_token}
  74   end
  75
  76   defp fetch_token_str(%Plug.Conn{} = conn) do
  77     headers = get_req_header(conn, "authorization")
  78
  79     with {:ok, token} <- fetch_token_str(headers) do
  80       {:ok, token}
  81     else
  82       _ -> :no_token_found
  83     end
  84   end
  85
  86   defp fetch_token_str([token | tail]) do
  87     trimmed_token = String.trim(token)
  88
  89     case Regex.run(@realm_reg, trimmed_token) do
  90       [_, match] -> {:ok, String.trim(match)}
  91       _ -> fetch_token_str(tail)
  92     end
  93   end
  94
  95   defp fetch_token_str([]), do: :no_token_found
  96 end