git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Token do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.OAuth.App
  13   alias Pleroma.Web.OAuth.Authorization
  14   alias Pleroma.Web.OAuth.Token
  15   alias Pleroma.Web.OAuth.Token.Query
  16
  17   @type t :: %__MODULE__{}
  18
  19   schema "oauth_tokens" do
  20     field(:token, :string)
  21     field(:refresh_token, :string)
  22     field(:scopes, {:array, :string}, default: [])
  23     field(:valid_until, :naive_datetime_usec)
  24     belongs_to(:user, User, type: FlakeId.Ecto.CompatType)
  25     belongs_to(:app, App)
  26
  27     timestamps()
  28   end
  29
  30   @doc "Gets token for app by access token"
  31   @spec get_by_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  32   def get_by_token(%App{id: app_id} = _app, token) do
  33     Query.get_by_app(app_id)
  34     |> Query.get_by_token(token)
  35     |> Repo.find_resource()
  36   end
  37
  38   @doc "Gets token for app by refresh token"
  39   @spec get_by_refresh_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  40   def get_by_refresh_token(%App{id: app_id} = _app, token) do
  41     Query.get_by_app(app_id)
  42     |> Query.get_by_refresh_token(token)
  43     |> Query.preload([:user])
  44     |> Repo.find_resource()
  45   end
  46
  47   @spec exchange_token(App.t(), Authorization.t()) :: {:ok, Token.t()} | {:error, Changeset.t()}
  48   def exchange_token(app, auth) do
  49     with {:ok, auth} <- Authorization.use_token(auth),
  50          true <- auth.app_id == app.id do
  51       user = if auth.user_id, do: User.get_cached_by_id(auth.user_id), else: %User{}
  52
  53       create_token(
  54         app,
  55         user,
  56         %{scopes: auth.scopes}
  57       )
  58     end
  59   end
  60
  61   defp put_token(changeset) do
  62     changeset
  63     |> change(%{token: Token.Utils.generate_token()})
  64     |> validate_required([:token])
  65     |> unique_constraint(:token)
  66   end
  67
  68   defp put_refresh_token(changeset, attrs) do
  69     refresh_token = Map.get(attrs, :refresh_token, Token.Utils.generate_token())
  70
  71     changeset
  72     |> change(%{refresh_token: refresh_token})
  73     |> validate_required([:refresh_token])
  74     |> unique_constraint(:refresh_token)
  75   end
  76
  77   defp put_valid_until(changeset, attrs) do
  78     expires_in =
  79       Map.get(attrs, :valid_until, NaiveDateTime.add(NaiveDateTime.utc_now(), expires_in()))
  80
  81     changeset
  82     |> change(%{valid_until: expires_in})
  83     |> validate_required([:valid_until])
  84   end
  85
  86   @spec create_token(App.t(), User.t(), map()) :: {:ok, Token} | {:error, Changeset.t()}
  87   def create_token(%App{} = app, %User{} = user, attrs \\ %{}) do
  88     %__MODULE__{user_id: user.id, app_id: app.id}
  89     |> cast(%{scopes: attrs[:scopes] || app.scopes}, [:scopes])
  90     |> validate_required([:scopes, :app_id])
  91     |> put_valid_until(attrs)
  92     |> put_token()
  93     |> put_refresh_token(attrs)
  94     |> Repo.insert()
  95   end
  96
  97   def delete_user_tokens(%User{id: user_id}) do
  98     Query.get_by_user(user_id)
  99     |> Repo.delete_all()
 100   end
 101
 102   def delete_user_token(%User{id: user_id}, token_id) do
 103     Query.get_by_user(user_id)
 104     |> Query.get_by_id(token_id)
 105     |> Repo.delete_all()
 106   end
 107
 108   def delete_expired_tokens do
 109     Query.get_expired_tokens()
 110     |> Repo.delete_all()
 111   end
 112
 113   def get_user_tokens(%User{id: user_id}) do
 114     Query.get_by_user(user_id)
 115     |> Query.preload([:app])
 116     |> Repo.all()
 117   end
 118
 119   def is_expired?(%__MODULE__{valid_until: valid_until}) do
 120     NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) > 0
 121   end
 122
 123   def is_expired?(_), do: false
 124
 125   defp expires_in, do: Pleroma.Config.get([:oauth2, :token_expires_in], 600)
 126 end