git.squeep.com Git - akkoma/blob - lib/pleroma/web/ostatus/ostatus.ex

   1 defmodule Pleroma.Web.OStatus do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   import Ecto.Query
   5   import Pleroma.Web.XML
   6   require Logger
   7
   8   alias Pleroma.{Repo, User, Web, Object, Activity}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.{WebFinger, Websub}
  11
  12   def feed_path(user) do
  13     "#{user.ap_id}/feed.atom"
  14   end
  15
  16   def pubsub_path(user) do
  17     "#{Web.base_url}/push/hub/#{user.nickname}"
  18   end
  19
  20   def salmon_path(user) do
  21     "#{user.ap_id}/salmon"
  22   end
  23
  24   def handle_incoming(xml_string) do
  25     doc = parse_document(xml_string)
  26     entries = :xmerl_xpath.string('//entry', doc)
  27
  28     activities = Enum.map(entries, fn (entry) ->
  29       {:xmlObj, :string, object_type} = :xmerl_xpath.string('string(/entry/activity:object-type[1])', entry)
  30       {:xmlObj, :string, verb} = :xmerl_xpath.string('string(/entry/activity:verb[1])', entry)
  31
  32       case verb do
  33         'http://activitystrea.ms/schema/1.0/share' ->
  34           with {:ok, activity, retweeted_activity} <- handle_share(entry, doc), do: [activity, retweeted_activity]
  35         'http://activitystrea.ms/schema/1.0/favorite' ->
  36           with {:ok, activity, favorited_activity} <- handle_favorite(entry, doc), do: [activity, favorited_activity]
  37         _ ->
  38           case object_type do
  39             'http://activitystrea.ms/schema/1.0/note' ->
  40               with {:ok, activity} <- handle_note(entry, doc), do: activity
  41             'http://activitystrea.ms/schema/1.0/comment' ->
  42               with {:ok, activity} <- handle_note(entry, doc), do: activity
  43             _ ->
  44               Logger.error("Couldn't parse incoming document")
  45               nil
  46           end
  47       end
  48     end)
  49     {:ok, activities}
  50   end
  51
  52   def make_share(_entry, doc, retweeted_activity) do
  53     with {:ok, actor} <- find_make_or_update_user(doc),
  54          %Object{} = object <- Object.get_cached_by_ap_id(retweeted_activity.data["object"]["id"]),
  55          {:ok, activity, _object} = ActivityPub.announce(actor, object, false) do
  56       {:ok, activity}
  57     end
  58   end
  59
  60   def handle_share(entry, doc) do
  61     with [object] <- :xmerl_xpath.string('/entry/activity:object', entry),
  62          {:ok, retweeted_activity} <-  handle_note(object, object),
  63          {:ok, activity} <- make_share(entry, doc, retweeted_activity) do
  64       {:ok, activity, retweeted_activity}
  65     else
  66       e -> {:error, e}
  67     end
  68   end
  69
  70   def make_favorite(_entry, doc, favorited_activity) do
  71     with {:ok, actor} <- find_make_or_update_user(doc),
  72          %Object{} = object <- Object.get_cached_by_ap_id(favorited_activity.data["object"]["id"]),
  73          {:ok, activity, _object} = ActivityPub.like(actor, object, false) do
  74       {:ok, activity}
  75     end
  76   end
  77
  78   def get_or_try_fetching(entry) do
  79     with id when not is_nil(id) <- string_from_xpath("//activity:object[1]/id", entry),
  80          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  81       {:ok, activity}
  82     else _e ->
  83         with href when not is_nil(href) <- string_from_xpath("//activity:object[1]/link[@type=\"text/html\"]/@href", entry),
  84              {:ok, [favorited_activity]} <- fetch_activity_from_html_url(href) do
  85           {:ok, favorited_activity}
  86         end
  87     end
  88   end
  89
  90   def handle_favorite(entry, doc) do
  91     with {:ok, favorited_activity} <- get_or_try_fetching(entry),
  92          {:ok, activity} <- make_favorite(entry, doc, favorited_activity) do
  93       {:ok, activity, favorited_activity}
  94     else
  95       e -> {:error, e}
  96     end
  97   end
  98
  99   def get_attachments(entry) do
 100     :xmerl_xpath.string('/entry/link[@rel="enclosure"]', entry)
 101     |> Enum.map(fn (enclosure) ->
 102       with href when not is_nil(href) <- string_from_xpath("/link/@href", enclosure),
 103            type when not is_nil(type) <- string_from_xpath("/link/@type", enclosure) do
 104         %{
 105           "type" => "Attachment",
 106           "url" => [%{
 107                        "type" => "Link",
 108                        "mediaType" => type,
 109                        "href" => href
 110                     }]
 111         }
 112       end
 113     end)
 114     |> Enum.filter(&(&1))
 115   end
 116
 117   def handle_note(entry, doc \\ nil) do
 118     content_html = string_from_xpath("//content[1]", entry)
 119
 120     [author] = :xmerl_xpath.string('//author[1]', doc)
 121     {:ok, actor} = find_make_or_update_user(author)
 122     inReplyTo = string_from_xpath("//thr:in-reply-to[1]/@ref", entry)
 123
 124     if !Object.get_cached_by_ap_id(inReplyTo) do
 125       inReplyToHref = string_from_xpath("//thr:in-reply-to[1]/@href", entry)
 126       if inReplyToHref do
 127         fetch_activity_from_html_url(inReplyToHref)
 128       end
 129     end
 130
 131     context = (string_from_xpath("//ostatus:conversation[1]", entry) || "") |> String.trim
 132
 133     attachments = get_attachments(entry)
 134
 135     context = with %{data: %{"context" => context}} <- Object.get_cached_by_ap_id(inReplyTo) do
 136                 context
 137               else _e ->
 138                 if String.length(context) > 0 do
 139                   context
 140                 else
 141                   ActivityPub.generate_context_id
 142                 end
 143               end
 144
 145     to = [
 146       "https://www.w3.org/ns/activitystreams#Public"
 147     ]
 148
 149     mentions = :xmerl_xpath.string('//link[@rel="mentioned" and @ostatus:object-type="http://activitystrea.ms/schema/1.0/person"]', entry)
 150     |> Enum.map(fn(person) -> string_from_xpath("@href", person) end)
 151
 152     to = to ++ mentions
 153
 154     date = string_from_xpath("//published", entry)
 155     id = string_from_xpath("//id", entry)
 156
 157     object = %{
 158       "id" => id,
 159       "type" => "Note",
 160       "to" => to,
 161       "content" => content_html,
 162       "published" => date,
 163       "context" => context,
 164       "actor" => actor.ap_id,
 165       "attachment" => attachments
 166     }
 167
 168     object = if inReplyTo do
 169       Map.put(object, "inReplyTo", inReplyTo)
 170     else
 171       object
 172     end
 173
 174     # TODO: Bail out sooner and use transaction.
 175     if Object.get_by_ap_id(id) do
 176       {:error, "duplicate activity"}
 177     else
 178       ActivityPub.create(to, actor, context, object, %{}, date, false)
 179     end
 180   end
 181
 182   def find_make_or_update_user(doc) do
 183     uri = string_from_xpath("//author/uri[1]", doc)
 184     with {:ok, user} <- find_or_make_user(uri) do
 185       avatar = make_avatar_object(doc)
 186       if user.avatar != avatar do
 187         change = Ecto.Changeset.change(user, %{avatar: avatar})
 188         Repo.update(change)
 189       else
 190         {:ok, user}
 191       end
 192     end
 193   end
 194
 195   def find_or_make_user(uri) do
 196     query = from user in User,
 197       where: user.local == false and fragment("? @> ?", user.info, ^%{uri: uri})
 198
 199     user = Repo.one(query)
 200
 201     if is_nil(user) do
 202       make_user(uri)
 203     else
 204       {:ok, user}
 205     end
 206   end
 207
 208   def make_user(uri) do
 209     with {:ok, info} <- gather_user_info(uri) do
 210       data = %{
 211         local: false,
 212         name: info["name"],
 213         nickname: info["nickname"] <> "@" <> info["host"],
 214         ap_id: info["uri"],
 215         info: info,
 216         avatar: info["avatar"]
 217       }
 218       # TODO: Make remote user changeset
 219       # SHould enforce fqn nickname
 220       Repo.insert(Ecto.Changeset.change(%User{}, data))
 221     end
 222   end
 223
 224   # TODO: Just takes the first one for now.
 225   def make_avatar_object(author_doc) do
 226     href = string_from_xpath("//author[1]/link[@rel=\"avatar\"]/@href", author_doc)
 227     type = string_from_xpath("//author[1]/link[@rel=\"avatar\"]/@type", author_doc)
 228
 229     if href do
 230       %{
 231         "type" => "Image",
 232         "url" =>
 233           [%{
 234               "type" => "Link",
 235               "mediaType" => type,
 236               "href" => href
 237            }]
 238       }
 239     else
 240       nil
 241     end
 242   end
 243
 244   def gather_user_info(username) do
 245     with {:ok, webfinger_data} <- WebFinger.finger(username),
 246          {:ok, feed_data} <- Websub.gather_feed_data(webfinger_data["topic"]) do
 247       {:ok, Map.merge(webfinger_data, feed_data) |> Map.put("fqn", username)}
 248     else e ->
 249       Logger.debug(fn -> "Couldn't gather info for #{username}" end)
 250       {:error, e}
 251     end
 252   end
 253
 254   # Regex-based 'parsing' so we don't have to pull in a full html parser
 255   # It's a hack anyway. Maybe revisit this in the future
 256   @mastodon_regex ~r/<link href='(.*)' rel='alternate' type='application\/atom\+xml'>/
 257   @gs_regex ~r/<link title=.* href="(.*)" type="application\/atom\+xml" rel="alternate">/
 258   @gs_classic_regex ~r/<link rel="alternate" href="(.*)" type="application\/atom\+xml" title=.*>/
 259   def get_atom_url(body) do
 260     cond do
 261       Regex.match?(@mastodon_regex, body) ->
 262         [[_, match]] = Regex.scan(@mastodon_regex, body)
 263         {:ok, match}
 264       Regex.match?(@gs_regex, body) ->
 265         [[_, match]] = Regex.scan(@gs_regex, body)
 266         {:ok, match}
 267       Regex.match?(@gs_classic_regex, body) ->
 268         [[_, match]] = Regex.scan(@gs_classic_regex, body)
 269         {:ok, match}
 270       true ->
 271         Logger.debug(fn -> "Couldn't find atom link in #{inspect(body)}" end)
 272         {:error, "Couldn't find the atom link"}
 273     end
 274   end
 275
 276   def fetch_activity_from_html_url(url) do
 277     with {:ok, %{body: body}} <- @httpoison.get(url),
 278          {:ok, atom_url} <- get_atom_url(body),
 279          {:ok, %{status_code: code, body: body}} when code in 200..299 <- @httpoison.get(atom_url) do
 280       handle_incoming(body)
 281     end
 282   end
 283 end