git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/conversation_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.ConversationController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [add_link_headers: 2]
   9
  10   alias Pleroma.Conversation.Participation
  11   alias Pleroma.Plugs.OAuthScopesPlug
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.MastodonAPI.StatusView
  14
  15   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  16   plug(:put_view, Pleroma.Web.MastodonAPI.ConversationView)
  17   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:show, :statuses])
  18
  19   plug(
  20     OAuthScopesPlug,
  21     %{scopes: ["write:conversations"]} when action in [:update, :mark_as_read]
  22   )
  23
  24   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.PleromaConversationOperation
  25
  26   def show(%{assigns: %{user: %{id: user_id} = user}} = conn, %{id: participation_id}) do
  27     with %Participation{user_id: ^user_id} = participation <- Participation.get(participation_id) do
  28       render(conn, "participation.json", participation: participation, for: user)
  29     else
  30       _error ->
  31         conn
  32         |> put_status(:not_found)
  33         |> json(%{"error" => "Unknown conversation id"})
  34     end
  35   end
  36
  37   def statuses(
  38         %{assigns: %{user: %{id: user_id} = user}} = conn,
  39         %{id: participation_id} = params
  40       ) do
  41     with %Participation{user_id: ^user_id} = participation <-
  42            Participation.get(participation_id, preload: [:conversation]) do
  43       params =
  44         params
  45         |> Map.new(fn {key, value} -> {to_string(key), value} end)
  46         |> Map.put("blocking_user", user)
  47         |> Map.put("muting_user", user)
  48         |> Map.put("user", user)
  49
  50       activities =
  51         participation.conversation.ap_id
  52         |> ActivityPub.fetch_activities_for_context_query(params)
  53         |> Pleroma.Pagination.fetch_paginated(Map.put(params, "total", false))
  54         |> Enum.reverse()
  55
  56       conn
  57       |> add_link_headers(activities)
  58       |> put_view(StatusView)
  59       |> render("index.json", activities: activities, for: user, as: :activity)
  60     else
  61       _error ->
  62         conn
  63         |> put_status(:not_found)
  64         |> json(%{"error" => "Unknown conversation id"})
  65     end
  66   end
  67
  68   def update(
  69         %{assigns: %{user: %{id: user_id} = user}} = conn,
  70         %{id: participation_id, recipients: recipients}
  71       ) do
  72     with %Participation{user_id: ^user_id} = participation <- Participation.get(participation_id),
  73          {:ok, participation} <- Participation.set_recipients(participation, recipients) do
  74       render(conn, "participation.json", participation: participation, for: user)
  75     else
  76       {:error, message} ->
  77         conn
  78         |> put_status(:bad_request)
  79         |> json(%{"error" => message})
  80
  81       _error ->
  82         conn
  83         |> put_status(:not_found)
  84         |> json(%{"error" => "Unknown conversation id"})
  85     end
  86   end
  87
  88   def mark_as_read(%{assigns: %{user: user}} = conn, _params) do
  89     with {:ok, _, participations} <- Participation.mark_all_as_read(user) do
  90       conn
  91       |> add_link_headers(participations)
  92       |> render("participations.json", participations: participations, for: user)
  93     end
  94   end
  95 end