git.squeep.com Git - akkoma/blob - lib/pleroma/web/ostatus/ostatus_controller.ex

   1 defmodule Pleroma.Web.OStatus.OStatusController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.{User, Activity}
   5   alias Pleroma.Web.OStatus.{FeedRepresenter, ActivityRepresenter}
   6   alias Pleroma.Repo
   7   alias Pleroma.Web.{OStatus, Federator}
   8   alias Pleroma.Web.XML
   9   alias Pleroma.Web.ActivityPub.ActivityPubController
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11
  12   def feed_redirect(conn, %{"nickname" => nickname} = params) do
  13     user = User.get_cached_by_nickname(nickname)
  14
  15     case get_format(conn) do
  16       "html" -> Fallback.RedirectController.redirector(conn, nil)
  17       "activity+json" -> ActivityPubController.user(conn, params)
  18       _ -> redirect(conn, external: OStatus.feed_path(user))
  19     end
  20   end
  21
  22   def feed(conn, %{"nickname" => nickname} = params) do
  23     user = User.get_cached_by_nickname(nickname)
  24
  25     query_params =
  26       Map.take(params, ["max_id"])
  27       |> Map.merge(%{"whole_db" => true, "actor_id" => user.ap_id})
  28
  29     activities =
  30       ActivityPub.fetch_public_activities(query_params)
  31       |> Enum.reverse()
  32
  33     response =
  34       user
  35       |> FeedRepresenter.to_simple_form(activities, [user])
  36       |> :xmerl.export_simple(:xmerl_xml)
  37       |> to_string
  38
  39     conn
  40     |> put_resp_content_type("application/atom+xml")
  41     |> send_resp(200, response)
  42   end
  43
  44   defp decode_or_retry(body) do
  45     with {:ok, magic_key} <- Pleroma.Web.Salmon.fetch_magic_key(body),
  46          {:ok, doc} <- Pleroma.Web.Salmon.decode_and_validate(magic_key, body) do
  47       {:ok, doc}
  48     else
  49       _e ->
  50         with [decoded | _] <- Pleroma.Web.Salmon.decode(body),
  51              doc <- XML.parse_document(decoded),
  52              uri when not is_nil(uri) <- XML.string_from_xpath("/entry/author[1]/uri", doc),
  53              {:ok, _} <- Pleroma.Web.OStatus.make_user(uri, true),
  54              {:ok, magic_key} <- Pleroma.Web.Salmon.fetch_magic_key(body),
  55              {:ok, doc} <- Pleroma.Web.Salmon.decode_and_validate(magic_key, body) do
  56           {:ok, doc}
  57         end
  58     end
  59   end
  60
  61   def salmon_incoming(conn, _) do
  62     {:ok, body, _conn} = read_body(conn)
  63     {:ok, doc} = decode_or_retry(body)
  64
  65     Federator.enqueue(:incoming_doc, doc)
  66
  67     conn
  68     |> send_resp(200, "")
  69   end
  70
  71   # TODO: Data leak
  72   def object(conn, %{"uuid" => uuid} = params) do
  73     if get_format(conn) == "activity+json" do
  74       ActivityPubController.object(conn, params)
  75     else
  76       with id <- o_status_url(conn, :object, uuid),
  77            %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  78            %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
  79         case get_format(conn) do
  80           "html" -> redirect(conn, to: "/notice/#{activity.id}")
  81           _ -> represent_activity(conn, activity, user)
  82         end
  83       end
  84     end
  85   end
  86
  87   # TODO: Data leak
  88   def activity(conn, %{"uuid" => uuid}) do
  89     with id <- o_status_url(conn, :activity, uuid),
  90          %Activity{} = activity <- Activity.get_by_ap_id(id),
  91          %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
  92       case get_format(conn) do
  93         "html" -> redirect(conn, to: "/notice/#{activity.id}")
  94         _ -> represent_activity(conn, activity, user)
  95       end
  96     end
  97   end
  98
  99   # TODO: Data leak
 100   def notice(conn, %{"id" => id}) do
 101     with %Activity{} = activity <- Repo.get(Activity, id),
 102          %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
 103       case get_format(conn) do
 104         "html" ->
 105           conn
 106           |> put_resp_content_type("text/html")
 107           |> send_file(200, "priv/static/index.html")
 108
 109         _ ->
 110           represent_activity(conn, activity, user)
 111       end
 112     end
 113   end
 114
 115   defp represent_activity(conn, activity, user) do
 116     response =
 117       activity
 118       |> ActivityRepresenter.to_simple_form(user, true)
 119       |> ActivityRepresenter.wrap_with_entry()
 120       |> :xmerl.export_simple(:xmerl_xml)
 121       |> to_string
 122
 123     conn
 124     |> put_resp_content_type("application/atom+xml")
 125     |> send_resp(200, response)
 126   end
 127 end