git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/conversation_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.ConversationController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [add_link_headers: 2]
   9
  10   alias Pleroma.Conversation.Participation
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.MastodonAPI.StatusView
  13   alias Pleroma.Web.Plugs.OAuthScopesPlug
  14
  15   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  16   plug(:put_view, Pleroma.Web.MastodonAPI.ConversationView)
  17   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:show, :statuses])
  18
  19   plug(
  20     OAuthScopesPlug,
  21     %{scopes: ["write:conversations"]} when action in [:update, :mark_as_read]
  22   )
  23
  24   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.PleromaConversationOperation
  25
  26   def show(%{assigns: %{user: %{id: user_id} = user}} = conn, %{id: participation_id}) do
  27     with %Participation{user_id: ^user_id} = participation <- Participation.get(participation_id) do
  28       render(conn, "participation.json", participation: participation, for: user)
  29     else
  30       _error ->
  31         conn
  32         |> put_status(:not_found)
  33         |> json(%{"error" => "Unknown conversation id"})
  34     end
  35   end
  36
  37   def statuses(
  38         %{assigns: %{user: %{id: user_id} = user}} = conn,
  39         %{id: participation_id} = params
  40       ) do
  41     with %Participation{user_id: ^user_id} = participation <-
  42            Participation.get(participation_id, preload: [:conversation]) do
  43       params =
  44         params
  45         |> Map.put(:blocking_user, user)
  46         |> Map.put(:muting_user, user)
  47         |> Map.put(:user, user)
  48
  49       activities =
  50         participation.conversation.ap_id
  51         |> ActivityPub.fetch_activities_for_context_query(params)
  52         |> Pleroma.Pagination.fetch_paginated(Map.put(params, :total, false))
  53         |> Enum.reverse()
  54
  55       conn
  56       |> add_link_headers(activities)
  57       |> put_view(StatusView)
  58       |> render("index.json", activities: activities, for: user, as: :activity)
  59     else
  60       _error ->
  61         conn
  62         |> put_status(:not_found)
  63         |> json(%{"error" => "Unknown conversation id"})
  64     end
  65   end
  66
  67   def update(
  68         %{assigns: %{user: %{id: user_id} = user}} = conn,
  69         %{id: participation_id, recipients: recipients}
  70       ) do
  71     with %Participation{user_id: ^user_id} = participation <- Participation.get(participation_id),
  72          {:ok, participation} <- Participation.set_recipients(participation, recipients) do
  73       render(conn, "participation.json", participation: participation, for: user)
  74     else
  75       {:error, message} ->
  76         conn
  77         |> put_status(:bad_request)
  78         |> json(%{"error" => message})
  79
  80       _error ->
  81         conn
  82         |> put_status(:not_found)
  83         |> json(%{"error" => "Unknown conversation id"})
  84     end
  85   end
  86
  87   def mark_as_read(%{assigns: %{user: user}} = conn, _params) do
  88     with {:ok, _, participations} <- Participation.mark_all_as_read(user) do
  89       conn
  90       |> add_link_headers(participations)
  91       |> render("participations.json", participations: participations, for: user)
  92     end
  93   end
  94 end