git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/scrobble_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.ScrobbleController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [add_link_headers: 2]
   9
  10   alias Pleroma.Plugs.OAuthScopesPlug
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.MastodonAPI.StatusView
  15
  16   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  17
  18   plug(
  19     OAuthScopesPlug,
  20     %{scopes: ["read"], fallback: :proceed_unauthenticated} when action == :index
  21   )
  22
  23   plug(OAuthScopesPlug, %{scopes: ["write"]} when action == :create)
  24
  25   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.PleromaScrobbleOperation
  26
  27   def create(%{assigns: %{user: user}, body_params: params} = conn, _) do
  28     with {:ok, activity} <- CommonAPI.listen(user, params) do
  29       conn
  30       |> put_view(StatusView)
  31       |> render("listen.json", %{activity: activity, for: user})
  32     else
  33       {:error, message} ->
  34         conn
  35         |> put_status(:bad_request)
  36         |> json(%{"error" => message})
  37     end
  38   end
  39
  40   def index(%{assigns: %{user: reading_user}} = conn, %{id: id} = params) do
  41     with %User{} = user <- User.get_cached_by_nickname_or_id(id, for: reading_user) do
  42       params =
  43         params
  44         |> Map.new(fn {key, value} -> {to_string(key), value} end)
  45         |> Map.put("type", ["Listen"])
  46
  47       activities = ActivityPub.fetch_user_abstract_activities(user, reading_user, params)
  48
  49       conn
  50       |> add_link_headers(activities)
  51       |> put_view(StatusView)
  52       |> render("listens.json", %{
  53         activities: activities,
  54         for: reading_user,
  55         as: :activity
  56       })
  57     end
  58   end
  59 end