git.squeep.com Git - akkoma/blob - lib/pleroma/web/ostatus/ostatus_controller.ex

   1 defmodule Pleroma.Web.OStatus.OStatusController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.{User, Activity}
   5   alias Pleroma.Web.OStatus.{FeedRepresenter, ActivityRepresenter}
   6   alias Pleroma.Repo
   7   alias Pleroma.Web.{OStatus, Federator}
   8   alias Pleroma.Web.XML
   9   alias Pleroma.Web.ActivityPub.ActivityPubController
  10   import Ecto.Query
  11
  12   def feed_redirect(conn, %{"nickname" => nickname} = params) do
  13     user = User.get_cached_by_nickname(nickname)
  14
  15     case get_format(conn) do
  16       "html" -> Fallback.RedirectController.redirector(conn, nil)
  17       "activity+json" -> ActivityPubController.user(conn, params)
  18       _ -> redirect conn, external: OStatus.feed_path(user)
  19     end
  20   end
  21
  22   def feed(conn, %{"nickname" => nickname}) do
  23     user = User.get_cached_by_nickname(nickname)
  24     query = from activity in Activity,
  25       where: fragment("?->>'actor' = ?", activity.data, ^user.ap_id),
  26       limit: 20,
  27       order_by: [desc: :id]
  28
  29     activities = query
  30     |> Repo.all
  31
  32     response = user
  33     |> FeedRepresenter.to_simple_form(activities, [user])
  34     |> :xmerl.export_simple(:xmerl_xml)
  35     |> to_string
  36
  37     conn
  38     |> put_resp_content_type("application/atom+xml")
  39     |> send_resp(200, response)
  40   end
  41
  42   defp decode_or_retry(body) do
  43     with {:ok, magic_key} <- Pleroma.Web.Salmon.fetch_magic_key(body),
  44          {:ok, doc} <- Pleroma.Web.Salmon.decode_and_validate(magic_key, body) do
  45       {:ok, doc}
  46     else
  47       _e ->
  48         with [decoded | _] <- Pleroma.Web.Salmon.decode(body),
  49              doc <- XML.parse_document(decoded),
  50              uri when not is_nil(uri) <- XML.string_from_xpath("/entry/author[1]/uri", doc),
  51              {:ok, _} <- Pleroma.Web.OStatus.make_user(uri, true),
  52              {:ok, magic_key} <- Pleroma.Web.Salmon.fetch_magic_key(body),
  53              {:ok, doc} <- Pleroma.Web.Salmon.decode_and_validate(magic_key, body) do
  54           {:ok, doc}
  55         end
  56     end
  57   end
  58
  59   def salmon_incoming(conn, _) do
  60     {:ok, body, _conn} = read_body(conn)
  61     {:ok, doc} = decode_or_retry(body)
  62
  63     Federator.enqueue(:incoming_doc, doc)
  64
  65     conn
  66     |> send_resp(200, "")
  67   end
  68
  69   def object(conn, %{"uuid" => uuid} = params) do
  70     if get_format(conn) == "activity+json" do
  71       ActivityPubController.object(conn, params)
  72     else
  73       with id <- o_status_url(conn, :object, uuid),
  74            %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  75              %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
  76         case get_format(conn) do
  77           "html" -> redirect(conn, to: "/notice/#{activity.id}")
  78           _ -> represent_activity(conn, activity, user)
  79         end
  80       end
  81     end
  82   end
  83
  84   def activity(conn, %{"uuid" => uuid}) do
  85     with id <- o_status_url(conn, :activity, uuid),
  86          %Activity{} = activity <- Activity.get_by_ap_id(id),
  87          %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
  88       case get_format(conn) do
  89         "html" -> redirect(conn, to: "/notice/#{activity.id}")
  90         _ -> represent_activity(conn, activity, user)
  91       end
  92     end
  93   end
  94
  95   def notice(conn, %{"id" => id}) do
  96      with %Activity{} = activity <- Repo.get(Activity, id),
  97           %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
  98       case get_format(conn) do
  99         "html" ->
 100           conn
 101           |> put_resp_content_type("text/html")
 102           |> send_file(200, "priv/static/index.html")
 103         _ -> represent_activity(conn, activity, user)
 104       end
 105     end
 106   end
 107
 108   defp represent_activity(conn, activity, user) do
 109     response = activity
 110     |> ActivityRepresenter.to_simple_form(user, true)
 111     |> ActivityRepresenter.wrap_with_entry
 112     |> :xmerl.export_simple(:xmerl_xml)
 113     |> to_string
 114
 115     conn
 116     |> put_resp_content_type("application/atom+xml")
 117     |> send_resp(200, response)
 118   end
 119 end