git.squeep.com Git - akkoma/blob - lib/pleroma/web/ostatus/ostatus.ex

   1 defmodule Pleroma.Web.OStatus do
   2   import Ecto.Query
   3   require Logger
   4
   5   alias Pleroma.{Repo, User, Web}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7
   8   def feed_path(user) do
   9     "#{user.ap_id}/feed.atom"
  10   end
  11
  12   def pubsub_path(user) do
  13     "#{Web.base_url}/push/hub/#{user.nickname}"
  14   end
  15
  16   def salmon_path(user) do
  17     "#{user.ap_id}/salmon"
  18   end
  19
  20   def handle_incoming(xml_string) do
  21     {doc, _rest} = :xmerl_scan.string(to_charlist(xml_string))
  22
  23     {:xmlObj, :string, object_type } = :xmerl_xpath.string('string(/entry/activity:object-type[1])', doc)
  24
  25     case object_type do
  26       'http://activitystrea.ms/schema/1.0/note' ->
  27         handle_note(doc)
  28       _ ->
  29         Logger.error("Couldn't parse incoming document")
  30     end
  31   end
  32
  33   # TODO
  34   # wire up replies
  35   def handle_note(doc) do
  36     content_html = string_from_xpath("/entry/content[1]", doc)
  37
  38     [author] = :xmerl_xpath.string('/entry/author[1]', doc)
  39     {:ok, actor} = find_or_make_user(author)
  40
  41     context = string_from_xpath("/entry/ostatus:conversation[1]", doc) |> String.trim
  42     context = if String.length(context) > 0 do
  43       context
  44     else
  45       ActivityPub.generate_context_id
  46     end
  47
  48     to = [
  49       "https://www.w3.org/ns/activitystreams#Public"
  50     ]
  51
  52     mentions = :xmerl_xpath.string('/entry/link[@rel="mentioned" and @ostatus:object-type="http://activitystrea.ms/schema/1.0/person"]', doc)
  53     |> Enum.map(fn(person) -> string_from_xpath("@href", person) end)
  54
  55     to = to ++ mentions
  56
  57     date = string_from_xpath("/entry/published", doc)
  58
  59     object = %{
  60       "type" => "Note",
  61       "to" => to,
  62       "content" => content_html,
  63       "published" => date,
  64       "context" => context,
  65       "actor" => actor.ap_id
  66     }
  67
  68     ActivityPub.create(to, actor, context, object, %{}, date)
  69   end
  70
  71   def find_or_make_user(author_doc) do
  72     {:xmlObj, :string, uri } = :xmerl_xpath.string('string(/author[1]/uri)', author_doc)
  73
  74     query = from user in User,
  75       where: user.local == false and fragment("? @> ?", user.info, ^%{ostatus_uri: to_string(uri)})
  76
  77     user = Repo.one(query)
  78
  79     if is_nil(user) do
  80       make_user(author_doc)
  81     else
  82       {:ok, user}
  83     end
  84   end
  85
  86   defp string_from_xpath(xpath, doc) do
  87     {:xmlObj, :string, res} = :xmerl_xpath.string('string(#{xpath})', doc)
  88
  89     res = res
  90     |> to_string
  91     |> String.trim
  92
  93     if res == "", do: nil, else: res
  94   end
  95
  96   def make_user(author_doc) do
  97     author = string_from_xpath("/author[1]/uri", author_doc)
  98     name = string_from_xpath("/author[1]/name", author_doc)
  99     preferredUsername = string_from_xpath("/author[1]/poco:preferredUsername", author_doc)
 100     displayName = string_from_xpath("/author[1]/poco:displayName", author_doc)
 101     avatar = make_avatar_object(author_doc)
 102
 103     data = %{
 104       local: false,
 105       name: preferredUsername || name,
 106       nickname: displayName || name,
 107       ap_id: author,
 108       info: %{
 109         "ostatus_uri" => author,
 110         "host" => URI.parse(author).host,
 111         "system" => "ostatus"
 112       },
 113       avatar: avatar
 114     }
 115
 116     Repo.insert(Ecto.Changeset.change(%User{}, data))
 117   end
 118
 119   # TODO: Just takes the first one for now.
 120   defp make_avatar_object(author_doc) do
 121     href = string_from_xpath("/author[1]/link[@rel=\"avatar\"]/@href", author_doc)
 122     type = string_from_xpath("/author[1]/link[@rel=\"avatar\"]/@type", author_doc)
 123
 124     if href do
 125       %{
 126         "type" => "Image",
 127         "url" =>
 128           [%{
 129               "type" => "Link",
 130               "mediaType" => type,
 131               "href" => href
 132            }]
 133       }
 134     else
 135       nil
 136     end
 137   end
 138 end