git.squeep.com Git - akkoma/blob - lib/pleroma/web/ostatus/ostatus.ex

   1 defmodule Pleroma.Web.OStatus do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   import Ecto.Query
   5   import Pleroma.Web.XML
   6   require Logger
   7
   8   alias Pleroma.{Repo, User, Web, Object, Activity}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.{WebFinger, Websub}
  11   alias Pleroma.Web.OStatus.{FollowHandler, UnfollowHandler, NoteHandler, DeleteHandler}
  12   alias Pleroma.Web.ActivityPub.Transmogrifier
  13
  14   def is_representable?(%Activity{data: data}) do
  15     object = Object.normalize(data["object"])
  16
  17     cond do
  18       is_nil(object) ->
  19         false
  20
  21       object.data["type"] == "Note" ->
  22         true
  23
  24       true ->
  25         false
  26     end
  27   end
  28
  29   def feed_path(user) do
  30     "#{user.ap_id}/feed.atom"
  31   end
  32
  33   def pubsub_path(user) do
  34     "#{Web.base_url()}/push/hub/#{user.nickname}"
  35   end
  36
  37   def salmon_path(user) do
  38     "#{user.ap_id}/salmon"
  39   end
  40
  41   def remote_follow_path do
  42     "#{Web.base_url()}/ostatus_subscribe?acct={uri}"
  43   end
  44
  45   def handle_incoming(xml_string) do
  46     with doc when doc != :error <- parse_document(xml_string) do
  47       entries = :xmerl_xpath.string('//entry', doc)
  48
  49       activities =
  50         Enum.map(entries, fn entry ->
  51           {:xmlObj, :string, object_type} =
  52             :xmerl_xpath.string('string(/entry/activity:object-type[1])', entry)
  53
  54           {:xmlObj, :string, verb} = :xmerl_xpath.string('string(/entry/activity:verb[1])', entry)
  55           Logger.debug("Handling #{verb}")
  56
  57           try do
  58             case verb do
  59               'http://activitystrea.ms/schema/1.0/delete' ->
  60                 with {:ok, activity} <- DeleteHandler.handle_delete(entry, doc), do: activity
  61
  62               'http://activitystrea.ms/schema/1.0/follow' ->
  63                 with {:ok, activity} <- FollowHandler.handle(entry, doc), do: activity
  64
  65               'http://activitystrea.ms/schema/1.0/unfollow' ->
  66                 with {:ok, activity} <- UnfollowHandler.handle(entry, doc), do: activity
  67
  68               'http://activitystrea.ms/schema/1.0/share' ->
  69                 with {:ok, activity, retweeted_activity} <- handle_share(entry, doc),
  70                      do: [activity, retweeted_activity]
  71
  72               'http://activitystrea.ms/schema/1.0/favorite' ->
  73                 with {:ok, activity, favorited_activity} <- handle_favorite(entry, doc),
  74                      do: [activity, favorited_activity]
  75
  76               _ ->
  77                 case object_type do
  78                   'http://activitystrea.ms/schema/1.0/note' ->
  79                     with {:ok, activity} <- NoteHandler.handle_note(entry, doc), do: activity
  80
  81                   'http://activitystrea.ms/schema/1.0/comment' ->
  82                     with {:ok, activity} <- NoteHandler.handle_note(entry, doc), do: activity
  83
  84                   _ ->
  85                     Logger.error("Couldn't parse incoming document")
  86                     nil
  87                 end
  88             end
  89           rescue
  90             e ->
  91               Logger.error("Error occured while handling activity")
  92               Logger.error(xml_string)
  93               Logger.error(inspect(e))
  94               nil
  95           end
  96         end)
  97         |> Enum.filter(& &1)
  98
  99       {:ok, activities}
 100     else
 101       _e -> {:error, []}
 102     end
 103   end
 104
 105   def make_share(entry, doc, retweeted_activity) do
 106     with {:ok, actor} <- find_make_or_update_user(doc),
 107          %Object{} = object <- Object.normalize(retweeted_activity.data["object"]),
 108          id when not is_nil(id) <- string_from_xpath("/entry/id", entry),
 109          {:ok, activity, _object} = ActivityPub.announce(actor, object, id, false) do
 110       {:ok, activity}
 111     end
 112   end
 113
 114   def handle_share(entry, doc) do
 115     with {:ok, retweeted_activity} <- get_or_build_object(entry),
 116          {:ok, activity} <- make_share(entry, doc, retweeted_activity) do
 117       {:ok, activity, retweeted_activity}
 118     else
 119       e -> {:error, e}
 120     end
 121   end
 122
 123   def make_favorite(entry, doc, favorited_activity) do
 124     with {:ok, actor} <- find_make_or_update_user(doc),
 125          %Object{} = object <- Object.normalize(favorited_activity.data["object"]),
 126          id when not is_nil(id) <- string_from_xpath("/entry/id", entry),
 127          {:ok, activity, _object} = ActivityPub.like(actor, object, id, false) do
 128       {:ok, activity}
 129     end
 130   end
 131
 132   def get_or_build_object(entry) do
 133     with {:ok, activity} <- get_or_try_fetching(entry) do
 134       {:ok, activity}
 135     else
 136       _e ->
 137         with [object] <- :xmerl_xpath.string('/entry/activity:object', entry) do
 138           NoteHandler.handle_note(object, object)
 139         end
 140     end
 141   end
 142
 143   def get_or_try_fetching(entry) do
 144     Logger.debug("Trying to get entry from db")
 145
 146     with id when not is_nil(id) <- string_from_xpath("//activity:object[1]/id", entry),
 147          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 148       {:ok, activity}
 149     else
 150       _ ->
 151         Logger.debug("Couldn't get, will try to fetch")
 152
 153         with href when not is_nil(href) <-
 154                string_from_xpath("//activity:object[1]/link[@type=\"text/html\"]/@href", entry),
 155              {:ok, [favorited_activity]} <- fetch_activity_from_url(href) do
 156           {:ok, favorited_activity}
 157         else
 158           e -> Logger.debug("Couldn't find href: #{inspect(e)}")
 159         end
 160     end
 161   end
 162
 163   def handle_favorite(entry, doc) do
 164     with {:ok, favorited_activity} <- get_or_try_fetching(entry),
 165          {:ok, activity} <- make_favorite(entry, doc, favorited_activity) do
 166       {:ok, activity, favorited_activity}
 167     else
 168       e -> {:error, e}
 169     end
 170   end
 171
 172   def get_attachments(entry) do
 173     :xmerl_xpath.string('/entry/link[@rel="enclosure"]', entry)
 174     |> Enum.map(fn enclosure ->
 175       with href when not is_nil(href) <- string_from_xpath("/link/@href", enclosure),
 176            type when not is_nil(type) <- string_from_xpath("/link/@type", enclosure) do
 177         %{
 178           "type" => "Attachment",
 179           "url" => [
 180             %{
 181               "type" => "Link",
 182               "mediaType" => type,
 183               "href" => href
 184             }
 185           ]
 186         }
 187       end
 188     end)
 189     |> Enum.filter(& &1)
 190   end
 191
 192   @doc """
 193     Gets the content from a an entry.
 194   """
 195   def get_content(entry) do
 196     string_from_xpath("//content", entry)
 197   end
 198
 199   @doc """
 200     Get the cw that mastodon uses.
 201   """
 202   def get_cw(entry) do
 203     with cw when not is_nil(cw) <- string_from_xpath("/*/summary", entry) do
 204       cw
 205     else
 206       _e -> nil
 207     end
 208   end
 209
 210   def get_tags(entry) do
 211     :xmerl_xpath.string('//category', entry)
 212     |> Enum.map(fn category -> string_from_xpath("/category/@term", category) end)
 213     |> Enum.filter(& &1)
 214     |> Enum.map(&String.downcase/1)
 215   end
 216
 217   def maybe_update(doc, user) do
 218     if "true" == string_from_xpath("//author[1]/ap_enabled", doc) do
 219       Transmogrifier.upgrade_user_from_ap_id(user.ap_id)
 220     else
 221       maybe_update_ostatus(doc, user)
 222     end
 223   end
 224
 225   def maybe_update_ostatus(doc, user) do
 226     old_data = %{
 227       avatar: user.avatar,
 228       bio: user.bio,
 229       name: user.name,
 230       info: user.info
 231     }
 232
 233     with false <- user.local,
 234          avatar <- make_avatar_object(doc),
 235          bio <- string_from_xpath("//author[1]/summary", doc),
 236          name <- string_from_xpath("//author[1]/poco:displayName", doc),
 237          info <-
 238            Map.put(user.info, "banner", make_avatar_object(doc, "header") || user.info["banner"]),
 239          new_data <- %{
 240            avatar: avatar || old_data.avatar,
 241            name: name || old_data.name,
 242            bio: bio || old_data.bio,
 243            info: info || old_data.info
 244          },
 245          false <- new_data == old_data do
 246       change = Ecto.Changeset.change(user, new_data)
 247       Repo.update(change)
 248     else
 249       _ ->
 250         {:ok, user}
 251     end
 252   end
 253
 254   def find_make_or_update_user(doc) do
 255     uri = string_from_xpath("//author/uri[1]", doc)
 256
 257     with {:ok, user} <- find_or_make_user(uri) do
 258       maybe_update(doc, user)
 259     end
 260   end
 261
 262   def find_or_make_user(uri) do
 263     query = from(user in User, where: user.ap_id == ^uri)
 264
 265     user = Repo.one(query)
 266
 267     if is_nil(user) do
 268       make_user(uri)
 269     else
 270       {:ok, user}
 271     end
 272   end
 273
 274   def make_user(uri, update \\ false) do
 275     with {:ok, info} <- gather_user_info(uri) do
 276       data = %{
 277         name: info["name"],
 278         nickname: info["nickname"] <> "@" <> info["host"],
 279         ap_id: info["uri"],
 280         info: info,
 281         avatar: info["avatar"],
 282         bio: info["bio"]
 283       }
 284
 285       with false <- update,
 286            %User{} = user <- User.get_by_ap_id(data.ap_id) do
 287         {:ok, user}
 288       else
 289         _e -> User.insert_or_update_user(data)
 290       end
 291     end
 292   end
 293
 294   # TODO: Just takes the first one for now.
 295   def make_avatar_object(author_doc, rel \\ "avatar") do
 296     href = string_from_xpath("//author[1]/link[@rel=\"#{rel}\"]/@href", author_doc)
 297     type = string_from_xpath("//author[1]/link[@rel=\"#{rel}\"]/@type", author_doc)
 298
 299     if href do
 300       %{
 301         "type" => "Image",
 302         "url" => [
 303           %{
 304             "type" => "Link",
 305             "mediaType" => type,
 306             "href" => href
 307           }
 308         ]
 309       }
 310     else
 311       nil
 312     end
 313   end
 314
 315   def gather_user_info(username) do
 316     with {:ok, webfinger_data} <- WebFinger.finger(username),
 317          {:ok, feed_data} <- Websub.gather_feed_data(webfinger_data["topic"]) do
 318       {:ok, Map.merge(webfinger_data, feed_data) |> Map.put("fqn", username)}
 319     else
 320       e ->
 321         Logger.debug(fn -> "Couldn't gather info for #{username}" end)
 322         {:error, e}
 323     end
 324   end
 325
 326   # Regex-based 'parsing' so we don't have to pull in a full html parser
 327   # It's a hack anyway. Maybe revisit this in the future
 328   @mastodon_regex ~r/<link href='(.*)' rel='alternate' type='application\/atom\+xml'>/
 329   @gs_regex ~r/<link title=.* href="(.*)" type="application\/atom\+xml" rel="alternate">/
 330   @gs_classic_regex ~r/<link rel="alternate" href="(.*)" type="application\/atom\+xml" title=.*>/
 331   def get_atom_url(body) do
 332     cond do
 333       Regex.match?(@mastodon_regex, body) ->
 334         [[_, match]] = Regex.scan(@mastodon_regex, body)
 335         {:ok, match}
 336
 337       Regex.match?(@gs_regex, body) ->
 338         [[_, match]] = Regex.scan(@gs_regex, body)
 339         {:ok, match}
 340
 341       Regex.match?(@gs_classic_regex, body) ->
 342         [[_, match]] = Regex.scan(@gs_classic_regex, body)
 343         {:ok, match}
 344
 345       true ->
 346         Logger.debug(fn -> "Couldn't find Atom link in #{inspect(body)}" end)
 347         {:error, "Couldn't find the Atom link"}
 348     end
 349   end
 350
 351   def fetch_activity_from_atom_url(url) do
 352     with true <- String.starts_with?(url, "http"),
 353          {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 354            @httpoison.get(
 355              url,
 356              [Accept: "application/atom+xml"],
 357              follow_redirect: true,
 358              timeout: 10000,
 359              recv_timeout: 20000
 360            ) do
 361       Logger.debug("Got document from #{url}, handling...")
 362       handle_incoming(body)
 363     else
 364       e ->
 365         Logger.debug("Couldn't get #{url}: #{inspect(e)}")
 366         e
 367     end
 368   end
 369
 370   def fetch_activity_from_html_url(url) do
 371     Logger.debug("Trying to fetch #{url}")
 372
 373     with true <- String.starts_with?(url, "http"),
 374          {:ok, %{body: body}} <-
 375            @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000),
 376          {:ok, atom_url} <- get_atom_url(body) do
 377       fetch_activity_from_atom_url(atom_url)
 378     else
 379       e ->
 380         Logger.debug("Couldn't get #{url}: #{inspect(e)}")
 381         e
 382     end
 383   end
 384
 385   def fetch_activity_from_url(url) do
 386     try do
 387       with {:ok, activities} when length(activities) > 0 <- fetch_activity_from_atom_url(url) do
 388         {:ok, activities}
 389       else
 390         _e ->
 391           with {:ok, activities} <- fetch_activity_from_html_url(url) do
 392             {:ok, activities}
 393           end
 394       end
 395     rescue
 396       e ->
 397         Logger.debug("Couldn't get #{url}: #{inspect(e)}")
 398         {:error, "Couldn't get #{url}: #{inspect(e)}"}
 399     end
 400   end
 401 end