git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/scopes.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Scopes do
   6   @moduledoc """
   7   Functions for dealing with scopes.
   8   """
   9
  10   alias Pleroma.Plugs.OAuthScopesPlug
  11
  12   @doc """
  13   Fetch scopes from request params.
  14
  15   Note: `scopes` is used by Mastodon — supporting it but sticking to
  16   OAuth's standard `scope` wherever we control it
  17   """
  18   @spec fetch_scopes(map(), list()) :: list()
  19   def fetch_scopes(params, default) do
  20     parse_scopes(params["scope"] || params["scopes"], default)
  21   end
  22
  23   def parse_scopes(scopes, _default) when is_list(scopes) do
  24     Enum.filter(scopes, &(&1 not in [nil, ""]))
  25   end
  26
  27   def parse_scopes(scopes, default) when is_binary(scopes) do
  28     scopes
  29     |> to_list
  30     |> parse_scopes(default)
  31   end
  32
  33   def parse_scopes(_, default) do
  34     default
  35   end
  36
  37   @doc """
  38   Convert scopes string to list
  39   """
  40   @spec to_list(binary()) :: [binary()]
  41   def to_list(nil), do: []
  42
  43   def to_list(str) do
  44     str
  45     |> String.trim()
  46     |> String.split(~r/[\s,]+/)
  47   end
  48
  49   @doc """
  50   Convert scopes list to string
  51   """
  52   @spec to_string(list()) :: binary()
  53   def to_string(scopes), do: Enum.join(scopes, " ")
  54
  55   @doc """
  56   Validates scopes.
  57   """
  58   @spec validate(list() | nil, list()) ::
  59           {:ok, list()} | {:error, :missing_scopes | :unsupported_scopes}
  60   def validate(blank_scopes, _app_scopes) when blank_scopes in [nil, []],
  61     do: {:error, :missing_scopes}
  62
  63   def validate(scopes, app_scopes) do
  64     case OAuthScopesPlug.filter_descendants(scopes, app_scopes) do
  65       ^scopes -> {:ok, scopes}
  66       _ -> {:error, :unsupported_scopes}
  67     end
  68   end
  69
  70   def contains_admin_scopes?(scopes) do
  71     scopes
  72     |> OAuthScopesPlug.filter_descendants(["admin"])
  73     |> Enum.any?()
  74   end
  75 end