git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/emoji_file_controller.ex

   1 defmodule Pleroma.Web.PleromaAPI.EmojiFileController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.Emoji.Pack
   5   alias Pleroma.Web.ApiSpec
   6
   7   plug(Pleroma.Web.ApiSpec.CastAndValidate)
   8
   9   plug(
  10     Pleroma.Plugs.OAuthScopesPlug,
  11     %{scopes: ["write"], admin: true}
  12     when action in [
  13            :create,
  14            :update,
  15            :delete
  16          ]
  17   )
  18
  19   defdelegate open_api_operation(action), to: ApiSpec.PleromaEmojiFileOperation
  20
  21   def create(%{body_params: params} = conn, %{name: pack_name}) do
  22     filename = params[:filename] || get_filename(params[:file])
  23     shortcode = params[:shortcode] || Path.basename(filename, Path.extname(filename))
  24
  25     with {:ok, pack} <- Pack.load_pack(pack_name),
  26          {:ok, file} <- get_file(params[:file]),
  27          {:ok, pack} <- Pack.add_file(pack, shortcode, filename, file) do
  28       json(conn, pack.files)
  29     else
  30       {:error, :already_exists} ->
  31         conn
  32         |> put_status(:conflict)
  33         |> json(%{error: "An emoji with the \"#{shortcode}\" shortcode already exists"})
  34
  35       {:error, :not_found} ->
  36         conn
  37         |> put_status(:not_found)
  38         |> json(%{error: "pack \"#{pack_name}\" is not found"})
  39
  40       {:error, :empty_values} ->
  41         conn
  42         |> put_status(:unprocessable_entity)
  43         |> json(%{error: "pack name, shortcode or filename cannot be empty"})
  44
  45       {:error, _} ->
  46         render_error(
  47           conn,
  48           :internal_server_error,
  49           "Unexpected error occurred while adding file to pack."
  50         )
  51     end
  52   end
  53
  54   def update(%{body_params: %{shortcode: shortcode} = params} = conn, %{name: pack_name}) do
  55     new_shortcode = params[:new_shortcode]
  56     new_filename = params[:new_filename]
  57     force = params[:force]
  58
  59     with {:ok, pack} <- Pack.load_pack(pack_name),
  60          {:ok, pack} <- Pack.update_file(pack, shortcode, new_shortcode, new_filename, force) do
  61       json(conn, pack.files)
  62     else
  63       {:error, :doesnt_exist} ->
  64         conn
  65         |> put_status(:bad_request)
  66         |> json(%{error: "Emoji \"#{shortcode}\" does not exist"})
  67
  68       {:error, :already_exists} ->
  69         conn
  70         |> put_status(:conflict)
  71         |> json(%{
  72           error:
  73             "New shortcode \"#{new_shortcode}\" is already used. If you want to override emoji use 'force' option"
  74         })
  75
  76       {:error, :not_found} ->
  77         conn
  78         |> put_status(:not_found)
  79         |> json(%{error: "pack \"#{pack_name}\" is not found"})
  80
  81       {:error, :empty_values} ->
  82         conn
  83         |> put_status(:bad_request)
  84         |> json(%{error: "new_shortcode or new_filename cannot be empty"})
  85
  86       {:error, _} ->
  87         render_error(
  88           conn,
  89           :internal_server_error,
  90           "Unexpected error occurred while updating file in pack."
  91         )
  92     end
  93   end
  94
  95   def delete(conn, %{name: pack_name, shortcode: shortcode}) do
  96     with {:ok, pack} <- Pack.load_pack(pack_name),
  97          {:ok, pack} <- Pack.delete_file(pack, shortcode) do
  98       json(conn, pack.files)
  99     else
 100       {:error, :doesnt_exist} ->
 101         conn
 102         |> put_status(:bad_request)
 103         |> json(%{error: "Emoji \"#{shortcode}\" does not exist"})
 104
 105       {:error, :not_found} ->
 106         conn
 107         |> put_status(:not_found)
 108         |> json(%{error: "pack \"#{pack_name}\" is not found"})
 109
 110       {:error, :empty_values} ->
 111         conn
 112         |> put_status(:bad_request)
 113         |> json(%{error: "pack name or shortcode cannot be empty"})
 114
 115       {:error, _} ->
 116         render_error(
 117           conn,
 118           :internal_server_error,
 119           "Unexpected error occurred while removing file from pack."
 120         )
 121     end
 122   end
 123
 124   defp get_filename(%Plug.Upload{filename: filename}), do: filename
 125   defp get_filename(url) when is_binary(url), do: Path.basename(url)
 126
 127   def get_file(%Plug.Upload{} = file), do: {:ok, file}
 128
 129   def get_file(url) when is_binary(url) do
 130     with {:ok, %Tesla.Env{body: body, status: code, headers: headers}}
 131          when code in 200..299 <- Pleroma.HTTP.get(url) do
 132       path = Plug.Upload.random_file!("emoji")
 133
 134       content_type =
 135         case List.keyfind(headers, "content-type", 0) do
 136           {"content-type", value} -> value
 137           nil -> nil
 138         end
 139
 140       File.write(path, body)
 141
 142       {:ok,
 143        %Plug.Upload{
 144          filename: Path.basename(url),
 145          path: path,
 146          content_type: content_type
 147        }}
 148     end
 149   end
 150 end