git.squeep.com Git - akkoma/blob - lib/pleroma/web/plugs/http_security_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Plugs.HTTPSecurityPlug do
   6   alias Pleroma.Config
   7   import Plug.Conn
   8
   9   require Logger
  10
  11   @mix_env Mix.env()
  12
  13   def init(opts), do: opts
  14
  15   def call(conn, _options) do
  16     if Config.get([:http_security, :enabled]) do
  17       conn
  18       |> merge_resp_headers(headers(conn))
  19       |> maybe_send_sts_header(Config.get([:http_security, :sts]))
  20     else
  21       conn
  22     end
  23   end
  24
  25   def primary_frontend do
  26     with %{"name" => frontend} <- Config.get([:frontends, :primary]),
  27          available <- Config.get([:frontends, :available]),
  28          %{} = primary_frontend <- Map.get(available, frontend) do
  29       {:ok, primary_frontend}
  30     end
  31   end
  32
  33   def custom_http_frontend_headers do
  34     with {:ok, %{"custom-http-headers" => custom_headers}} <- primary_frontend() do
  35       custom_headers
  36     else
  37       _ -> []
  38     end
  39   end
  40
  41   @spec headers(Plug.Conn.t()) :: [{String.t(), String.t()}]
  42   def headers(conn) do
  43     referrer_policy = Config.get([:http_security, :referrer_policy])
  44     report_uri = Config.get([:http_security, :report_uri])
  45     custom_http_frontend_headers = custom_http_frontend_headers()
  46
  47     headers = [
  48       {"x-xss-protection", "0"},
  49       {"x-permitted-cross-domain-policies", "none"},
  50       {"x-frame-options", "DENY"},
  51       {"x-content-type-options", "nosniff"},
  52       {"referrer-policy", referrer_policy},
  53       {"content-security-policy", csp_string(conn)},
  54       {"permissions-policy", "interest-cohort=()"}
  55     ]
  56
  57     headers =
  58       if custom_http_frontend_headers do
  59         custom_http_frontend_headers ++ headers
  60       else
  61         headers
  62       end
  63
  64     if report_uri do
  65       report_group = %{
  66         "group" => "csp-endpoint",
  67         "max-age" => 10_886_400,
  68         "endpoints" => [
  69           %{"url" => report_uri}
  70         ]
  71       }
  72
  73       [{"report-to", Jason.encode!(report_group)} | headers]
  74     else
  75       headers
  76     end
  77   end
  78
  79   static_csp_rules = [
  80     "default-src 'none'",
  81     "base-uri 'none'",
  82     "frame-ancestors 'none'",
  83     "manifest-src 'self'"
  84   ]
  85
  86   @csp_start [Enum.join(static_csp_rules, ";") <> ";"]
  87
  88   defp csp_string(conn) do
  89     scheme = Config.get([Pleroma.Web.Endpoint, :url])[:scheme]
  90     static_url = Pleroma.Web.Endpoint.static_url()
  91     websocket_url = Pleroma.Web.Endpoint.websocket_url()
  92     report_uri = Config.get([:http_security, :report_uri])
  93     %{assigns: %{csp_nonce: nonce}} = conn
  94     nonce_tag = "nonce-" <> nonce
  95     img_src = "img-src 'self' data: blob:"
  96     media_src = "media-src 'self'"
  97
  98     # Strict multimedia CSP enforcement only when MediaProxy is enabled
  99     {img_src, media_src} =
 100       if Config.get([:media_proxy, :enabled]) &&
 101            !Config.get([:media_proxy, :proxy_opts, :redirect_on_failure]) do
 102         sources = build_csp_multimedia_source_list()
 103         {[img_src, sources], [media_src, sources]}
 104       else
 105         {[img_src, " https:"], [media_src, " https:"]}
 106       end
 107
 108     connect_src =
 109       if Config.get([:media_proxy, :enabled]) do
 110         sources = build_csp_multimedia_source_list()
 111         ["connect-src 'self' ", static_url, ?\s, websocket_url, ?\s, sources]
 112       else
 113         ["connect-src 'self' ", static_url, ?\s, websocket_url]
 114       end
 115
 116     style_src = "style-src 'self' '#{nonce_tag}'"
 117     font_src = "font-src 'self'"
 118
 119     script_src = "script-src 'self' '#{nonce_tag}' "
 120     script_src = if @mix_env == :dev do
 121       "script-src 'self' 'unsafe-eval' 'unsafe-inline'"
 122     else
 123       script_src
 124     end
 125
 126     report = if report_uri, do: ["report-uri ", report_uri, ";report-to csp-endpoint"]
 127     insecure = if scheme == "https", do: "upgrade-insecure-requests"
 128
 129     @csp_start
 130     |> add_csp_param(img_src)
 131     |> add_csp_param(media_src)
 132     |> add_csp_param(connect_src)
 133     |> add_csp_param(script_src)
 134     |> add_csp_param(font_src)
 135     |> add_csp_param(style_src)
 136     |> add_csp_param(insecure)
 137     |> add_csp_param(report)
 138     |> :erlang.iolist_to_binary()
 139   end
 140
 141   defp build_csp_from_whitelist([], acc), do: acc
 142
 143   defp build_csp_from_whitelist([last], acc) do
 144     [build_csp_param_from_whitelist(last) | acc]
 145   end
 146
 147   defp build_csp_from_whitelist([head | tail], acc) do
 148     build_csp_from_whitelist(tail, [[?\s, build_csp_param_from_whitelist(head)] | acc])
 149   end
 150
 151   # TODO: use `build_csp_param/1` after removing support bare domains for media proxy whitelist
 152   defp build_csp_param_from_whitelist("http" <> _ = url) do
 153     build_csp_param(url)
 154   end
 155
 156   defp build_csp_param_from_whitelist(url), do: url
 157
 158   defp build_csp_multimedia_source_list do
 159     media_proxy_whitelist =
 160       [:media_proxy, :whitelist]
 161       |> Config.get()
 162       |> build_csp_from_whitelist([])
 163
 164     captcha_method = Config.get([Pleroma.Captcha, :method])
 165     captcha_endpoint = Config.get([captcha_method, :endpoint])
 166
 167     base_endpoints =
 168       [
 169         [:media_proxy, :base_url],
 170         [Pleroma.Upload, :base_url],
 171         [Pleroma.Uploaders.S3, :public_endpoint]
 172       ]
 173       |> Enum.map(&Config.get/1)
 174
 175     [captcha_endpoint | base_endpoints]
 176     |> Enum.map(&build_csp_param/1)
 177     |> Enum.reduce([], &add_source(&2, &1))
 178     |> add_source(media_proxy_whitelist)
 179   end
 180
 181   defp add_source(iodata, nil), do: iodata
 182   defp add_source(iodata, []), do: iodata
 183   defp add_source(iodata, source), do: [[?\s, source] | iodata]
 184
 185   defp add_csp_param(csp_iodata, nil), do: csp_iodata
 186
 187   defp add_csp_param(csp_iodata, param), do: [[param, ?;] | csp_iodata]
 188
 189   defp build_csp_param(nil), do: nil
 190
 191   defp build_csp_param(url) when is_binary(url) do
 192     %{host: host, scheme: scheme} = URI.parse(url)
 193
 194     if scheme do
 195       [scheme, "://", host]
 196     end
 197   end
 198
 199   def warn_if_disabled do
 200     unless Config.get([:http_security, :enabled]) do
 201       Logger.warn("
 202                                  .i;;;;i.
 203                                iYcviii;vXY:
 204                              .YXi       .i1c.
 205                             .YC.     .    in7.
 206                            .vc.   ......   ;1c.
 207                            i7,   ..        .;1;
 208                           i7,   .. ...      .Y1i
 209                          ,7v     .6MMM@;     .YX,
 210                         .7;.   ..IMMMMMM1     :t7.
 211                        .;Y.     ;$MMMMMM9.     :tc.
 212                        vY.   .. .nMMM@MMU.      ;1v.
 213                       i7i   ...  .#MM@M@C. .....:71i
 214                      it:   ....   $MMM@9;.,i;;;i,;tti
 215                     :t7.  .....   0MMMWv.,iii:::,,;St.
 216                    .nC.   .....   IMMMQ..,::::::,.,czX.
 217                   .ct:   ....... .ZMMMI..,:::::::,,:76Y.
 218                   c2:   ......,i..Y$M@t..:::::::,,..inZY
 219                  vov   ......:ii..c$MBc..,,,,,,,,,,..iI9i
 220                 i9Y   ......iii:..7@MA,..,,,,,,,,,....;AA:
 221                iIS.  ......:ii::..;@MI....,............;Ez.
 222               .I9.  ......:i::::...8M1..................C0z.
 223              .z9;  ......:i::::,.. .i:...................zWX.
 224              vbv  ......,i::::,,.      ................. :AQY
 225             c6Y.  .,...,::::,,..:t0@@QY. ................ :8bi
 226            :6S. ..,,...,:::,,,..EMMMMMMI. ............... .;bZ,
 227           :6o,  .,,,,..:::,,,..i#MMMMMM#v.................  YW2.
 228          .n8i ..,,,,,,,::,,,,.. tMMMMM@C:.................. .1Wn
 229          7Uc. .:::,,,,,::,,,,..   i1t;,..................... .UEi
 230          7C...::::::::::::,,,,..        ....................  vSi.
 231          ;1;...,,::::::,.........       ..................    Yz:
 232           v97,.........                                     .voC.
 233            izAotX7777777777777777777777777777777777777777Y7n92:
 234              .;CoIIIIIUAA666666699999ZZZZZZZZZZZZZZZZZZZZ6ov.
 235
 236 HTTP Security is disabled. Please re-enable it to prevent users from attacking
 237 your instance and your users via malicious posts:
 238
 239       config :pleroma, :http_security, enabled: true
 240       ")
 241     end
 242   end
 243
 244   defp maybe_send_sts_header(conn, true) do
 245     max_age_sts = Config.get([:http_security, :sts_max_age])
 246
 247     merge_resp_headers(conn, [
 248       {"strict-transport-security", "max-age=#{max_age_sts}; includeSubDomains; preload"}
 249     ])
 250   end
 251
 252   defp maybe_send_sts_header(conn, _), do: conn
 253 end