git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Token do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.OAuth.App
  13   alias Pleroma.Web.OAuth.Authorization
  14   alias Pleroma.Web.OAuth.Token
  15   alias Pleroma.Web.OAuth.Token.Query
  16
  17   @type t :: %__MODULE__{}
  18
  19   schema "oauth_tokens" do
  20     field(:token, :string)
  21     field(:refresh_token, :string)
  22     field(:scopes, {:array, :string}, default: [])
  23     field(:valid_until, :naive_datetime_usec)
  24     belongs_to(:user, User, type: Pleroma.FlakeId)
  25     belongs_to(:app, App)
  26
  27     timestamps()
  28   end
  29
  30   @doc "Gets token for app by access token"
  31   @spec get_by_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  32   def get_by_token(%App{id: app_id} = _app, token) do
  33     Query.get_by_app(app_id)
  34     |> Query.get_by_token(token)
  35     |> Repo.find_resource()
  36   end
  37
  38   @doc "Gets token for app by refresh token"
  39   @spec get_by_refresh_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  40   def get_by_refresh_token(%App{id: app_id} = _app, token) do
  41     Query.get_by_app(app_id)
  42     |> Query.get_by_refresh_token(token)
  43     |> Query.preload([:user])
  44     |> Repo.find_resource()
  45   end
  46
  47   @spec exchange_token(App.t(), Authorization.t()) ::
  48           {:ok, Token.t()} | {:error, Changeset.t()}
  49   def exchange_token(app, auth) do
  50     with {:ok, auth} <- Authorization.use_token(auth),
  51          true <- auth.app_id == app.id do
  52       user = if auth.user_id, do: User.get_cached_by_id(auth.user_id), else: %User{}
  53
  54       create_token(
  55         app,
  56         user,
  57         %{scopes: auth.scopes}
  58       )
  59     end
  60   end
  61
  62   defp put_token(changeset) do
  63     changeset
  64     |> change(%{token: Token.Utils.generate_token()})
  65     |> validate_required([:token])
  66     |> unique_constraint(:token)
  67   end
  68
  69   defp put_refresh_token(changeset, attrs) do
  70     refresh_token = Map.get(attrs, :refresh_token, Token.Utils.generate_token())
  71
  72     changeset
  73     |> change(%{refresh_token: refresh_token})
  74     |> validate_required([:refresh_token])
  75     |> unique_constraint(:refresh_token)
  76   end
  77
  78   defp put_valid_until(changeset, attrs) do
  79     expires_in =
  80       Map.get(attrs, :valid_until, NaiveDateTime.add(NaiveDateTime.utc_now(), expires_in()))
  81
  82     changeset
  83     |> change(%{valid_until: expires_in})
  84     |> validate_required([:valid_until])
  85   end
  86
  87   @spec create_token(App.t(), User.t(), map()) :: {:ok, Token} | {:error, Changeset.t()}
  88   def create_token(%App{} = app, %User{} = user, attrs \\ %{}) do
  89     %__MODULE__{user_id: user.id, app_id: app.id}
  90     |> cast(%{scopes: attrs[:scopes] || app.scopes}, [:scopes])
  91     |> validate_required([:scopes, :app_id])
  92     |> put_valid_until(attrs)
  93     |> put_token()
  94     |> put_refresh_token(attrs)
  95     |> Repo.insert()
  96   end
  97
  98   def delete_user_tokens(%User{id: user_id}) do
  99     Query.get_by_user(user_id)
 100     |> Repo.delete_all()
 101   end
 102
 103   def delete_user_token(%User{id: user_id}, token_id) do
 104     Query.get_by_user(user_id)
 105     |> Query.get_by_id(token_id)
 106     |> Repo.delete_all()
 107   end
 108
 109   def delete_expired_tokens do
 110     Query.get_expired_tokens()
 111     |> Repo.delete_all()
 112   end
 113
 114   def get_user_tokens(%User{id: user_id}) do
 115     Query.get_by_user(user_id)
 116     |> Query.preload([:app])
 117     |> Repo.all()
 118   end
 119
 120   def is_expired?(%__MODULE__{valid_until: valid_until}) do
 121     NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) > 0
 122   end
 123
 124   def is_expired?(_), do: false
 125
 126   defp expires_in, do: Pleroma.Config.get([:oauth2, :token_expires_in], 600)
 127 end