git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Token do
   6   use Ecto.Schema
   7
   8   import Ecto.Query
   9   import Ecto.Changeset
  10
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.OAuth.App
  14   alias Pleroma.Web.OAuth.Authorization
  15   alias Pleroma.Web.OAuth.Token
  16
  17   @expires_in Pleroma.Config.get([:oauth2, :token_expires_in], 600)
  18   @type t :: %__MODULE__{}
  19
  20   schema "oauth_tokens" do
  21     field(:token, :string)
  22     field(:refresh_token, :string)
  23     field(:scopes, {:array, :string}, default: [])
  24     field(:valid_until, :naive_datetime_usec)
  25     belongs_to(:user, Pleroma.User, type: Pleroma.FlakeId)
  26     belongs_to(:app, App)
  27
  28     timestamps()
  29   end
  30
  31   @doc "Gets token for app by access token"
  32   @spec get_by_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  33   def get_by_token(%App{id: app_id} = _app, token) do
  34     from(t in __MODULE__, where: t.app_id == ^app_id and t.token == ^token)
  35     |> Repo.find_resource()
  36   end
  37
  38   @doc "Gets token for app by refresh token"
  39   @spec get_by_refresh_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  40   def get_by_refresh_token(%App{id: app_id} = _app, token) do
  41     from(t in __MODULE__,
  42       where: t.app_id == ^app_id and t.refresh_token == ^token,
  43       preload: [:user]
  44     )
  45     |> Repo.find_resource()
  46   end
  47
  48   @spec exchange_token(App.t(), Authorization.t()) ::
  49           {:ok, Token.t()} | {:error, Changeset.t()}
  50   def exchange_token(app, auth) do
  51     with {:ok, auth} <- Authorization.use_token(auth),
  52          true <- auth.app_id == app.id do
  53       user = if auth.user_id, do: User.get_cached_by_id(auth.user_id), else: %User{}
  54
  55       create_token(
  56         app,
  57         user,
  58         %{scopes: auth.scopes}
  59       )
  60     end
  61   end
  62
  63   defp put_token(changeset) do
  64     changeset
  65     |> change(%{token: Token.Utils.generate_token()})
  66     |> validate_required([:token])
  67     |> unique_constraint(:token)
  68   end
  69
  70   defp put_refresh_token(changeset, attrs) do
  71     refresh_token = Map.get(attrs, :refresh_token, Token.Utils.generate_token())
  72
  73     changeset
  74     |> change(%{refresh_token: refresh_token})
  75     |> validate_required([:refresh_token])
  76     |> unique_constraint(:refresh_token)
  77   end
  78
  79   defp put_valid_until(changeset, attrs) do
  80     expires_in =
  81       Map.get(attrs, :valid_until, NaiveDateTime.add(NaiveDateTime.utc_now(), @expires_in))
  82
  83     changeset
  84     |> change(%{valid_until: expires_in})
  85     |> validate_required([:valid_until])
  86   end
  87
  88   @spec create_token(App.t(), User.t(), map()) :: {:ok, Token} | {:error, Changeset.t()}
  89   def create_token(%App{} = app, %User{} = user, attrs \\ %{}) do
  90     %__MODULE__{user_id: user.id, app_id: app.id}
  91     |> cast(%{scopes: attrs[:scopes] || app.scopes}, [:scopes])
  92     |> validate_required([:scopes, :app_id])
  93     |> put_valid_until(attrs)
  94     |> put_token()
  95     |> put_refresh_token(attrs)
  96     |> Repo.insert()
  97   end
  98
  99   def delete_user_tokens(%User{id: user_id}) do
 100     from(
 101       t in Token,
 102       where: t.user_id == ^user_id
 103     )
 104     |> Repo.delete_all()
 105   end
 106
 107   def delete_user_token(%User{id: user_id}, token_id) do
 108     from(
 109       t in Token,
 110       where: t.user_id == ^user_id,
 111       where: t.id == ^token_id
 112     )
 113     |> Repo.delete_all()
 114   end
 115
 116   def get_user_tokens(%User{id: user_id}) do
 117     from(
 118       t in Token,
 119       where: t.user_id == ^user_id
 120     )
 121     |> Repo.all()
 122     |> Repo.preload(:app)
 123   end
 124
 125   def is_expired?(%__MODULE__{valid_until: valid_until}) do
 126     NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) > 0
 127   end
 128
 129   def is_expired?(_), do: false
 130 end