git.squeep.com Git - akkoma/blob - lib/pleroma/web/ostatus/ostatus_controller.ex

   1 defmodule Pleroma.Web.OStatus.OStatusController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.{User, Activity}
   5   alias Pleroma.Web.OStatus.{FeedRepresenter, ActivityRepresenter}
   6   alias Pleroma.Repo
   7   alias Pleroma.Web.{OStatus, Federator}
   8   alias Pleroma.Web.XML
   9   alias Pleroma.Web.ActivityPub.ActivityPubController
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   import Ecto.Query
  12
  13   def feed_redirect(conn, %{"nickname" => nickname} = params) do
  14     user = User.get_cached_by_nickname(nickname)
  15
  16     case get_format(conn) do
  17       "html" -> Fallback.RedirectController.redirector(conn, nil)
  18       "activity+json" -> ActivityPubController.user(conn, params)
  19       _ -> redirect(conn, external: OStatus.feed_path(user))
  20     end
  21   end
  22
  23   def feed(conn, %{"nickname" => nickname} = params) do
  24     user = User.get_cached_by_nickname(nickname)
  25
  26     query_params =
  27       Map.take(params, ["max_id"])
  28       |> Map.merge(%{"whole_db" => true, "actor_id" => user.ap_id})
  29
  30     activities =
  31       ActivityPub.fetch_public_activities(query_params)
  32       |> Enum.reverse()
  33
  34     response =
  35       user
  36       |> FeedRepresenter.to_simple_form(activities, [user])
  37       |> :xmerl.export_simple(:xmerl_xml)
  38       |> to_string
  39
  40     conn
  41     |> put_resp_content_type("application/atom+xml")
  42     |> send_resp(200, response)
  43   end
  44
  45   defp decode_or_retry(body) do
  46     with {:ok, magic_key} <- Pleroma.Web.Salmon.fetch_magic_key(body),
  47          {:ok, doc} <- Pleroma.Web.Salmon.decode_and_validate(magic_key, body) do
  48       {:ok, doc}
  49     else
  50       _e ->
  51         with [decoded | _] <- Pleroma.Web.Salmon.decode(body),
  52              doc <- XML.parse_document(decoded),
  53              uri when not is_nil(uri) <- XML.string_from_xpath("/entry/author[1]/uri", doc),
  54              {:ok, _} <- Pleroma.Web.OStatus.make_user(uri, true),
  55              {:ok, magic_key} <- Pleroma.Web.Salmon.fetch_magic_key(body),
  56              {:ok, doc} <- Pleroma.Web.Salmon.decode_and_validate(magic_key, body) do
  57           {:ok, doc}
  58         end
  59     end
  60   end
  61
  62   def salmon_incoming(conn, _) do
  63     {:ok, body, _conn} = read_body(conn)
  64     {:ok, doc} = decode_or_retry(body)
  65
  66     Federator.enqueue(:incoming_doc, doc)
  67
  68     conn
  69     |> send_resp(200, "")
  70   end
  71
  72   # TODO: Data leak
  73   def object(conn, %{"uuid" => uuid} = params) do
  74     if get_format(conn) == "activity+json" do
  75       ActivityPubController.object(conn, params)
  76     else
  77       with id <- o_status_url(conn, :object, uuid),
  78            %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  79            %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
  80         case get_format(conn) do
  81           "html" -> redirect(conn, to: "/notice/#{activity.id}")
  82           _ -> represent_activity(conn, activity, user)
  83         end
  84       end
  85     end
  86   end
  87
  88   # TODO: Data leak
  89   def activity(conn, %{"uuid" => uuid}) do
  90     with id <- o_status_url(conn, :activity, uuid),
  91          %Activity{} = activity <- Activity.get_by_ap_id(id),
  92          %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
  93       case get_format(conn) do
  94         "html" -> redirect(conn, to: "/notice/#{activity.id}")
  95         _ -> represent_activity(conn, activity, user)
  96       end
  97     end
  98   end
  99
 100   # TODO: Data leak
 101   def notice(conn, %{"id" => id}) do
 102     with %Activity{} = activity <- Repo.get(Activity, id),
 103          %User{} = user <- User.get_cached_by_ap_id(activity.data["actor"]) do
 104       case get_format(conn) do
 105         "html" ->
 106           conn
 107           |> put_resp_content_type("text/html")
 108           |> send_file(200, "priv/static/index.html")
 109
 110         _ ->
 111           represent_activity(conn, activity, user)
 112       end
 113     end
 114   end
 115
 116   defp represent_activity(conn, activity, user) do
 117     response =
 118       activity
 119       |> ActivityRepresenter.to_simple_form(user, true)
 120       |> ActivityRepresenter.wrap_with_entry()
 121       |> :xmerl.export_simple(:xmerl_xml)
 122       |> to_string
 123
 124     conn
 125     |> put_resp_content_type("application/atom+xml")
 126     |> send_resp(200, response)
 127   end
 128 end