git.squeep.com Git - akkoma/blob - lib/pleroma/web/plugs/http_security_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Plugs.HTTPSecurityPlug do
   6   alias Pleroma.Config
   7   import Plug.Conn
   8
   9   require Logger
  10
  11   def init(opts), do: opts
  12
  13   def call(conn, _options) do
  14     if Config.get([:http_security, :enabled]) do
  15       conn
  16       |> merge_resp_headers(headers(conn))
  17       |> maybe_send_sts_header(Config.get([:http_security, :sts]))
  18     else
  19       conn
  20     end
  21   end
  22
  23   def primary_frontend do
  24     with %{"name" => frontend} <- Config.get([:frontends, :primary]),
  25          available <- Config.get([:frontends, :available]),
  26          %{} = primary_frontend <- Map.get(available, frontend) do
  27       {:ok, primary_frontend}
  28     end
  29   end
  30
  31   def custom_http_frontend_headers do
  32     with {:ok, %{"custom-http-headers" => custom_headers}} <- primary_frontend() do
  33       custom_headers
  34     else
  35       _ -> []
  36     end
  37   end
  38
  39   @spec headers(Plug.Conn.t()) :: [{String.t(), String.t()}]
  40   def headers(conn) do
  41     referrer_policy = Config.get([:http_security, :referrer_policy])
  42     report_uri = Config.get([:http_security, :report_uri])
  43     custom_http_frontend_headers = custom_http_frontend_headers()
  44
  45     headers = [
  46       {"x-xss-protection", "0"},
  47       {"x-permitted-cross-domain-policies", "none"},
  48       {"x-frame-options", "DENY"},
  49       {"x-content-type-options", "nosniff"},
  50       {"referrer-policy", referrer_policy},
  51       {"content-security-policy", csp_string(conn)},
  52       {"permissions-policy", "interest-cohort=()"}
  53     ]
  54
  55     headers =
  56       if custom_http_frontend_headers do
  57         custom_http_frontend_headers ++ headers
  58       else
  59         headers
  60       end
  61
  62     if report_uri do
  63       report_group = %{
  64         "group" => "csp-endpoint",
  65         "max-age" => 10_886_400,
  66         "endpoints" => [
  67           %{"url" => report_uri}
  68         ]
  69       }
  70
  71       [{"report-to", Jason.encode!(report_group)} | headers]
  72     else
  73       headers
  74     end
  75   end
  76
  77   static_csp_rules = [
  78     "default-src 'none'",
  79     "base-uri 'none'",
  80     "frame-ancestors 'none'",
  81     "manifest-src 'self'"
  82   ]
  83
  84   @csp_start [Enum.join(static_csp_rules, ";") <> ";"]
  85
  86   defp csp_string(conn) do
  87     scheme = Config.get([Pleroma.Web.Endpoint, :url])[:scheme]
  88     static_url = Pleroma.Web.Endpoint.static_url()
  89     websocket_url = Pleroma.Web.Endpoint.websocket_url()
  90     report_uri = Config.get([:http_security, :report_uri])
  91     %{assigns: %{csp_nonce: nonce}} = conn
  92     nonce_tag = "nonce-" <> nonce
  93     img_src = "img-src 'self' data: blob:"
  94     media_src = "media-src 'self'"
  95
  96     # Strict multimedia CSP enforcement only when MediaProxy is enabled
  97     {img_src, media_src} =
  98       if Config.get([:media_proxy, :enabled]) &&
  99            !Config.get([:media_proxy, :proxy_opts, :redirect_on_failure]) do
 100         sources = build_csp_multimedia_source_list()
 101         {[img_src, sources], [media_src, sources]}
 102       else
 103         {[img_src, " https:"], [media_src, " https:"]}
 104       end
 105
 106     connect_src =
 107       if Config.get([:media_proxy, :enabled]) do
 108         sources = build_csp_multimedia_source_list()
 109         ["connect-src 'self' ", static_url, ?\s, websocket_url, ?\s, sources]
 110       else
 111         ["connect-src 'self' ", static_url, ?\s, websocket_url]
 112       end
 113
 114     style_src = "style-src 'self' '#{nonce_tag}'"
 115     font_src = "font-src 'self'"
 116
 117     script_src = "script-src 'self' '#{nonce_tag}'"
 118
 119     report = if report_uri, do: ["report-uri ", report_uri, ";report-to csp-endpoint"]
 120     insecure = if scheme == "https", do: "upgrade-insecure-requests"
 121
 122     @csp_start
 123     |> add_csp_param(img_src)
 124     |> add_csp_param(media_src)
 125     |> add_csp_param(connect_src)
 126     |> add_csp_param(script_src)
 127     |> add_csp_param(font_src)
 128     |> add_csp_param(style_src)
 129     |> add_csp_param(insecure)
 130     |> add_csp_param(report)
 131     |> :erlang.iolist_to_binary()
 132   end
 133
 134   defp build_csp_from_whitelist([], acc), do: acc
 135
 136   defp build_csp_from_whitelist([last], acc) do
 137     [build_csp_param_from_whitelist(last) | acc]
 138   end
 139
 140   defp build_csp_from_whitelist([head | tail], acc) do
 141     build_csp_from_whitelist(tail, [[?\s, build_csp_param_from_whitelist(head)] | acc])
 142   end
 143
 144   # TODO: use `build_csp_param/1` after removing support bare domains for media proxy whitelist
 145   defp build_csp_param_from_whitelist("http" <> _ = url) do
 146     build_csp_param(url)
 147   end
 148
 149   defp build_csp_param_from_whitelist(url), do: url
 150
 151   defp build_csp_multimedia_source_list do
 152     media_proxy_whitelist =
 153       [:media_proxy, :whitelist]
 154       |> Config.get()
 155       |> build_csp_from_whitelist([])
 156
 157     captcha_method = Config.get([Pleroma.Captcha, :method])
 158     captcha_endpoint = Config.get([captcha_method, :endpoint])
 159
 160     base_endpoints =
 161       [
 162         [:media_proxy, :base_url],
 163         [Pleroma.Upload, :base_url],
 164         [Pleroma.Uploaders.S3, :public_endpoint]
 165       ]
 166       |> Enum.map(&Config.get/1)
 167
 168     [captcha_endpoint | base_endpoints]
 169     |> Enum.map(&build_csp_param/1)
 170     |> Enum.reduce([], &add_source(&2, &1))
 171     |> add_source(media_proxy_whitelist)
 172   end
 173
 174   defp add_source(iodata, nil), do: iodata
 175   defp add_source(iodata, []), do: iodata
 176   defp add_source(iodata, source), do: [[?\s, source] | iodata]
 177
 178   defp add_csp_param(csp_iodata, nil), do: csp_iodata
 179
 180   defp add_csp_param(csp_iodata, param), do: [[param, ?;] | csp_iodata]
 181
 182   defp build_csp_param(nil), do: nil
 183
 184   defp build_csp_param(url) when is_binary(url) do
 185     %{host: host, scheme: scheme} = URI.parse(url)
 186
 187     if scheme do
 188       [scheme, "://", host]
 189     end
 190   end
 191
 192   def warn_if_disabled do
 193     unless Config.get([:http_security, :enabled]) do
 194       Logger.warn("
 195                                  .i;;;;i.
 196                                iYcviii;vXY:
 197                              .YXi       .i1c.
 198                             .YC.     .    in7.
 199                            .vc.   ......   ;1c.
 200                            i7,   ..        .;1;
 201                           i7,   .. ...      .Y1i
 202                          ,7v     .6MMM@;     .YX,
 203                         .7;.   ..IMMMMMM1     :t7.
 204                        .;Y.     ;$MMMMMM9.     :tc.
 205                        vY.   .. .nMMM@MMU.      ;1v.
 206                       i7i   ...  .#MM@M@C. .....:71i
 207                      it:   ....   $MMM@9;.,i;;;i,;tti
 208                     :t7.  .....   0MMMWv.,iii:::,,;St.
 209                    .nC.   .....   IMMMQ..,::::::,.,czX.
 210                   .ct:   ....... .ZMMMI..,:::::::,,:76Y.
 211                   c2:   ......,i..Y$M@t..:::::::,,..inZY
 212                  vov   ......:ii..c$MBc..,,,,,,,,,,..iI9i
 213                 i9Y   ......iii:..7@MA,..,,,,,,,,,....;AA:
 214                iIS.  ......:ii::..;@MI....,............;Ez.
 215               .I9.  ......:i::::...8M1..................C0z.
 216              .z9;  ......:i::::,.. .i:...................zWX.
 217              vbv  ......,i::::,,.      ................. :AQY
 218             c6Y.  .,...,::::,,..:t0@@QY. ................ :8bi
 219            :6S. ..,,...,:::,,,..EMMMMMMI. ............... .;bZ,
 220           :6o,  .,,,,..:::,,,..i#MMMMMM#v.................  YW2.
 221          .n8i ..,,,,,,,::,,,,.. tMMMMM@C:.................. .1Wn
 222          7Uc. .:::,,,,,::,,,,..   i1t;,..................... .UEi
 223          7C...::::::::::::,,,,..        ....................  vSi.
 224          ;1;...,,::::::,.........       ..................    Yz:
 225           v97,.........                                     .voC.
 226            izAotX7777777777777777777777777777777777777777Y7n92:
 227              .;CoIIIIIUAA666666699999ZZZZZZZZZZZZZZZZZZZZ6ov.
 228
 229 HTTP Security is disabled. Please re-enable it to prevent users from attacking
 230 your instance and your users via malicious posts:
 231
 232       config :pleroma, :http_security, enabled: true
 233       ")
 234     end
 235   end
 236
 237   defp maybe_send_sts_header(conn, true) do
 238     max_age_sts = Config.get([:http_security, :sts_max_age])
 239
 240     merge_resp_headers(conn, [
 241       {"strict-transport-security", "max-age=#{max_age_sts}; includeSubDomains; preload"}
 242     ])
 243   end
 244
 245   defp maybe_send_sts_header(conn, _), do: conn
 246 end