git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/chat_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4 defmodule Pleroma.Web.PleromaAPI.ChatController do
   5   use Pleroma.Web, :controller
   6
   7   alias Pleroma.Chat
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.PleromaAPI.ChatView
  13   alias Pleroma.Web.PleromaAPI.ChatMessageView
  14
  15   import Ecto.Query
  16
  17   # TODO
  18   # - Oauth stuff
  19   # - Views / Representers
  20   # - Error handling
  21
  22   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.ChatOperation
  23
  24   def post_chat_message(%{assigns: %{user: %{id: user_id} = user}} = conn, %{
  25         "id" => id,
  26         "content" => content
  27       }) do
  28     with %Chat{} = chat <- Repo.get_by(Chat, id: id, user_id: user_id),
  29          %User{} = recipient <- User.get_cached_by_ap_id(chat.recipient),
  30          {:ok, activity} <- CommonAPI.post_chat_message(user, recipient, content),
  31          message <- Object.normalize(activity) do
  32       conn
  33       |> put_view(ChatMessageView)
  34       |> render("show.json", for: user, object: message, chat: chat)
  35     end
  36   end
  37
  38   def messages(%{assigns: %{user: %{id: user_id} = user}} = conn, %{"id" => id}) do
  39     with %Chat{} = chat <- Repo.get_by(Chat, id: id, user_id: user_id) do
  40       messages =
  41         from(o in Object,
  42           where: fragment("?->>'type' = ?", o.data, "ChatMessage"),
  43           where:
  44             fragment(
  45               """
  46               (?->>'actor' = ? and ?->'to' = ?)
  47               OR (?->>'actor' = ? and ?->'to' = ?)
  48               """,
  49               o.data,
  50               ^user.ap_id,
  51               o.data,
  52               ^[chat.recipient],
  53               o.data,
  54               ^chat.recipient,
  55               o.data,
  56               ^[user.ap_id]
  57             ),
  58           order_by: [desc: o.id]
  59         )
  60         |> Repo.all()
  61
  62       conn
  63       |> put_view(ChatMessageView)
  64       |> render("index.json", for: user, objects: messages, chat: chat)
  65     end
  66   end
  67
  68   def index(%{assigns: %{user: %{id: user_id}}} = conn, _params) do
  69     chats =
  70       from(c in Chat,
  71         where: c.user_id == ^user_id,
  72         order_by: [desc: c.updated_at]
  73       )
  74       |> Repo.all()
  75
  76     conn
  77     |> put_view(ChatView)
  78     |> render("index.json", chats: chats)
  79   end
  80
  81   def create(%{assigns: %{user: user}} = conn, params) do
  82     recipient = params["ap_id"] |> URI.decode_www_form()
  83
  84     with {:ok, %Chat{} = chat} <- Chat.get_or_create(user.id, recipient) do
  85       conn
  86       |> put_view(ChatView)
  87       |> render("show.json", chat: chat)
  88     end
  89   end
  90 end