git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/scrobble_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.ScrobbleController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [add_link_headers: 2, fetch_integer_param: 2]
   9
  10   alias Pleroma.Plugs.OAuthScopesPlug
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.MastodonAPI.StatusView
  15
  16   plug(
  17     OAuthScopesPlug,
  18     %{scopes: ["read"], fallback: :proceed_unauthenticated} when action == :user_scrobbles
  19   )
  20
  21   plug(OAuthScopesPlug, %{scopes: ["write"]} when action != :user_scrobbles)
  22
  23   def new_scrobble(%{assigns: %{user: user}} = conn, %{"title" => _} = params) do
  24     params =
  25       if !params["length"] do
  26         params
  27       else
  28         params
  29         |> Map.put("length", fetch_integer_param(params, "length"))
  30       end
  31
  32     with {:ok, activity} <- CommonAPI.listen(user, params) do
  33       conn
  34       |> put_view(StatusView)
  35       |> render("listen.json", %{activity: activity, for: user})
  36     else
  37       {:error, message} ->
  38         conn
  39         |> put_status(:bad_request)
  40         |> json(%{"error" => message})
  41     end
  42   end
  43
  44   def user_scrobbles(%{assigns: %{user: reading_user}} = conn, params) do
  45     with %User{} = user <- User.get_cached_by_nickname_or_id(params["id"], for: reading_user) do
  46       params = Map.put(params, "type", ["Listen"])
  47
  48       activities = ActivityPub.fetch_user_abstract_activities(user, reading_user, params)
  49
  50       conn
  51       |> add_link_headers(activities)
  52       |> put_view(StatusView)
  53       |> render("listens.json", %{
  54         activities: activities,
  55         for: reading_user,
  56         as: :activity
  57       })
  58     end
  59   end
  60 end