git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/emoji_file_controller.ex

   1 defmodule Pleroma.Web.PleromaAPI.EmojiFileController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.Emoji.Pack
   5   alias Pleroma.Web.ApiSpec
   6
   7   plug(Pleroma.Web.ApiSpec.CastAndValidate)
   8
   9   plug(
  10     Pleroma.Plugs.OAuthScopesPlug,
  11     %{scopes: ["write"], admin: true}
  12     when action in [
  13            :create,
  14            :update,
  15            :delete
  16          ]
  17   )
  18
  19   defdelegate open_api_operation(action), to: ApiSpec.PleromaEmojiFileOperation
  20
  21   def create(%{body_params: params} = conn, %{name: pack_name}) do
  22     filename = params[:filename] || get_filename(params[:file])
  23     shortcode = params[:shortcode] || Path.basename(filename, Path.extname(filename))
  24
  25     with {:ok, pack} <- Pack.add_file(pack_name, shortcode, filename, params[:file]) do
  26       json(conn, pack.files)
  27     else
  28       {:error, :already_exists} ->
  29         conn
  30         |> put_status(:conflict)
  31         |> json(%{error: "An emoji with the \"#{shortcode}\" shortcode already exists"})
  32
  33       {:error, :not_found} ->
  34         conn
  35         |> put_status(:bad_request)
  36         |> json(%{error: "pack \"#{pack_name}\" is not found"})
  37
  38       {:error, :empty_values} ->
  39         conn
  40         |> put_status(:bad_request)
  41         |> json(%{error: "pack name, shortcode or filename cannot be empty"})
  42
  43       {:error, _} ->
  44         render_error(
  45           conn,
  46           :internal_server_error,
  47           "Unexpected error occurred while adding file to pack."
  48         )
  49     end
  50   end
  51
  52   def update(%{body_params: %{shortcode: shortcode} = params} = conn, %{name: pack_name}) do
  53     new_shortcode = params[:new_shortcode]
  54     new_filename = params[:new_filename]
  55     force = params[:force]
  56
  57     with {:ok, pack} <- Pack.update_file(pack_name, shortcode, new_shortcode, new_filename, force) do
  58       json(conn, pack.files)
  59     else
  60       {:error, :doesnt_exist} ->
  61         conn
  62         |> put_status(:bad_request)
  63         |> json(%{error: "Emoji \"#{shortcode}\" does not exist"})
  64
  65       {:error, :already_exists} ->
  66         conn
  67         |> put_status(:conflict)
  68         |> json(%{
  69           error:
  70             "New shortcode \"#{new_shortcode}\" is already used. If you want to override emoji use 'force' option"
  71         })
  72
  73       {:error, :not_found} ->
  74         conn
  75         |> put_status(:bad_request)
  76         |> json(%{error: "pack \"#{pack_name}\" is not found"})
  77
  78       {:error, :empty_values} ->
  79         conn
  80         |> put_status(:bad_request)
  81         |> json(%{error: "new_shortcode or new_filename cannot be empty"})
  82
  83       {:error, _} ->
  84         render_error(
  85           conn,
  86           :internal_server_error,
  87           "Unexpected error occurred while updating file in pack."
  88         )
  89     end
  90   end
  91
  92   def delete(conn, %{name: pack_name, shortcode: shortcode}) do
  93     with {:ok, pack} <- Pack.delete_file(pack_name, shortcode) do
  94       json(conn, pack.files)
  95     else
  96       {:error, :doesnt_exist} ->
  97         conn
  98         |> put_status(:bad_request)
  99         |> json(%{error: "Emoji \"#{shortcode}\" does not exist"})
 100
 101       {:error, :not_found} ->
 102         conn
 103         |> put_status(:bad_request)
 104         |> json(%{error: "pack \"#{pack_name}\" is not found"})
 105
 106       {:error, :empty_values} ->
 107         conn
 108         |> put_status(:bad_request)
 109         |> json(%{error: "pack name or shortcode cannot be empty"})
 110
 111       {:error, _} ->
 112         render_error(
 113           conn,
 114           :internal_server_error,
 115           "Unexpected error occurred while removing file from pack."
 116         )
 117     end
 118   end
 119
 120   defp get_filename(%Plug.Upload{filename: filename}), do: filename
 121   defp get_filename(url) when is_binary(url), do: Path.basename(url)
 122 end