git.squeep.com Git - akkoma/blob - lib/pleroma/web/ostatus/ostatus.ex

   1 defmodule Pleroma.Web.OStatus do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   import Ecto.Query
   5   import Pleroma.Web.XML
   6   require Logger
   7
   8   alias Pleroma.{Repo, User, Web, Object, Activity}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.{WebFinger, Websub}
  11   alias Pleroma.Web.OStatus.{FollowHandler, NoteHandler, DeleteHandler}
  12
  13   def feed_path(user) do
  14     "#{user.ap_id}/feed.atom"
  15   end
  16
  17   def pubsub_path(user) do
  18     "#{Web.base_url}/push/hub/#{user.nickname}"
  19   end
  20
  21   def salmon_path(user) do
  22     "#{user.ap_id}/salmon"
  23   end
  24
  25   def remote_follow_path do
  26     "#{Web.base_url}/ostatus_subscribe?acct={uri}"
  27   end
  28
  29   def handle_incoming(xml_string) do
  30     with doc when doc != :error <- parse_document(xml_string) do
  31       entries = :xmerl_xpath.string('//entry', doc)
  32
  33       activities = Enum.map(entries, fn (entry) ->
  34         {:xmlObj, :string, object_type} = :xmerl_xpath.string('string(/entry/activity:object-type[1])', entry)
  35         {:xmlObj, :string, verb} = :xmerl_xpath.string('string(/entry/activity:verb[1])', entry)
  36         Logger.debug("Handling #{verb}")
  37
  38         try do
  39           case verb do
  40             'http://activitystrea.ms/schema/1.0/delete' ->
  41               with {:ok, activity} <- DeleteHandler.handle_delete(entry, doc), do: activity
  42             'http://activitystrea.ms/schema/1.0/follow' ->
  43               with {:ok, activity} <- FollowHandler.handle(entry, doc), do: activity
  44             'http://activitystrea.ms/schema/1.0/share' ->
  45               with {:ok, activity, retweeted_activity} <- handle_share(entry, doc), do: [activity, retweeted_activity]
  46             'http://activitystrea.ms/schema/1.0/favorite' ->
  47               with {:ok, activity, favorited_activity} <- handle_favorite(entry, doc), do: [activity, favorited_activity]
  48             _ ->
  49               case object_type do
  50                 'http://activitystrea.ms/schema/1.0/note' ->
  51                   with {:ok, activity} <- NoteHandler.handle_note(entry, doc), do: activity
  52                 'http://activitystrea.ms/schema/1.0/comment' ->
  53                   with {:ok, activity} <- NoteHandler.handle_note(entry, doc), do: activity
  54                 _ ->
  55                   Logger.error("Couldn't parse incoming document")
  56                   nil
  57               end
  58           end
  59         rescue
  60           e ->
  61             Logger.error("Error occured while handling activity")
  62             Logger.error(xml_string)
  63           Logger.error(inspect(e))
  64           nil
  65         end
  66       end)
  67       |> Enum.filter(&(&1))
  68
  69       {:ok, activities}
  70     else
  71       _e -> {:error, []}
  72     end
  73   end
  74
  75   def make_share(entry, doc, retweeted_activity) do
  76     with {:ok, actor} <- find_make_or_update_user(doc),
  77          %Object{} = object <- Object.get_by_ap_id(retweeted_activity.data["object"]["id"]),
  78          id when not is_nil(id) <- string_from_xpath("/entry/id", entry),
  79          {:ok, activity, _object} = ActivityPub.announce(actor, object, id, false) do
  80       {:ok, activity}
  81     end
  82   end
  83
  84   def handle_share(entry, doc) do
  85     with {:ok, retweeted_activity} <- get_or_build_object(entry),
  86          {:ok, activity} <- make_share(entry, doc, retweeted_activity) do
  87       {:ok, activity, retweeted_activity}
  88     else
  89       e -> {:error, e}
  90     end
  91   end
  92
  93   def make_favorite(entry, doc, favorited_activity) do
  94     with {:ok, actor} <- find_make_or_update_user(doc),
  95          %Object{} = object <- Object.get_by_ap_id(favorited_activity.data["object"]["id"]),
  96          id when not is_nil(id) <- string_from_xpath("/entry/id", entry),
  97          {:ok, activity, _object} = ActivityPub.like(actor, object, id, false) do
  98       {:ok, activity}
  99     end
 100   end
 101
 102   def get_or_build_object(entry) do
 103     with {:ok, activity} <- get_or_try_fetching(entry) do
 104       {:ok, activity}
 105     else
 106       _e ->
 107         with [object] <- :xmerl_xpath.string('/entry/activity:object', entry) do
 108           NoteHandler.handle_note(object, object)
 109         end
 110     end
 111   end
 112
 113   def get_or_try_fetching(entry) do
 114     Logger.debug("Trying to get entry from db")
 115     with id when not is_nil(id) <- string_from_xpath("//activity:object[1]/id", entry),
 116          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 117       {:ok, activity}
 118     else _ ->
 119         Logger.debug("Couldn't get, will try to fetch")
 120         with href when not is_nil(href) <- string_from_xpath("//activity:object[1]/link[@type=\"text/html\"]/@href", entry),
 121              {:ok, [favorited_activity]} <- fetch_activity_from_url(href) do
 122           {:ok, favorited_activity}
 123         else e -> Logger.debug("Couldn't find href: #{inspect(e)}")
 124         end
 125     end
 126   end
 127
 128   def handle_favorite(entry, doc) do
 129     with {:ok, favorited_activity} <- get_or_try_fetching(entry),
 130          {:ok, activity} <- make_favorite(entry, doc, favorited_activity) do
 131       {:ok, activity, favorited_activity}
 132     else
 133       e -> {:error, e}
 134     end
 135   end
 136
 137   def get_attachments(entry) do
 138     :xmerl_xpath.string('/entry/link[@rel="enclosure"]', entry)
 139     |> Enum.map(fn (enclosure) ->
 140       with href when not is_nil(href) <- string_from_xpath("/link/@href", enclosure),
 141            type when not is_nil(type) <- string_from_xpath("/link/@type", enclosure) do
 142         %{
 143           "type" => "Attachment",
 144           "url" => [%{
 145                        "type" => "Link",
 146                        "mediaType" => type,
 147                        "href" => href
 148                     }]
 149         }
 150       end
 151     end)
 152     |> Enum.filter(&(&1))
 153   end
 154
 155   @doc """
 156     Gets the content from a an entry.
 157   """
 158   def get_content(entry) do
 159     string_from_xpath("//content", entry)
 160   end
 161
 162   @doc """
 163     Get the cw that mastodon uses.
 164   """
 165   def get_cw(entry) do
 166     with scope when not is_nil(scope) <- string_from_xpath("//mastodon:scope", entry),
 167          cw when not is_nil(cw) <- string_from_xpath("/*/summary", entry) do
 168       cw
 169     else _e -> nil
 170     end
 171   end
 172
 173   def get_tags(entry) do
 174     :xmerl_xpath.string('//category', entry)
 175     |> Enum.map(fn (category) -> string_from_xpath("/category/@term", category) end)
 176     |> Enum.filter(&(&1))
 177     |> Enum.map(&String.downcase/1)
 178   end
 179
 180   def maybe_update(doc, user) do
 181     old_data = %{
 182       avatar: user.avatar,
 183       bio: user.bio,
 184       name: user.name,
 185       info: user.info
 186     }
 187
 188     with false <- user.local,
 189          avatar <- make_avatar_object(doc),
 190          bio <- string_from_xpath("//author[1]/summary", doc),
 191          name <- string_from_xpath("//author[1]/poco:displayName", doc),
 192          info <- Map.put(user.info, "banner", make_avatar_object(doc, "header") || user.info["banner"]),
 193          new_data <- %{avatar: avatar || old_data.avatar, name: name || old_data.name, bio: bio || old_data.bio, info: info || old_data.info},
 194          false <- new_data == old_data do
 195       change = Ecto.Changeset.change(user, new_data)
 196       Repo.update(change)
 197     else _ ->
 198       {:ok, user}
 199     end
 200   end
 201
 202   def find_make_or_update_user(doc) do
 203     uri = string_from_xpath("//author/uri[1]", doc)
 204     with {:ok, user} <- find_or_make_user(uri) do
 205       maybe_update(doc, user)
 206     end
 207   end
 208
 209   def find_or_make_user(uri) do
 210     query = from user in User,
 211       where: user.ap_id == ^uri
 212
 213     user = Repo.one(query)
 214
 215     if is_nil(user) do
 216       make_user(uri)
 217     else
 218       {:ok, user}
 219     end
 220   end
 221
 222   def insert_or_update_user(data) do
 223     cs = User.remote_user_creation(data)
 224     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 225   end
 226
 227   def make_user(uri, update \\ false) do
 228     with {:ok, info} <- gather_user_info(uri) do
 229       data = %{
 230         name: info["name"],
 231         nickname: info["nickname"] <> "@" <> info["host"],
 232         ap_id: info["uri"],
 233         info: info,
 234         avatar: info["avatar"],
 235         bio: info["bio"]
 236       }
 237       with false <- update,
 238            %User{} = user <- User.get_by_ap_id(data.ap_id) do
 239         {:ok, user}
 240       else _e -> insert_or_update_user(data)
 241       end
 242     end
 243   end
 244
 245   # TODO: Just takes the first one for now.
 246   def make_avatar_object(author_doc, rel \\ "avatar") do
 247     href = string_from_xpath("//author[1]/link[@rel=\"#{rel}\"]/@href", author_doc)
 248     type = string_from_xpath("//author[1]/link[@rel=\"#{rel}\"]/@type", author_doc)
 249
 250     if href do
 251       %{
 252         "type" => "Image",
 253         "url" =>
 254           [%{
 255               "type" => "Link",
 256               "mediaType" => type,
 257               "href" => href
 258            }]
 259       }
 260     else
 261       nil
 262     end
 263   end
 264
 265   def gather_user_info(username) do
 266     with {:ok, webfinger_data} <- WebFinger.finger(username),
 267          {:ok, feed_data} <- Websub.gather_feed_data(webfinger_data["topic"]) do
 268       {:ok, Map.merge(webfinger_data, feed_data) |> Map.put("fqn", username)}
 269     else e ->
 270       Logger.debug(fn -> "Couldn't gather info for #{username}" end)
 271       {:error, e}
 272     end
 273   end
 274
 275   # Regex-based 'parsing' so we don't have to pull in a full html parser
 276   # It's a hack anyway. Maybe revisit this in the future
 277   @mastodon_regex ~r/<link href='(.*)' rel='alternate' type='application\/atom\+xml'>/
 278   @gs_regex ~r/<link title=.* href="(.*)" type="application\/atom\+xml" rel="alternate">/
 279   @gs_classic_regex ~r/<link rel="alternate" href="(.*)" type="application\/atom\+xml" title=.*>/
 280   def get_atom_url(body) do
 281     cond do
 282       Regex.match?(@mastodon_regex, body) ->
 283         [[_, match]] = Regex.scan(@mastodon_regex, body)
 284         {:ok, match}
 285       Regex.match?(@gs_regex, body) ->
 286         [[_, match]] = Regex.scan(@gs_regex, body)
 287         {:ok, match}
 288       Regex.match?(@gs_classic_regex, body) ->
 289         [[_, match]] = Regex.scan(@gs_classic_regex, body)
 290         {:ok, match}
 291       true ->
 292         Logger.debug(fn -> "Couldn't find atom link in #{inspect(body)}" end)
 293         {:error, "Couldn't find the atom link"}
 294     end
 295   end
 296
 297   def fetch_activity_from_atom_url(url) do
 298     with {:ok, %{body: body, status_code: code}} when code in 200..299 <- @httpoison.get(url, [Accept: "application/atom+xml"], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 299       Logger.debug("Got document from #{url}, handling...")
 300       handle_incoming(body)
 301     else e -> Logger.debug("Couldn't get #{url}: #{inspect(e)}")
 302     end
 303   end
 304
 305   def fetch_activity_from_html_url(url) do
 306     Logger.debug("Trying to fetch #{url}")
 307     with {:ok, %{body: body}} <- @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000),
 308          {:ok, atom_url} <- get_atom_url(body) do
 309         fetch_activity_from_atom_url(atom_url)
 310     else e -> Logger.debug("Couldn't get #{url}: #{inspect(e)}")
 311     end
 312   end
 313
 314   def fetch_activity_from_url(url) do
 315     try do
 316       with {:ok, activities} when length(activities) > 0 <- fetch_activity_from_atom_url(url) do
 317         {:ok, activities}
 318       else
 319         _e -> with {:ok, activities} <- fetch_activity_from_html_url(url) do
 320                 {:ok, activities}
 321               end
 322       end
 323     rescue
 324       e ->
 325         Logger.debug("Couldn't get #{url}: #{inspect(e)}")
 326         {:error, "Couldn't get #{url}: #{inspect(e)}"}
 327     end
 328   end
 329 end