git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/chat_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4 defmodule Pleroma.Web.PleromaAPI.ChatController do
   5   use Pleroma.Web, :controller
   6
   7   alias Pleroma.Chat
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.PleromaAPI.ChatView
  13   alias Pleroma.Web.PleromaAPI.ChatMessageView
  14   alias Pleroma.Pagination
  15
  16   import Ecto.Query
  17
  18   # TODO
  19   # - Oauth stuff
  20   # - Views / Representers
  21   # - Error handling
  22
  23   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.ChatOperation
  24
  25   def post_chat_message(%{assigns: %{user: %{id: user_id} = user}} = conn, %{
  26         "id" => id,
  27         "content" => content
  28       }) do
  29     with %Chat{} = chat <- Repo.get_by(Chat, id: id, user_id: user_id),
  30          %User{} = recipient <- User.get_cached_by_ap_id(chat.recipient),
  31          {:ok, activity} <- CommonAPI.post_chat_message(user, recipient, content),
  32          message <- Object.normalize(activity) do
  33       conn
  34       |> put_view(ChatMessageView)
  35       |> render("show.json", for: user, object: message, chat: chat)
  36     end
  37   end
  38
  39   def messages(%{assigns: %{user: %{id: user_id} = user}} = conn, %{"id" => id} = params) do
  40     with %Chat{} = chat <- Repo.get_by(Chat, id: id, user_id: user_id) do
  41       messages =
  42         from(o in Object,
  43           where: fragment("?->>'type' = ?", o.data, "ChatMessage"),
  44           where:
  45             fragment(
  46               """
  47               (?->>'actor' = ? and ?->'to' = ?)
  48               OR (?->>'actor' = ? and ?->'to' = ?)
  49               """,
  50               o.data,
  51               ^user.ap_id,
  52               o.data,
  53               ^[chat.recipient],
  54               o.data,
  55               ^chat.recipient,
  56               o.data,
  57               ^[user.ap_id]
  58             )
  59         )
  60         |> Pagination.fetch_paginated(params)
  61
  62       conn
  63       |> put_view(ChatMessageView)
  64       |> render("index.json", for: user, objects: messages, chat: chat)
  65     end
  66   end
  67
  68   def index(%{assigns: %{user: %{id: user_id}}} = conn, params) do
  69     chats =
  70       from(c in Chat,
  71         where: c.user_id == ^user_id,
  72         order_by: [desc: c.updated_at]
  73       )
  74       |> Pagination.fetch_paginated(params)
  75
  76     conn
  77     |> put_view(ChatView)
  78     |> render("index.json", chats: chats)
  79   end
  80
  81   def create(%{assigns: %{user: user}} = conn, params) do
  82     recipient = params["ap_id"] |> URI.decode_www_form()
  83
  84     with {:ok, %Chat{} = chat} <- Chat.get_or_create(user.id, recipient) do
  85       conn
  86       |> put_view(ChatView)
  87       |> render("show.json", chat: chat)
  88     end
  89   end
  90 end